Consolidate sql driver configuration redundancy

Previously sql driver recipes each appeared in both the plugin
pro file and src/sql/drivers/drivers.pri for building into QtSql.

Split driver recipes into shared pri files.
Also split bundled 3rd party sqlite code recipe into a shared pri.

Merge-request: 715
Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@nokia.com>

20 files changed, 126 insertions, 221 deletions

diff --git a/src/3rdparty/sqlite.pri b/src/3rdparty/sqlite.pri
new file mode 100644
index 0000000..575412d
--- /dev/null
+++ b/src/3rdparty/sqlite.pri
@@ -0,0 +1,4 @@
+CONFIG(release, debug|release):DEFINES *= NDEBUG
+DEFINES += SQLITE_OMIT_LOAD_EXTENSION SQLITE_OMIT_COMPLETE
+INCLUDEPATH +=  $$PWD/sqlite
+SOURCES +=      $$PWD/sqlite/sqlite3.c
diff --git a/src/plugins/sqldrivers/db2/db2.pro b/src/plugins/sqldrivers/db2/db2.pro
index 25ca499..e053f37 100644
--- a/src/plugins/sqldrivers/db2/db2.pro
+++ b/src/plugins/sqldrivers/db2/db2.pro
@@ -1,10 +1,6 @@
 TARGET = qsqldb2
 
-HEADERS		= ../../../sql/drivers/db2/qsql_db2.h
-SOURCES		= main.cpp \
-		  ../../../sql/drivers/db2/qsql_db2.cpp
-
-unix:!contains( LIBS, .*db2.* ):LIBS 	*= -ldb2
-win32:!contains( LIBS, .*db2.* ):LIBS   *= -ldb2cli
+SOURCES = main.cpp
+include(../../../sql/drivers/db2/qsql_db2.pri)
 
 include(../qsqldriverbase.pri)
diff --git a/src/plugins/sqldrivers/ibase/ibase.pro b/src/plugins/sqldrivers/ibase/ibase.pro
index bb73adb..7870ec8 100644
--- a/src/plugins/sqldrivers/ibase/ibase.pro
+++ b/src/plugins/sqldrivers/ibase/ibase.pro
@@ -1,14 +1,6 @@
 TARGET = qsqlibase
 
-HEADERS		= ../../../sql/drivers/ibase/qsql_ibase.h
-SOURCES		= main.cpp \
-		  ../../../sql/drivers/ibase/qsql_ibase.cpp
-
-unix:!contains( LIBS, .*gds.* ):!contains( LIBS, .*libfb.* ):LIBS    *= -lgds
-
-win32:!contains( LIBS, .*gds.* ):!contains( LIBS, .*fbclient.* ) {
-	!win32-borland:LIBS *= -lgds32_ms
-	win32-borland:LIBS  += gds32.lib
-}
+SOURCES = main.cpp
+include(../../../sql/drivers/ibase/qsql_ibase.pri)
 
 include(../qsqldriverbase.pri)
diff --git a/src/plugins/sqldrivers/mysql/mysql.pro b/src/plugins/sqldrivers/mysql/mysql.pro
index b808c8e..b6d42ff 100644
--- a/src/plugins/sqldrivers/mysql/mysql.pro
+++ b/src/plugins/sqldrivers/mysql/mysql.pro
@@ -1,23 +1,6 @@
 TARGET = qsqlmysql
 
-HEADERS		= ../../../sql/drivers/mysql/qsql_mysql.h
-SOURCES		= main.cpp \
-		  ../../../sql/drivers/mysql/qsql_mysql.cpp
-
-unix: {
-    isEmpty(QT_LFLAGS_MYSQL) {
-        !contains(LIBS, .*mysqlclient.*):!contains(LIBS, .*mysqld.*) {
-            use_libmysqlclient_r:LIBS *= -lmysqlclient_r
-            else:LIBS *= -lmysqlclient
-        }
-    } else {
-        LIBS *= $$QT_LFLAGS_MYSQL
-        QMAKE_CXXFLAGS *= $$QT_CFLAGS_MYSQL
-    }
-}
-
-win32:!contains(LIBS, .*mysql.*):!contains(LIBS, .*mysqld.*) {
-    LIBS     *= -llibmysql    
-}
+SOURCES = main.cpp
+include(../../../sql/drivers/mysql/qsql_mysql.pri)
 
 include(../qsqldriverbase.pri)
