From e898324778c5f46d264a1351992be5d0c0d11eae Mon Sep 17 00:00:00 2001
From: Andy Cedilnik <andy.cedilnik@kitware.com>
Date: Sun, 31 Jul 2005 23:02:22 -0400
Subject: ENH: Add a test for C source file like AC_TRY_COMPILE

---
 Modules/CheckCSourceCompiles.cmake | 53 ++++++++++++++++++++++++++++++++++++++
 Tests/MacroTest/CMakeLists.txt     | 22 ++++++++++++++++
 2 files changed, 75 insertions(+)
 create mode 100644 Modules/CheckCSourceCompiles.cmake

diff --git a/Modules/CheckCSourceCompiles.cmake b/Modules/CheckCSourceCompiles.cmake
new file mode 100644
index 0000000..f43ebf3
--- /dev/null
+++ b/Modules/CheckCSourceCompiles.cmake
@@ -0,0 +1,53 @@
+#
+# Check if the source code provided in the SOURCE argument compiles.
+#
+# CHECK_C_SOURCE_COMPILES - macro which checks if the source code compiles\
+# SOURCE   - source code to try to compile
+# VARIABLE - variable to store size if the type exists.
+#
+# Checks the following optional VARIABLES (not arguments)
+# CMAKE_REQUIRED_LIBRARIES - Link to extra libraries
+# CMAKE_REQUIRED_FLAGS - Extra flags to C compiler
+#
+
+MACRO(CHECK_C_SOURCE_COMPILES SOURCE VAR)
+  IF("${VAR}" MATCHES "^${VAR}$")
+    SET(MACRO_CHECK_FUNCTION_DEFINITIONS 
+      "-D${VAR} ${CMAKE_REQUIRED_FLAGS}")
+    IF(CMAKE_REQUIRED_LIBRARIES)
+      SET(CHECK_C_SOURCE_COMPILES_ADD_LIBRARIES
+        "-DLINK_LIBRARIES:STRING=${CMAKE_REQUIRED_LIBRARIES}")
+    ENDIF(CMAKE_REQUIRED_LIBRARIES)
+    IF(CMAKE_REQUIRED_INCLUDES)
+      SET(CHECK_C_SOURCE_COMPILES_ADD_INCLUDES
+        "-DINCLUDE_DIRECTORIES:STRING=${CMAKE_REQUIRED_INCLUDES}")
+    ENDIF(CMAKE_REQUIRED_INCLUDES)
+    FILE(WRITE "${CMAKE_BINARY_DIR}/CMakeTmp/src.c"
+      "${SOURCE}")
+
+    MESSAGE(STATUS "Performing Test ${VAR}")
+    TRY_COMPILE(${VAR}
+      ${CMAKE_BINARY_DIR}
+      ${CMAKE_BINARY_DIR}/CMakeTmp/src.c
+      CMAKE_FLAGS 
+      "${CHECK_C_SOURCE_COMPILES_ADD_LIBRARIES}"
+      "${CHECK_C_SOURCE_COMPILES_ADD_INCLUDES}"
+      OUTPUT_VARIABLE OUTPUT)
+    IF(${VAR})
+      SET(${VAR} 1 CACHE INTERNAL "Test ${FUNCTION}")
+      MESSAGE(STATUS "Performing Test ${VAR} - Success")
+      WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log 
+        "Performing C SOURCE FILE Test ${VAR} succeded with the following output:\n"
+        "${OUTPUT}\n"
+        "Source file was:\n${SOURCE}\n" APPEND)
+    ELSE(${VAR})
+      MESSAGE(STATUS "Performing Test ${VAR} - Failed")
+      SET(${VAR} "" CACHE INTERNAL "Test ${FUNCTION}")
+      WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log 
+        "Performing C SOURCE FILE Test ${VAR} failed with the following output:\n"
+        "${OUTPUT}\n"
+        "Source file was:\n${SOURCE}\n" APPEND)
+    ENDIF(${VAR})
+  ENDIF("${VAR}" MATCHES "^${VAR}$")
+ENDMACRO(CHECK_C_SOURCE_COMPILES)
+
diff --git a/Tests/MacroTest/CMakeLists.txt b/Tests/MacroTest/CMakeLists.txt
index 8e5a5e9..604467c 100644
--- a/Tests/MacroTest/CMakeLists.txt
+++ b/Tests/MacroTest/CMakeLists.txt
@@ -47,4 +47,26 @@ ENDIF("${var}" EQUAL "strange_macro" AND "${second_var}" EQUAL "second_var")
 MACRO(ADD_EXECUTABLE exec)
   _ADD_EXECUTABLE("mini${exec}" ${ARGN})
 ENDMACRO(ADD_EXECUTABLE)
+
+INCLUDE(CheckCSourceCompiles)
+Check_C_Source_Compiles(
+"
+#include <stdio.h>
+#ifdef __CLASSIC_C__
+int main(){
+  int ac;
+  char*av[];
+#else
+int main(int ac, char*av[]){
+#endif
+  if(ac > 1000){return *av[0];}
+  return 0;
+}"
+SOME_CHECK)
+IF(SOME_CHECK)
+  MESSAGE("CheckCSourceCompiles works")
+ELSE(SOME_CHECK)
+  MESSAGE(FATAL_ERROR "CheckCSourceCompiles does not work")
+ENDIF(SOME_CHECK)
+
 ADD_EXECUTABLE(MacroTest macroTest.c)
-- 
cgit v0.12