7 files changed, 323 insertions, 4 deletions
diff --git a/Tests/CMakeCommands/build_command/CMakeLists.txt b/Tests/CMakeCommands/build_command/CMakeLists.txt
new file mode 100644
index 0000000..990ac90
--- /dev/null
+++ b/Tests/CMakeCommands/build_command/CMakeLists.txt
@@ -0,0 +1,58 @@
+# This CMakeLists file is *sometimes expected* to result in a configure error.
+#
+# expect this to succeed:
+# ../bin/Release/cmake -G Xcode
+#   ../../CMake/Tests/CMakeCommands/build_command
+#
+# expect this to fail:
+# ../bin/Release/cmake -DTEST_ERROR_CONDITIONS:BOOL=ON -G Xcode
+#   ../../CMake/Tests/CMakeCommands/build_command
+#
+# This project exists merely to test the CMake command 'build_command'...
+# ...even purposefully calling it with known-bad argument lists to cover
+# error handling code.
+#
+cmake_minimum_required(VERSION 2.8)
+project(test_build_command)
+
+set(cmd "initial")
+
+message("CTEST_FULL_OUTPUT")
+message("0. begin")
+
+if(TEST_ERROR_CONDITIONS)
+  # Test with no arguments (an error):
+  build_command()
+  message("1. cmd='${cmd}'")
+
+  # Test with unknown arguments (also an error):
+  build_command(cmd BOGUS STUFF)
+  message("2. cmd='${cmd}'")
+
+  build_command(cmd STUFF BOGUS)
+  message("3. cmd='${cmd}'")
+else()
+  message("(skipping cases 1, 2 and 3 because TEST_ERROR_CONDITIONS is OFF)")
+endif()
+
+# Test the one arg signature with none of the optional KEYWORD arguments:
+build_command(cmd)
+message("4. cmd='${cmd}'")
+
+# Test the two-arg legacy signature:
+build_command(legacy_cmd ${CMAKE_BUILD_TOOL})
+message("5. legacy_cmd='${legacy_cmd}'")
+message("   CMAKE_BUILD_TOOL='${CMAKE_BUILD_TOOL}'")
+
+# Test the optional KEYWORDs:
+build_command(cmd CONFIGURATION hoohaaConfig)
+message("6. cmd='${cmd}'")
+
+build_command(cmd PROJECT_NAME hoohaaProject)
+message("7. cmd='${cmd}'")
+
+build_command(cmd TARGET hoohaaTarget)
+message("8. cmd='${cmd}'")
+
+set(cmd "final")
+message("9. cmd='${cmd}'")
diff --git a/Tests/CMakeCommands/build_command/RunCMake.cmake b/Tests/CMakeCommands/build_command/RunCMake.cmake
new file mode 100644
index 0000000..55d9359
--- /dev/null
+++ b/Tests/CMakeCommands/build_command/RunCMake.cmake
@@ -0,0 +1,86 @@
+if(NOT DEFINED CMake_SOURCE_DIR)
+  message(FATAL_ERROR "CMake_SOURCE_DIR not defined")
+endif()
+
+if(NOT DEFINED dir)
+  message(FATAL_ERROR "dir not defined")
+endif()
+
+if(NOT DEFINED gen)
+  message(FATAL_ERROR "gen not defined")
+endif()
+
+message(STATUS "CTEST_FULL_OUTPUT (Avoid ctest truncation of output)")
+
+# Run cmake:
+#
+function(run_cmake build_dir extra_args expected_result expected_output expected_error)
+  message(STATUS "run_cmake build_dir='${build_dir}' extra_args='${extra_args}'")
+
+  # Ensure build_dir exists:
+  #
+  execute_process(COMMAND ${CMAKE_COMMAND} -E make_directory ${build_dir})
+
+  # Run cmake:
+  #
+  execute_process(COMMAND ${CMAKE_COMMAND}
+    ${extra_args}
+    -G ${gen} ${CMake_SOURCE_DIR}/Tests/CMakeCommands/build_command
+    RESULT_VARIABLE result
+    OUTPUT_VARIABLE stdout
+    ERROR_VARIABLE stderr
+    WORKING_DIRECTORY ${build_dir}
+    )
+
+  message(STATUS "result='${result}'")
+  message(STATUS "stdout='${stdout}'")
+  message(STATUS "stderr='${stderr}'")
+  message(STATUS "")
+
+  # Verify result and output match expectations:
+  #
+  if("0" STREQUAL "${expected_result}")
+    if(NOT "${result}" STREQUAL "0")
+      message(FATAL_ERROR
+        "error: result='${result}' is non-zero and different than expected_result='${expected_result}'")
+    endif()
+  else()
+    if("${result}" STREQUAL "0")
+      message(FATAL_ERROR
+        "error: result='${result}' is zero and different than expected_result='${expected_result}'")
+    endif()
+  endif()
+
+  foreach(e ${expected_output})
+    if(NOT stdout MATCHES "${e}")
+      message(FATAL_ERROR
+        "error: stdout does not match expected_output item e='${e}'")
+    else()
+      message(STATUS "info: stdout matches '${e}'")
+    endif()
+  endforeach()
+
+  foreach(e ${expected_error})
+    if(NOT stderr MATCHES "${e}")
+      message(FATAL_ERROR
+        "error: stderr does not match expected_error item e='${e}'")
+    else()
+      message(STATUS "info: stderr matches '${e}'")
+    endif()
+  endforeach()
+
+  message(STATUS "result, stdout and stderr match all expectations: test passes")
+  message(STATUS "")
+endfunction()
+
+
+# Expect this case to succeed:
+run_cmake("${dir}/b1" "" 0
+  "Build files have been written to:"
+  "skipping cases 1, 2 and 3 because TEST_ERROR_CONDITIONS is OFF")
+
+
+# Expect this one to fail:
+run_cmake("${dir}/b2" "-DTEST_ERROR_CONDITIONS:BOOL=ON" 1
+  "Configuring incomplete, errors occurred!"
+  "build_command requires at least one argument naming a CMake variable;build_command unknown argument ")
diff --git a/Tests/CMakeLists.txt b/Tests/CMakeLists.txt
index a9b584b..fe8caeb 100644
--- a/Tests/CMakeLists.txt
+++ b/Tests/CMakeLists.txt
@@ -1181,7 +1181,7 @@ ${CMake_BINARY_DIR}/bin/cmake -DVERSION=CVS -P ${CMake_SOURCE_DIR}/Utilities/Rel
     )
   SET_TESTS_PROPERTIES(CTestTestNoBuild PROPERTIES
     FAIL_REGULAR_EXPRESSION "Error" WILL_FAIL true)