diff --git a/src/plugins/sqldrivers/oci/oci.pro b/src/plugins/sqldrivers/oci/oci.pro
index d75827e..d7dcce9 100644
--- a/src/plugins/sqldrivers/oci/oci.pro
+++ b/src/plugins/sqldrivers/oci/oci.pro
@@ -1,13 +1,6 @@
 TARGET = qsqloci
 
-HEADERS		= ../../../sql/drivers/oci/qsql_oci.h
-SOURCES		= main.cpp \
-		  ../../../sql/drivers/oci/qsql_oci.cpp
-
-win32:LIBS	*= -loci
-
-unix:!contains( LIBS, .*clnts.* ):LIBS	*= -lclntsh
-
-macx:QMAKE_LFLAGS += -Wl,-flat_namespace,-U,_environ
+SOURCES = main.cpp
+include(../../../sql/drivers/oci/qsql_oci.pri)
 
 include(../qsqldriverbase.pri)
diff --git a/src/plugins/sqldrivers/odbc/odbc.pro b/src/plugins/sqldrivers/odbc/odbc.pro
index 70070db..677eb6e 100644
--- a/src/plugins/sqldrivers/odbc/odbc.pro
+++ b/src/plugins/sqldrivers/odbc/odbc.pro
@@ -1,19 +1,6 @@
 TARGET = qsqlodbc
 
-HEADERS		= ../../../sql/drivers/odbc/qsql_odbc.h
-SOURCES		= main.cpp \
-		  ../../../sql/drivers/odbc/qsql_odbc.cpp
-
-unix {
-	!contains( LIBS, .*odbc.* ) {
-	    LIBS 	*= $$QT_LFLAGS_ODBC
-	}
-        DEFINES += UNICODE
-}
-
-win32 {
-	!win32-borland:LIBS	*= -lodbc32
-    	win32-borland:LIBS	*= $(BCB)/lib/PSDK/odbc32.lib
-}
+SOURCES = main.cpp
+include(../../../sql/drivers/odbc/qsql_odbc.pri)
 
 include(../qsqldriverbase.pri)
diff --git a/src/plugins/sqldrivers/psql/psql.pro b/src/plugins/sqldrivers/psql/psql.pro
index 9586695..8276c0a 100644
--- a/src/plugins/sqldrivers/psql/psql.pro
+++ b/src/plugins/sqldrivers/psql/psql.pro
@@ -1,18 +1,6 @@
 TARGET = qsqlpsql
 
-HEADERS		= ../../../sql/drivers/psql/qsql_psql.h
-SOURCES		= main.cpp \
-		  ../../../sql/drivers/psql/qsql_psql.cpp
-
-unix|win32-g++*: {
-    !isEmpty(QT_LFLAGS_PSQL) {
-        !contains(QT_CONFIG, system-zlib): QT_LFLAGS_PSQL -= -lz
-        !static:LIBS *= $$QT_LFLAGS_PSQL
-        QMAKE_CXXFLAGS *= $$QT_CFLAGS_PSQL
-    }
-    !contains(LIBS, .*pq.*):LIBS *= -lpq
-}
-
-win32:!win32-g++*:!contains(LIBS, .*pq.* ) LIBS *= -llibpq -lws2_32 -ladvapi32
+SOURCES = main.cpp
+include(../../../sql/drivers/psql/qsql_psql.pri)
 
 include(../qsqldriverbase.pri)
diff --git a/src/plugins/sqldrivers/sqlite/sqlite.pro b/src/plugins/sqldrivers/sqlite/sqlite.pro
index 75f04b9..f4c1671 100644
--- a/src/plugins/sqldrivers/sqlite/sqlite.pro
+++ b/src/plugins/sqldrivers/sqlite/sqlite.pro
@@ -1,18 +1,7 @@
 TARGET = qsqlite
 
