Restructure the examples. They are now organized into various

subdirectories to make it easier to locate examples for certain
features (e.g. animation) and to distinguish between different types
of examples (e.g. very basic examples vs complex demo-like examples).

10 files changed, 286 insertions, 0 deletions

diff --git a/examples/declarative/keyinteraction/focus/Core/ContextMenu.qml b/examples/declarative/keyinteraction/focus/Core/ContextMenu.qml
new file mode 100644
index 0000000..49a54bc
--- /dev/null
+++ b/examples/declarative/keyinteraction/focus/Core/ContextMenu.qml
@@ -0,0 +1,18 @@
+import Qt 4.7
+
+FocusScope {
+    id: container
+
+    property bool open: false
+
+    Item {
+        anchors.fill: parent
+
+        Rectangle {
+            anchors.fill: parent
+            color: "#D1DBBD"
+            focus: true
+            Keys.onRightPressed: mainView.focus = true
+        }
+    }
+}
diff --git a/examples/declarative/keyinteraction/focus/Core/GridMenu.qml b/examples/declarative/keyinteraction/focus/Core/GridMenu.qml
new file mode 100644
index 0000000..3f727fd
--- /dev/null
+++ b/examples/declarative/keyinteraction/focus/Core/GridMenu.qml
@@ -0,0 +1,61 @@
+import Qt 4.7
+
+FocusScope {
+    property alias interactive: gridView.interactive
+
+    onWantsFocusChanged: if (wantsFocus) mainView.state = ""
+
+    Rectangle {
+        anchors.fill: parent
+        clip: true
+        gradient: Gradient {
+            GradientStop { position: 0.0; color: "#193441" }
+            GradientStop { position: 1.0; color: Qt.darker("#193441") }
+        }
+
+        GridView {
+            id: gridView
+            x: 20; width: parent.width - 40; height: parent.height
+            cellWidth: 152; cellHeight: 152
+            focus: true
+            model: 12
+            KeyNavigation.down: listViews
+            KeyNavigation.left: contextMenu
+
+            delegate: Item {
+                id: container
+                width: GridView.view.cellWidth; height: GridView.view.cellHeight
+
+                Rectangle {
+                    id: content
+                    color: "transparent"
+                    smooth: true
+                    anchors.centerIn: parent; width: container.width - 40; height: container.height - 40; radius: 10
+
+                    Rectangle { color: "#91AA9D"; x: 3; y: 3; width: parent.width - 6; height: parent.height - 6; radius: 8 }
+                    Image { source: "images/qt-logo.png"; anchors.centerIn: parent; smooth: true }
+                }
+
+                MouseArea {
+                    id: mouseArea
+                    anchors.fill: parent
+                    hoverEnabled: true
+
+                    onClicked: {
+                        GridView.view.currentIndex = index
+                        container.forceFocus()
+                    }
+                }
+
+                states: State {
+                    name: "active"; when: container.focus == true
+                    PropertyChanges { target: content; color: "#FCFFF5"; scale: 1.1 }
+                }
+
+                transitions: Transition {
+                    NumberAnimation { properties: "scale"; duration: 100 }
+                }
+            }
+        }
+    }
+}
diff --git a/examples/declarative/keyinteraction/focus/Core/ListViewDelegate.qml b/examples/declarative/keyinteraction/focus/Core/ListViewDelegate.qml
new file mode 100644
index 0000000..14e2548
--- /dev/null
+++ b/examples/declarative/keyinteraction/focus/Core/ListViewDelegate.qml
@@ -0,0 +1,40 @@
+import Qt 4.7
+
+Item {
+    id: container
+    x: 5; width: ListView.view.width - 10; height: 60
+
+    Rectangle {
+        id: content
+        anchors.centerIn: parent; width: container.width - 40; height: container.height - 10
+        color: "transparent"
+        smooth: true
+        radius: 10
+
+        Rectangle { color: "#91AA9D"; x: 3; y: 3; width: parent.width - 6; height: parent.height - 6; radius: 8 }
+        Text {
+            text: "List element " + (index + 1); color: "#193441"; font.bold: false; anchors.centerIn: parent
+            font.pixelSize: 14
+        }
+    }
+
+    MouseArea {
+        id: mouseArea
+        anchors.fill: parent
+        hoverEnabled: true
+
+        onClicked: {
+            ListView.view.currentIndex = index
+            container.forceFocus()
+        }
+    }
+
+    states: State {
+        name: "active"; when: container.focus == true
+        PropertyChanges { target: content; color: "#FCFFF5"; scale: 1.1 }
+    }
+
+    transitions: Transition {
+        NumberAnimation { properties: "scale"; duration: 100 }
+    }
+}
diff --git a/examples/declarative/keyinteraction/focus/Core/ListViews.qml b/examples/declarative/keyinteraction/focus/Core/ListViews.qml
new file mode 100644
index 0000000..32a5d4c
--- /dev/null
+++ b/examples/declarative/keyinteraction/focus/Core/ListViews.qml
@@ -0,0 +1,62 @@
+import Qt 4.7
+
+FocusScope {
+    clip: true
+
+    onWantsFocusChanged: if (wantsFocus) mainView.state = "showListViews"
+
+    ListView {
+        id: list1
+        y: wantsFocus ? 10 : 40; width: parent.width / 3; height: parent.height - 20
+        focus: true
+        KeyNavigation.up: gridMenu; KeyNavigation.left: contextMenu; KeyNavigation.right: list2
+        model: 10; cacheBuffer: 200
+        delegate: ListViewDelegate {}
+
+        Behavior on y {
+            NumberAnimation { duration: 600; easing.type: Easing.OutQuint }
+        }
+    }
+
+    ListView {
+        id: list2
+        y: wantsFocus ? 10 : 40; x: parent.width / 3; width: parent.width / 3; height: parent.height - 20
+        KeyNavigation.up: gridMenu; KeyNavigation.left: list1; KeyNavigation.right: list3
+        model: 10; cacheBuffer: 200
+        delegate: ListViewDelegate {}
+
+        Behavior on y {
+            NumberAnimation { duration: 600; easing.type: Easing.OutQuint }
+        }
+    }
+
+    ListView {
+        id: list3
+        y: wantsFocus ? 10 : 40; x: 2 * parent.width / 3; width: parent.width / 3; height: parent.height - 20
+        KeyNavigation.up: gridMenu; KeyNavigation.left: list2
+        model: 10; cacheBuffer: 200
+        delegate: ListViewDelegate {}
+
+        Behavior on y {
+            NumberAnimation { duration: 600; easing.type: Easing.OutQuint }
+        }
+    }
+
+    Rectangle { width: parent.width; height: 1; color: "#D1DBBD" }
+
+    Rectangle {
+        y: 1; width: parent.width; height: 10
+        gradient: Gradient {
+            GradientStop { position: 0.0; color: "#3E606F" }
+            GradientStop { position: 1.0; color: "transparent" }
+        }
+    }
+
+    Rectangle {
+        y: parent.height - 10; width: parent.width; height: 10
+        gradient: Gradient {
+            GradientStop { position: 1.0; color: "#3E606F" }
+            GradientStop { position: 0.0; color: "transparent" }
+        }
+    }
+}
diff --git a/examples/declarative/keyinteraction/focus/Core/images/arrow.png b/examples/declarative/keyinteraction/focus/Core/images/arrow.png
new file mode 100644
index 0000000..14978c2
--- /dev/null
+++ b/examples/declarative/keyinteraction/focus/Core/images/arrow.png
diff --git a/examples/declarative/keyinteraction/focus/Core/images/qt-logo.png b/examples/declarative/keyinteraction/focus/Core/images/qt-logo.png
new file mode 100644
index 0000000..14ddf2a
--- /dev/null
+++ b/examples/declarative/keyinteraction/focus/Core/images/qt-logo.png
diff --git a/examples/declarative/keyinteraction/focus/Core/qmldir b/examples/declarative/keyinteraction/focus/Core/qmldir
new file mode 100644
index 0000000..e25d63c
--- /dev/null
+++ b/examples/declarative/keyinteraction/focus/Core/qmldir
@@ -0,0 +1,4 @@
+ContextMenu ContextMenu.qml
+GridMenu GridMenu.qml
+ListViews ListViews.qml
+ListViewDelegate ListViewDelegate.qml
diff --git a/examples/declarative/keyinteraction/focus/focus.qml b/examples/declarative/keyinteraction/focus/focus.qml
new file mode 100644
index 0000000..8c992ae
--- /dev/null
+++ b/examples/declarative/keyinteraction/focus/focus.qml
@@ -0,0 +1,69 @@
+import Qt 4.7
+import "Core"
+
+Rectangle {
+    id: window
+    
+    width: 800; height: 480
+    color: "#3E606F"
+
+    FocusScope {
+        id: mainView
+
+        width: parent.width; height: parent.height
+        focus: true
+
+        GridMenu {
+            id: gridMenu
+
+            width: parent.width; height: 320
+            focus: true
+            interactive: parent.wantsFocus
+        }
+
+        ListViews {
+            id: listViews
+            y: 320; width: parent.width; height: 320
+        }
+
+        Rectangle { 
+            id: shade
+            color: "black"; opacity: 0; anchors.fill: parent
+        }
+
+        states: State {
+            name: "showListViews"
+            PropertyChanges { target: gridMenu; y: -160 }
+            PropertyChanges { target: listViews; y: 160 }
+        }
+
+        transitions: Transition {
+            NumberAnimation { properties: "y"; duration: 600; easing.type: Easing.OutQuint }
+        }
+    }
+
+    Image {
+        source: "Core/images/arrow.png"
+        rotation: 90
+        anchors.verticalCenter: parent.verticalCenter
+
+        MouseArea {
+            anchors { fill: parent; leftMargin: -10; topMargin: -10; rightMargin: -10; bottomMargin: -10 }
+            onClicked: window.state = "contextMenuOpen"
+        }
+    }
+
+    ContextMenu { id: contextMenu; x: -265; width: 260; height: parent.height }
+
+    states: State {
+        name: "contextMenuOpen"
+        when: !mainView.wantsFocus
+        PropertyChanges { target: contextMenu; x: 0; open: true }
+        PropertyChanges { target: mainView; x: 130 }
+        PropertyChanges { target: shade; opacity: 0.25 }
+    }
+
+    transitions: Transition {
+        NumberAnimation { properties: "x,opacity"; duration: 600; easing.type: Easing.OutQuint }
+    }
+}
diff --git a/examples/declarative/keyinteraction/focus/focus.qmlproject b/examples/declarative/keyinteraction/focus/focus.qmlproject
new file mode 100644
index 0000000..d4909f8
--- /dev/null
+++ b/examples/declarative/keyinteraction/focus/focus.qmlproject
@@ -0,0 +1,16 @@
+import QmlProject 1.0
+
+Project {
+    /* Include .qml, .js, and image files from current directory and subdirectories */
+    QmlFiles {
+        directory: "."
+    }
+    JavaScriptFiles {
+        directory: "."
+    }
+    ImageFiles {
+        directory: "."
+    }
+    /* List of plugin directories passed to QML runtime */
+    // importPaths: [ " ../exampleplugin " ]
+}
diff --git a/examples/declarative/keyinteraction/keyinteraction.qmlproject b/examples/declarative/keyinteraction/keyinteraction.qmlproject
new file mode 100644
index 0000000..d4909f8
--- /dev/null
+++ b/examples/declarative/keyinteraction/keyinteraction.qmlproject
@@ -0,0 +1,16 @@
+import QmlProject 1.0
+
+Project {
+    /* Include .qml, .js, and image files from current directory and subdirectories */
+    QmlFiles {
+        directory: "."
+    }
+    JavaScriptFiles {
+        directory: "."
+    }
+    ImageFiles {
+        directory: "."
+    }
+    /* List of plugin directories passed to QML runtime */
+    // importPaths: [ " ../exampleplugin " ]
+}