-  
+
   CONFIGURE_FILE(
     "${CMake_SOURCE_DIR}/Tests/CTestTestFailure/testNoExe.cmake.in"
     "${CMake_BINARY_DIR}/Tests/CTestTestFailure/testNoExe.cmake"
@@ -1194,6 +1194,50 @@ ${CMake_BINARY_DIR}/bin/cmake -DVERSION=CVS -P ${CMake_SOURCE_DIR}/Utilities/Rel
     PASS_REGULAR_EXPRESSION "Could not find executable"
     FAIL_REGULAR_EXPRESSION "SegFault")
 
+
+  # Use macro, not function so that build can still be driven by CMake 2.4.
+  # After 2.6 is required, this could be a function without the extra 'set'
+  # calls.
+  #
+  macro(add_config_tests cfg)
+    set(cfg "${cfg}")
+    set(base "${CMake_BINARY_DIR}/Tests/CTestConfig")
+
+    # Test -S script with a -C config arg to ctest:
+    configure_file(
+      "${CMake_SOURCE_DIR}/Tests/CTestConfig/script.cmake.in"
+      "${base}/${cfg}-script.cmake"
+      @ONLY ESCAPE_QUOTES)
+    add_test(CTestConfig.Script.${cfg} ${CMAKE_CTEST_COMMAND}
+      -C ${cfg}
+      -S "${base}/${cfg}-script.cmake" -VV
+      --output-log "${base}/${cfg}-script.log"
+      )
+
+    # Test -D dashboard with a -C config arg to ctest.
+    # (Actual commands inside a cmake -P script because we need to be able to set
+    #  the working directory reliably...)
+    configure_file(
+      "${CMake_SOURCE_DIR}/Tests/CTestConfig/dashboard.cmake.in"
+      "${base}/${cfg}-dashboard.cmake"
+      @ONLY ESCAPE_QUOTES)
+    add_test(CTestConfig.Dashboard.${cfg} ${CMAKE_CMAKE_COMMAND}
+      -P "${base}/${cfg}-dashboard.cmake" -VV
+      )
+  endmacro()
+
+  add_config_tests(Debug)
+  add_config_tests(MinSizeRel)
+  add_config_tests(Release)
+  add_config_tests(RelWithDebInfo)
+
+  add_test(CMakeCommands.build_command ${CMAKE_CMAKE_COMMAND}
+    -DCMake_SOURCE_DIR=${CMake_SOURCE_DIR}
+    -Ddir=${CMake_BINARY_DIR}/Tests/CMakeCommands/build_command
+    -Dgen=${CMAKE_TEST_GENERATOR}
+    -P "${CMake_SOURCE_DIR}/Tests/CMakeCommands/build_command/RunCMake.cmake"
+  )
+
   CONFIGURE_FILE(
     "${CMake_SOURCE_DIR}/Tests/CTestTestCrash/test.cmake.in"
     "${CMake_BINARY_DIR}/Tests/CTestTestCrash/test.cmake"
@@ -1256,11 +1300,11 @@ ${CMake_BINARY_DIR}/bin/cmake -DVERSION=CVS -P ${CMake_SOURCE_DIR}/Utilities/Rel
     -S "${CMake_BINARY_DIR}/Tests/CTestTestRunScript/test.cmake" -V
     --output-log "${CMake_BINARY_DIR}/Tests/CTestTestRunScript/testOutput.log"
     )