-HEADERS		= ../../../sql/drivers/sqlite/qsql_sqlite.h
-SOURCES		= smain.cpp \
-		  ../../../sql/drivers/sqlite/qsql_sqlite.cpp
-
-!system-sqlite:!contains( LIBS, .*sqlite.* ) {
-    CONFIG(release, debug|release):DEFINES *= NDEBUG
-    DEFINES += SQLITE_OMIT_LOAD_EXTENSION SQLITE_OMIT_COMPLETE 
-    INCLUDEPATH += ../../../3rdparty/sqlite
-    SOURCES += ../../../3rdparty/sqlite/sqlite3.c
-} else {
-    LIBS *= $$QT_LFLAGS_SQLITE
-    QMAKE_CXXFLAGS *= $$QT_CFLAGS_SQLITE
-}
+SOURCES = smain.cpp
+include(../../../sql/drivers/sqlite/qsql_sqlite.pri)
 
 wince*: DEFINES += HAVE_LOCALTIME_S=0
 
diff --git a/src/plugins/sqldrivers/sqlite2/sqlite2.pro b/src/plugins/sqldrivers/sqlite2/sqlite2.pro
index 0f6c19a..e6197b9 100644
--- a/src/plugins/sqldrivers/sqlite2/sqlite2.pro
+++ b/src/plugins/sqldrivers/sqlite2/sqlite2.pro
@@ -1,9 +1,6 @@
 TARGET = qsqlite2
 
-HEADERS		= ../../../sql/drivers/sqlite2/qsql_sqlite2.h
-SOURCES		= smain.cpp \
-		  ../../../sql/drivers/sqlite2/qsql_sqlite2.cpp
-
-!contains(LIBS, .*sqlite.*):LIBS *= -lsqlite
+SOURCES = smain.cpp
+include(../../../sql/drivers/sqlite2/qsql_sqlite2.pri)
 
 include(../qsqldriverbase.pri)
diff --git a/src/plugins/sqldrivers/tds/tds.pro b/src/plugins/sqldrivers/tds/tds.pro
index ba40be5..b8e8ded 100644
--- a/src/plugins/sqldrivers/tds/tds.pro
+++ b/src/plugins/sqldrivers/tds/tds.pro
@@ -1,15 +1,6 @@
 TARGET = qsqltds
 
-HEADERS		= ../../../sql/drivers/tds/qsql_tds.h
-
-SOURCES		= main.cpp \
-		  ../../../sql/drivers/tds/qsql_tds.cpp
-
-unix:!contains( LIBS, .*sybdb.* ):LIBS 	*= -lsybdb
-
-win32 {
-    !win32-borland:LIBS *= -lNTWDBLIB
-    win32-borland:LIBS 	*= $(BCB)/lib/PSDK/NTWDBLIB.LIB
-}
+SOURCES = main.cpp
+include(../../../sql/drivers/tds/qsql_tds.pri)
 
 include(../qsqldriverbase.pri)
