Tests: Add the MFC test (#11213)

Build a simple, do-nothing VS 7.1 MFC wizard generated app
with CMake.

Build it two different ways via ExternalProject, one with
CMAKE_MFC_FLAG set to 1 for linking to MFC statically, and
one with CMAKE_MFC_FLAG set to 2 for linking to the shared
MFC dlls.

Validate that the install tree of the static build has only
one *.exe file in it and nothing else. Also validate that the
install tree of the shared library build has multiple files in
it (no less than 3) and that they are only of the expected types
*.exe, *.dll and *.manifest.

This commit does not address the issue reported in #11213,
it merely adds a test that may be used to show that the
bug report is valid. After this commit, the MFC test should
fail on any dashboard machines that have MSVC defined, but
cannot build an MFC app. We can then analyze that failure
data as input to solving the issue.

1 files changed, 60 insertions, 0 deletions

diff --git a/Tests/MFC/ValidateBuild.cmake.in b/Tests/MFC/ValidateBuild.cmake.in
new file mode 100644
index 0000000..68de549
--- /dev/null
+++ b/Tests/MFC/ValidateBuild.cmake.in
@@ -0,0 +1,60 @@
+#
+# This code validates that the install trees of the shared and static builds
+# of "mfc1" have the expected contents:
+#
+set(binary_dir "@binary_dir@")
+message("binary_dir='${binary_dir}'")
+
+# There should be exactly one file in the static install tree "bin" directory
+# and it should be named "mfc1.exe"
+#
+message(STATUS "===== mfcStatic install tree =====")
+file(GLOB_RECURSE files "${binary_dir}/mfcStatic-prefix/bin/*.*")
+message(STATUS "mfcStatic files='${files}'")
+list(LENGTH files len)
+if(NOT len EQUAL 1)
+  message(FATAL_ERROR
+    "len='${len}' is not '1' (count of static 'bin' files)")
+endif()
+get_filename_component(name "${files}" NAME)
+string(TOLOWER "${name}" name)
+if(NOT "${name}" STREQUAL "mfc1.exe")
+  message(FATAL_ERROR "unexpected mfcStatic file name '${name}'")
+endif()
+
+# There should be at least 3 files in the shared install tree "bin"
+# directory: mfc1.exe, the main MFC dll and the C runtime dll. With more
+# recent versions of VS, there will also be an MFC language dll and a
+# manifest file.
+#
+message(STATUS "===== mfcShared install tree =====")
+file(GLOB_RECURSE files "${binary_dir}/mfcShared-prefix/bin/*.*")
+message(STATUS "mfcShared files='${files}'")
+list(LENGTH files len)
+if(len LESS 3)
+  message(FATAL_ERROR
+    "len='${len}' is less than '3' (count of shared 'bin' files)")
+endif()
+foreach(f ${files})
+  message(STATUS "file '${f}'")
+  get_filename_component(ext "${f}" EXT)
+  string(TOLOWER "${ext}" ext)
+
+  if("${ext}" MATCHES "\\.exe$")
+    message(STATUS "  exe file")
+    get_filename_component(name "${f}" NAME)
+    string(TOLOWER "${name}" name)
+    if(NOT "${name}" STREQUAL "mfc1.exe")
+      message(FATAL_ERROR "unexpected mfcShared .exe file name '${name}'")
+    endif()
+  elseif("${ext}" MATCHES "\\.dll$")
+    message(STATUS "  dll file")
+  elseif("${ext}" MATCHES "\\.manifest$")
+    message(STATUS "  manifest file")
+  else()
+    message(STATUS "  unknown file")
+    message(FATAL_ERROR "unexpected mfcShared ${ext} file name '${f}'")
+  endif()
+endforeach()
+
+message(STATUS "All mfc1 build validation tests pass.")