-  
+
   ADD_TEST(CTestTestShowOnly ${CMAKE_CTEST_COMMAND} -N)
-  
+
   ADD_TEST(CTestBatchTest ${CMAKE_CTEST_COMMAND} -B)
-  
+
   # Use macro, not function so that build can still be driven by CMake 2.4.
   # After 2.6 is required, this could be a function without the extra 'set'
   # calls.
diff --git a/Tests/CTestConfig/CMakeLists.txt b/Tests/CTestConfig/CMakeLists.txt
new file mode 100644
index 0000000..f46d89a
--- /dev/null
+++ b/Tests/CTestConfig/CMakeLists.txt
@@ -0,0 +1,47 @@
+cmake_minimum_required(VERSION 2.8)
+project(CTestConfig)
+
+include(CTest)
+
+
+# We expect this configure to occur through a 'ctest -D Experimental' or a
+# 'ctest -S script.cmake' call.
+#
+# In either case, we expect CMAKE_BUILD_TYPE to be defined for single-configuration
+# build trees and not defined for multi-configuration build trees.
+#
+if(CMAKE_CONFIGURATION_TYPES)
+  # multi-configuration: expect not defined, error if defined
+  if(DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE STREQUAL "")
+    message(FATAL_ERROR "CMAKE_CONFIGURATION_TYPES='${CMAKE_CONFIGURATION_TYPES}' CMAKE_BUILD_TYPE='${CMAKE_BUILD_TYPE}' is defined and non-empty (but should not be for a multi-configuration generator)")
+  endif()
+else()
+  # single-configuration: expect defined, error if not defined
+  if(NOT DEFINED CMAKE_BUILD_TYPE OR CMAKE_BUILD_TYPE STREQUAL "")
+    message(FATAL_ERROR "CMAKE_BUILD_TYPE is not defined or is empty (but should be defined and non-empty for a single-configuration generator)")
+  endif()
+endif()
+
+
+if(DEFINED CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE STREQUAL "")
+  add_definitions(-DCMAKE_BUILD_TYPE="${CMAKE_BUILD_TYPE}")
+endif()
+
+add_executable(ctc CTestConfig.cxx)
+
+
+foreach(cfg ${CMAKE_CONFIGURATION_TYPES} ${CMAKE_BUILD_TYPE})
+  add_test(NAME ctc-${cfg} CONFIGURATIONS ${cfg} COMMAND ctc --config $<CONFIGURATION>)
+
+  if(CMAKE_CONFIGURATION_TYPES)
+    set_property(TEST ctc-${cfg}
+      PROPERTY PASS_REGULAR_EXPRESSION "CMAKE_INTDIR is ${cfg}")
+    set_property(TEST ctc-${cfg}
+      PROPERTY FAIL_REGULAR_EXPRESSION "CMAKE_BUILD_TYPE is")
+  else()
+    set_property(TEST ctc-${cfg}
+      PROPERTY PASS_REGULAR_EXPRESSION "CMAKE_BUILD_TYPE is ${cfg}")
+    set_property(TEST ctc-${cfg}
+      PROPERTY FAIL_REGULAR_EXPRESSION "CMAKE_INTDIR is")
+  endif()
+endforeach()
diff --git a/Tests/CTestConfig/CTestConfig.cxx b/Tests/CTestConfig/CTestConfig.cxx
new file mode 100644
index 0000000..49c5324
--- /dev/null
+++ b/Tests/CTestConfig/CTestConfig.cxx
@@ -0,0 +1,20 @@
+#include <stdio.h>
+
+int main(int argc, const char* argv[])
+{
+  int i = 0;
+  for (; i<argc; ++i)
+  {
+    fprintf(stdout, "%s\n", argv[i]);
+  }
+
+#ifdef CMAKE_BUILD_TYPE
+  fprintf(stdout, "CMAKE_BUILD_TYPE is %s\n", CMAKE_BUILD_TYPE);
+#endif
+
+#ifdef CMAKE_INTDIR
+  fprintf(stdout, "CMAKE_INTDIR is %s\n", CMAKE_INTDIR);
+#endif
+
+  return 0;
+}
diff --git a/Tests/CTestConfig/dashboard.cmake.in b/Tests/CTestConfig/dashboard.cmake.in
new file mode 100644
index 0000000..c7ac210
--- /dev/null
+++ b/Tests/CTestConfig/dashboard.cmake.in
@@ -0,0 +1,43 @@
+set(CMAKE_CONFIGURATION_TYPES "@CMAKE_CONFIGURATION_TYPES@")
+set(CTEST_SOURCE_DIRECTORY "@CMake_SOURCE_DIR@/Tests/CTestConfig")
+set(CTEST_BINARY_DIRECTORY "@CMake_BINARY_DIR@/Tests/CTestConfig/@cfg@-dashboard")
+
+file(MAKE_DIRECTORY "${CTEST_BINARY_DIRECTORY}")
+
+get_filename_component(dir "${CMAKE_COMMAND}" PATH)
+set(CMAKE_CTEST_COMMAND "${dir}/ctest")
+
+message("CMAKE_COMMAND='${CMAKE_COMMAND}'")
+message("CMAKE_CTEST_COMMAND='${CMAKE_CTEST_COMMAND}'")
+
+set(arg "")
+if(NOT CMAKE_CONFIGURATION_TYPES)
+  set(arg "-DCMAKE_BUILD_TYPE:STRING=@cfg@")
+endif()
+
+message("cmake initial configure")
+execute_process(COMMAND ${CMAKE_COMMAND}
+  ${arg} -G "@CMAKE_TEST_GENERATOR@" ${CTEST_SOURCE_DIRECTORY}
+  WORKING_DIRECTORY ${CTEST_BINARY_DIRECTORY}
+  RESULT_VARIABLE rv)
+if(NOT rv STREQUAL 0)
+  message(FATAL_ERROR "error calling cmake: rv='${rv}'")
+endif()
+
+
+function(call_ctest arg)
+  message("call_ctest ${arg}")
+  execute_process(COMMAND ${CMAKE_CTEST_COMMAND}
+    -C "@cfg@" -D ${arg} -VV
+    WORKING_DIRECTORY ${CTEST_BINARY_DIRECTORY}
+    RESULT_VARIABLE rv)
+  if(NOT rv STREQUAL 0)
+    message(FATAL_ERROR "error calling ctest: rv='${rv}'")
+  endif()
+endfunction()
+
+
+call_ctest(ExperimentalStart)
+call_ctest(ExperimentalConfigure)
+call_ctest(ExperimentalBuild)
+call_ctest(ExperimentalTest)
diff --git a/Tests/CTestConfig/script.cmake.in b/Tests/CTestConfig/script.cmake.in
new file mode 100644
index 0000000..5ceb7c3
--- /dev/null
+++ b/Tests/CTestConfig/script.cmake.in
@@ -0,0 +1,21 @@
+set(CTEST_CMAKE_GENERATOR "@CMAKE_TEST_GENERATOR@")
+set(CTEST_PROJECT_NAME "CTestConfig")
+set(CTEST_SOURCE_DIRECTORY "@CMake_SOURCE_DIR@/Tests/CTestConfig")
+set(CTEST_BINARY_DIRECTORY "@CMake_BINARY_DIR@/Tests/CTestConfig/@cfg@-script")
+
+ctest_start(Experimental)
+
+ctest_configure(BUILD "${CTEST_BINARY_DIRECTORY}" RETURN_VALUE rv)
+if(NOT rv STREQUAL 0)
+  message(FATAL_ERROR "*** error in ctest_configure ***")
+endif()
+
+ctest_build(BUILD "${CTEST_BINARY_DIRECTORY}" RETURN_VALUE rv)
+if(NOT rv STREQUAL 0)
+  message(FATAL_ERROR "*** error in ctest_build ***")
+endif()
+
+ctest_test(BUILD "${CTEST_BINARY_DIRECTORY}" RETURN_VALUE rv)
+if(NOT rv STREQUAL 0)
+  message(FATAL_ERROR "*** error in ctest_test ***")
+endif()