diff --git a/src/sql/drivers/db2/qsql_db2.pri b/src/sql/drivers/db2/qsql_db2.pri
new file mode 100644
index 0000000..e53a8a0
--- /dev/null
+++ b/src/sql/drivers/db2/qsql_db2.pri
@@ -0,0 +1,8 @@
+HEADERS += $$PWD/qsql_db2.h
+SOURCES += $$PWD/qsql_db2.cpp
+
+unix {
+    !contains(LIBS, .*db2.*):LIBS *= -ldb2
+} else:!win32-borland {
+    !contains(LIBS, .*db2.*):LIBS *= -ldb2cli
+}
diff --git a/src/sql/drivers/drivers.pri b/src/sql/drivers/drivers.pri
index 05e7265..3af5525 100644
--- a/src/sql/drivers/drivers.pri
+++ b/src/sql/drivers/drivers.pri
@@ -1,119 +1,11 @@
-contains(sql-drivers, all ) {
-    sql-driver +=   psql mysql odbc oci tds db2 sqlite ibase
-}
-
-contains(sql-drivers, psql) {
-    HEADERS +=      drivers/psql/qsql_psql.h
-    SOURCES +=      drivers/psql/qsql_psql.cpp
-
-    unix|win32-g++* {
-        !static:!isEmpty(QT_LFLAGS_PSQL) {
-            !contains(QT_CONFIG, system-zlib): QT_LFLAGS_PSQL -= -lz
-            !static:LIBS *= $$QT_LFLAGS_PSQL
-            QMAKE_CXXFLAGS *= $$QT_CFLAGS_PSQL
-        }
-        !contains(LIBS, .*pq.*):LIBS *= -lpq
-    } else:win32:!contains(LIBS, .*pq.* ) LIBS *= -llibpq -lws2_32 -ladvapi32
-}
-
-contains(sql-drivers, mysql) {
-    HEADERS +=      drivers/mysql/qsql_mysql.h
-    SOURCES +=      drivers/mysql/qsql_mysql.cpp
-
-    unix {
-        isEmpty(QT_LFLAGS_MYSQL) {
-            !contains(LIBS, .*mysqlclient.*):!contains(LIBS, .*mysqld.*) {
-                use_libmysqlclient_r:LIBS *= -lmysqlclient_r
-                else:LIBS *= -lmysqlclient
-            }
-        } else {
-            LIBS *= $$QT_LFLAGS_MYSQL
-            QMAKE_CXXFLAGS *= $$QT_CFLAGS_MYSQL
-        }
-    }
-
-    win32:!contains(LIBS, .*mysql.*):!contains(LIBS, .*mysqld.*) {
-        !win32-g++*:LIBS *= -llibmysql
-        else:LIBS        *= -lmysql
-    }    
-}
-
-contains(sql-drivers, odbc) {
-     HEADERS += drivers/odbc/qsql_odbc.h
-     SOURCES += drivers/odbc/qsql_odbc.cpp
-
-     mac:!contains( LIBS, .*odbc.* ):LIBS        *= -liodbc
-     unix:!contains( LIBS, .*odbc.* ):LIBS       *= -lodbc
-     unix:DEFINES += UNICODE
-
-     win32 {
-         !win32-borland:LIBS *= -lodbc32
-         else:LIBS           *= $(BCB)/lib/PSDK/odbc32.lib
-     }
-}
-
-contains(sql-drivers, oci) {
-    HEADERS += drivers/oci/qsql_oci.h
-    SOURCES += drivers/oci/qsql_oci.cpp
-
-    unix:!contains( LIBS, .*clnts.* ):LIBS += -lclntsh
-
-    win32:LIBS += -loci
-}
-
-contains(sql-drivers, tds) {
-    HEADERS += drivers/tds/qsql_tds.h
-    SOURCES += drivers/tds/qsql_tds.cpp
-
-    unix:LIBS += -L$SYBASE/lib -lsybdb
-
-    win32 {
-        !win32-borland:LIBS += -lNTWDBLIB
-        else:LIBS           += $(BCB)/lib/PSDK/NTWDBLIB.LIB
-    }
-}
-
-contains(sql-drivers, db2) {
-    HEADERS += drivers/db2/qsql_db2.h
-    SOURCES += drivers/db2/qsql_db2.cpp
-    
-    unix:LIBS += -ldb2
-    
-    win32 {
-        !win32-borland:LIBS += -ldb2cli
-#        else:LIBS          += $(BCB)/lib/PSDK/db2cli.lib
-    }
-}
-
-contains(sql-drivers, ibase) {
-    HEADERS += drivers/ibase/qsql_ibase.h
-    SOURCES += drivers/ibase/qsql_ibase.cpp
-    
-    unix:LIBS *= -lgds  
-    
-    win32 {
-        !win32-borland:LIBS *= -lgds32_ms
-        else:LIBS           += gds32.lib
-    }
-}
-
-contains(sql-drivers, sqlite2) {
-    HEADERS += drivers/sqlite2/qsql_sqlite2.h
-    SOURCES += drivers/sqlite2/qsql_sqlite2.cpp
-    !contains(LIBS, .*sqlite.*):LIBS *= -lsqlite
-}
-
-contains(sql-drivers, sqlite) {
-    !system-sqlite:!contains( LIBS, .*sqlite3.* ) {
-        CONFIG(release, debug|release):DEFINES *= NDEBUG
-        DEFINES += SQLITE_OMIT_LOAD_EXTENSION SQLITE_OMIT_COMPLETE 
-        INCLUDEPATH +=  ../3rdparty/sqlite
-        SOURCES +=      ../3rdparty/sqlite/sqlite3.c
-    } else {
-        LIBS *= $$QT_LFLAGS_SQLITE
-        QMAKE_CXXFLAGS *= $$QT_CFLAGS_SQLITE
-    }
-
-    HEADERS +=      drivers/sqlite/qsql_sqlite.h
-    SOURCES +=      drivers/sqlite/qsql_sqlite.cpp
-}
+contains(sql-drivers, all):sql-driver += psql mysql odbc oci tds db2 sqlite ibase
+
+contains(sql-drivers, psql):include($$PWD/sqlite/qsql_psql.pri)
+contains(sql-drivers, mysql):include($$PWD/mysql/qsql_mysql.pri)
+contains(sql-drivers, odbc):include($$PWD/odbc/qsql_odbc.pri)
+contains(sql-drivers, oci):include($$PWD/oci/qsql_oci.pri)
+contains(sql-drivers, tds):include($$PWD/tds/qsql_tds.pri)
+contains(sql-drivers, db2):include($$PWD/db2/qsql_db2.pri)
+contains(sql-drivers, ibase):include($$PWD/db2/qsql_ibase.pri)
+contains(sql-drivers, sqlite2):include($$PWD/sqlite2/qsql_sqlite2.pri)
+contains(sql-drivers, sqlite):include($$PWD/sqlite/qsql_sqlite.pri)
diff --git a/src/sql/drivers/ibase/qsql_ibase.pri b/src/sql/drivers/ibase/qsql_ibase.pri
new file mode 100644
index 0000000..ebcd18a
--- /dev/null
+++ b/src/sql/drivers/ibase/qsql_ibase.pri
@@ -0,0 +1,11 @@
+HEADERS += $$PWD/qsql_ibase.h
+SOURCES += $$PWD/qsql_ibase.cpp
+
+unix {
+    !contains(LIBS, .*gds.*):!contains(LIBS, .*libfb.*):LIBS *= -lgds
+} else {
+    !contains(LIBS, .*gds.*):!contains(LIBS, .*fbclient.*) {
+        win32-borland:LIBS += gds32.lib
+        else:LIBS *= -lgds32_ms
+    }
+}
diff --git a/src/sql/drivers/mysql/qsql_mysql.pri b/src/sql/drivers/mysql/qsql_mysql.pri
new file mode 100644
index 0000000..801b891
--- /dev/null
+++ b/src/sql/drivers/mysql/qsql_mysql.pri
@@ -0,0 +1,16 @@
+HEADERS += $$PWD/qsql_mysql.h
+SOURCES += $$PWD/qsql_mysql.cpp
+
+unix {
+    isEmpty(QT_LFLAGS_MYSQL) {
+        !contains(LIBS, .*mysqlclient.*):!contains(LIBS, .*mysqld.*) {
+            use_libmysqlclient_r:LIBS *= -lmysqlclient_r
+            else:LIBS *= -lmysqlclient
+        }
+    } else {
+        LIBS *= $$QT_LFLAGS_MYSQL
+        QMAKE_CXXFLAGS *= $$QT_CFLAGS_MYSQL
+    }
+} else {
+    !contains(LIBS, .*mysql.*):!contains(LIBS, .*mysqld.*):LIBS *= -llibmysql
+}
diff --git a/src/sql/drivers/oci/qsql_oci.pri b/src/sql/drivers/oci/qsql_oci.pri
new file mode 100644
index 0000000..6859156
--- /dev/null
+++ b/src/sql/drivers/oci/qsql_oci.pri
@@ -0,0 +1,9 @@
+HEADERS += $$PWD/qsql_oci.h
+SOURCES += $$PWD/qsql_oci.cpp
+
+unix {
+    !contains(LIBS, .*clnts.*):LIBS *= -lclntsh
+} else {
+    LIBS *= -loci
+}
+macx:QMAKE_LFLAGS += -Wl,-flat_namespace,-U,_environ
diff --git a/src/sql/drivers/odbc/qsql_odbc.pri b/src/sql/drivers/odbc/qsql_odbc.pri
new file mode 100644
index 0000000..c4c92be
--- /dev/null
+++ b/src/sql/drivers/odbc/qsql_odbc.pri
@@ -0,0 +1,13 @@
+HEADERS += $$PWD/qsql_odbc.h
+SOURCES += $$PWD/qsql_odbc.cpp
+
+mac {
+    !contains(LIBS, .*odbc.*):LIBS *= -liodbc
+} else:unix {
+    DEFINES += UNICODE
+    !contains(LIBS, .*odbc.*):LIBS *= $$QT_LFLAGS_ODBC
+} else:win32-borland {
+    LIBS *= $(BCB)/lib/PSDK/odbc32.lib
+} else {
+    LIBS *= -lodbc32
+}
diff --git a/src/sql/drivers/psql/qsql_psql.pri b/src/sql/drivers/psql/qsql_psql.pri
new file mode 100644
index 0000000..c282d57
--- /dev/null
+++ b/src/sql/drivers/psql/qsql_psql.pri
@@ -0,0 +1,13 @@
+HEADERS += $$PWD/qsql_psql.h
+SOURCES += $$PWD/qsql_psql.cpp
+
+unix|win32-g++* {
+    !static:!isEmpty(QT_LFLAGS_PSQL) {
+        !contains(QT_CONFIG, system-zlib): QT_LFLAGS_PSQL -= -lz
+        LIBS *= $$QT_LFLAGS_PSQL
+        QMAKE_CXXFLAGS *= $$QT_CFLAGS_PSQL
+    }
+    !contains(LIBS, .*pq.*):LIBS *= -lpq
+} else {
+    !contains(LIBS, .*pq.*):LIBS *= -llibpq -lws2_32 -ladvapi32
+}
diff --git a/src/sql/drivers/sqlite/qsql_sqlite.pri b/src/sql/drivers/sqlite/qsql_sqlite.pri
new file mode 100644
index 0000000..7ad5936
--- /dev/null
+++ b/src/sql/drivers/sqlite/qsql_sqlite.pri
@@ -0,0 +1,9 @@
+HEADERS += $$PWD/qsql_sqlite.h
+SOURCES += $$PWD/qsql_sqlite.cpp
+
+!system-sqlite:!contains(LIBS, .*sqlite3.*) {
+    include($$PWD/../../../3rdparty/sqlite.pri)
+} else {
+    LIBS *= $$QT_LFLAGS_SQLITE
+    QMAKE_CXXFLAGS *= $$QT_CFLAGS_SQLITE
+}
diff --git a/src/sql/drivers/sqlite2/qsql_sqlite2.pri b/src/sql/drivers/sqlite2/qsql_sqlite2.pri
new file mode 100644
index 0000000..9f0e807
--- /dev/null
+++ b/src/sql/drivers/sqlite2/qsql_sqlite2.pri
@@ -0,0 +1,4 @@
+HEADERS += $PWD/qsql_sqlite2.h
+SOURCES += $PWD/qsql_sqlite2.cpp
+
+!contains(LIBS, .*sqlite.*):LIBS *= -lsqlite
diff --git a/src/sql/drivers/tds/qsql_tds.pri b/src/sql/drivers/tds/qsql_tds.pri
new file mode 100644
index 0000000..e2662ca
--- /dev/null
+++ b/src/sql/drivers/tds/qsql_tds.pri
@@ -0,0 +1,10 @@
+HEADERS += $$PWD/qsql_tds.h
+SOURCES += $$PWD/qsql_tds.cpp
+
+unix {
+    !contains(LIBS, .*sybdb.*):LIBS *= -lsybdb
+} else:win32-borland {
+    LIBS *= $(BCB)/lib/PSDK/NTWDBLIB.LIB
+} else {
+    LIBS *= -lNTWDBLIB
+}