3 files changed, 63 insertions, 0 deletions
diff --git a/Tests/RunCMake/CPack/tests/TIMESTAMPS/ExpectedFiles.cmake b/Tests/RunCMake/CPack/tests/TIMESTAMPS/ExpectedFiles.cmake
new file mode 100644
index 0000000..d1a3a5f
--- /dev/null
+++ b/Tests/RunCMake/CPack/tests/TIMESTAMPS/ExpectedFiles.cmake
@@ -0,0 +1,2 @@
+set(EXPECTED_FILES_COUNT "1")
+set(EXPECTED_FILE_CONTENT_1_LIST "/foo;/foo/CMakeLists.txt")
diff --git a/Tests/RunCMake/CPack/tests/TIMESTAMPS/VerifyResult.cmake b/Tests/RunCMake/CPack/tests/TIMESTAMPS/VerifyResult.cmake
new file mode 100644
index 0000000..e7e2645
--- /dev/null
+++ b/Tests/RunCMake/CPack/tests/TIMESTAMPS/VerifyResult.cmake
@@ -0,0 +1,58 @@
+macro(getFileMetadata_ FILE RESULT_VAR)
+  if(GENERATOR_TYPE STREQUAL "TGZ")
+    # getPackageContent defined for archives omit the metadata (non-verbose)
+    execute_process(COMMAND ${CMAKE_COMMAND} -E env TZ=Etc/UTC ${CMAKE_COMMAND} -E tar -xtvf ${FILE}
+            OUTPUT_VARIABLE ${RESULT_VAR}
+            ERROR_QUIET
+            OUTPUT_STRIP_TRAILING_WHITESPACE)
+  else()
+    getPackageContent("${FILE}" ${RESULT_VAR})
+  endif()
+endmacro()
+
+function(checkContentTimestamp FILE REGEX)
+  getFileMetadata_("${FILE}" METADATA_)
+
+  if(NOT METADATA_ MATCHES "${REGEX}")
+    string(REPLACE "\n" "\n  " metadata_indented "${METADATA_}")
+    message(FATAL_ERROR
+      "Wrong timestamps in file:\n"
+      "  ${FILE}\n"
+      "Expected timestamps to match:\n"
+      "  ${REGEX}\n"
+      "Actual timestamps:\n"
+      "  ${metadata_indented}")
+  endif()
+endfunction()
+
+function(checkTimestamp FILE_NAME)
+  file(READ ${FILE_NAME} ACTUAL_TIMESTAMP OFFSET 4 LIMIT 4 HEX)
+
+  if(NOT ACTUAL_TIMESTAMP STREQUAL "00000000")
+    message(FATAL_ERROR "${FILE_NAME} contains a timestamp [0x${ACTUAL_TIMESTAMP}]")
+  endif()
+endfunction()
+
+# Expected timestamp is UNIX time 123456789
+if(GENERATOR_TYPE STREQUAL "TGZ")
+  set(EXPECTED_TIMESTAMP "29 Nov +1973")
+  set(EXPECTED_FILES foo/ foo/CMakeLists.txt)
+else()
+  set(EXPECTED_TIMESTAMP "1973-11-29 21:33")
+  set(EXPECTED_FILES ./usr/ ./usr/foo/ ./usr/foo/CMakeLists.txt)
+endif()
+
+set(EXPECTED_METADATA)
+foreach(FILE ${EXPECTED_FILES})
+  list(APPEND EXPECTED_METADATA ".* ${EXPECTED_TIMESTAMP} ${FILE}")
+endforeach()
+list(JOIN EXPECTED_METADATA ".*" EXPECTED_REGEX)
+checkContentTimestamp("${FOUND_FILE_1}" "${EXPECTED_REGEX}")
+
+if(GENERATOR_TYPE STREQUAL "TGZ")
+  checkTimestamp("${FOUND_FILE_1}")
+else()
+  execute_process(COMMAND ${CMAKE_COMMAND} -E tar xf "${FOUND_FILE_1}")
+  checkTimestamp("data.tar.gz")
+  checkTimestamp("control.tar.gz")
+endif()
diff --git a/Tests/RunCMake/CPack/tests/TIMESTAMPS/test.cmake b/Tests/RunCMake/CPack/tests/TIMESTAMPS/test.cmake
new file mode 100644
index 0000000..a193852
--- /dev/null
+++ b/Tests/RunCMake/CPack/tests/TIMESTAMPS/test.cmake
@@ -0,0 +1,3 @@
+install(FILES CMakeLists.txt DESTINATION foo COMPONENT test)
+
+set(CPACK_COMPONENTS_ALL test)