Merge branch '4.7' of scm.dev.nokia.troll.no:qt/qt-qml into 4.7-integration

* '4.7' of scm.dev.nokia.troll.no:qt/qt-qml:
  Move xmldata example into rssnews demo.
  Move Q_ENUMS to start of class declaration
  Restructure QDeclarativeAbstractBinding destructor
  Don't call pure virtual method in ~QDeclarativeAbstractBinding()
  Fix examples autotest when compiled without webkit or xmlpatterns
  Check for acquireReg() failure
  Focus should be applied to focus scopes all the way up the chain, not
  Add focus docs snippets
  Fix doc for status, add Image::onLoaded.
  Don't crash due to recursive positioning.
  ListModel::get() shouldn't print warnings for invalid indices since it
  Add \brief to TextInput
  Add missing .pro
  Restructure the examples. They are now organized into various
  graphicsWidgets doc example was previously removed
  Doc fix
  Add a "priority" property to Keys and KeyNavigation

6 files changed, 156 insertions, 0 deletions

diff --git a/examples/declarative/text/fonts/availableFonts.qml b/examples/declarative/text/fonts/availableFonts.qml
new file mode 100644
index 0000000..defa4ce
--- /dev/null
+++ b/examples/declarative/text/fonts/availableFonts.qml
@@ -0,0 +1,17 @@
+import Qt 4.7
+
+Rectangle {
+    width: 480; height: 640; color: "steelblue"
+
+    ListView {
+        anchors.fill: parent; model: Qt.fontFamilies()
+
+        delegate: Item {
+            height: 40; width: ListView.view.width
+            Text {
+                anchors.centerIn: parent
+                text: modelData; font.family: modelData; font.pixelSize: 24; color: "white"
+            }
+        }
+    }
+}
diff --git a/examples/declarative/text/fonts/banner.qml b/examples/declarative/text/fonts/banner.qml
new file mode 100644
index 0000000..353354a
--- /dev/null
+++ b/examples/declarative/text/fonts/banner.qml
@@ -0,0 +1,21 @@
+import Qt 4.7
+
+Rectangle {
+    id: screen
+
+    property int pixelSize: screen.height * 1.25
+    property color textColor: "lightsteelblue"
+    property string text: "Hello world! "
+
+    width: 640; height: 320
+    color: "steelblue"
+
+    Row {
+        y: -screen.height / 4.5
+
+        NumberAnimation on x { from: 0; to: -text.width; duration: 6000; loops: Animation.Infinite }
+        Text { id: text; font.pixelSize: screen.pixelSize; color: screen.textColor; text: screen.text }
+        Text { font.pixelSize: screen.pixelSize; color: screen.textColor; text: screen.text }
+        Text { font.pixelSize: screen.pixelSize; color: screen.textColor; text: screen.text }
+    }
+}
diff --git a/examples/declarative/text/fonts/fonts.qml b/examples/declarative/text/fonts/fonts.qml
new file mode 100644
index 0000000..f3eac48
--- /dev/null
+++ b/examples/declarative/text/fonts/fonts.qml
@@ -0,0 +1,64 @@
+import Qt 4.7
+
+Rectangle {
+    property string myText: "The quick brown fox jumps over the lazy dog."
+
+    width: 800; height: 480
+    color: "steelblue"
+
+    FontLoader { id: fixedFont; name: "Courier" }
+    FontLoader { id: localFont; source: "fonts/tarzeau_ocr_a.ttf" }
+    FontLoader { id: webFont; source: "http://www.princexml.com/fonts/steffmann/Starburst.ttf" }
+
+    Column {
+        anchors { fill: parent; leftMargin: 10; rightMargin: 10 }
+        spacing: 15
+
+        Text {
+            text: myText
+            color: "lightsteelblue"
+            width: parent.width
+            elide: Text.ElideRight
+            font.family: "Times"; font.pointSize: 42
+        }
+        Text {
+            text: myText
+            color: "lightsteelblue"
+            width: parent.width
+            elide: Text.ElideLeft
+            font { family: "Times"; pointSize: 42; capitalization: Font.AllUppercase }
+        }
+        Text {
+            text: myText
+            color: "lightsteelblue"
+            width: parent.width
+            elide: Text.ElideMiddle
+            font { family: fixedFont.name; pointSize: 42; weight: Font.Bold; capitalization: Font.AllLowercase }
+        }
+        Text {
+            text: myText
+            color: "lightsteelblue"
+            width: parent.width
+            elide: Text.ElideRight
+            font { family: fixedFont.name; pointSize: 42; italic: true; capitalization: Font.SmallCaps }
+        }
+        Text {
+            text: myText
+            color: "lightsteelblue"
+            width: parent.width
+            elide: Text.ElideLeft
+            font { family: localFont.name; pointSize: 42; capitalization: Font.Capitalize }
+        }
+        Text {
+            text: {
+                if (webFont.status == FontLoader.Ready) myText
+                else if (webFont.status == FontLoader.Loading) "Loading..."
+                else if (webFont.status == FontLoader.Error) "Error loading font"
+            }
+            color: "lightsteelblue"
+            width: parent.width
+            elide: Text.ElideMiddle
+            font.family: webFont.name; font.pointSize: 42
+        }
+    }
+}
diff --git a/examples/declarative/text/fonts/fonts.qmlproject b/examples/declarative/text/fonts/fonts.qmlproject
new file mode 100644
index 0000000..d4909f8
--- /dev/null
+++ b/examples/declarative/text/fonts/fonts.qmlproject
@@ -0,0 +1,16 @@
+import QmlProject 1.0
+
+Project {
+    /* Include .qml, .js, and image files from current directory and subdirectories */
+    QmlFiles {
+        directory: "."
+    }
+    JavaScriptFiles {
+        directory: "."
+    }
+    ImageFiles {
+        directory: "."
+    }
+    /* List of plugin directories passed to QML runtime */
+    // importPaths: [ " ../exampleplugin " ]
+}
diff --git a/examples/declarative/text/fonts/fonts/tarzeau_ocr_a.ttf b/examples/declarative/text/fonts/fonts/tarzeau_ocr_a.ttf
new file mode 100644
index 0000000..cf93f96
--- /dev/null
+++ b/examples/declarative/text/fonts/fonts/tarzeau_ocr_a.ttf
diff --git a/examples/declarative/text/fonts/hello.qml b/examples/declarative/text/fonts/hello.qml
new file mode 100644
index 0000000..0d6f4cd
--- /dev/null
+++ b/examples/declarative/text/fonts/hello.qml
@@ -0,0 +1,38 @@
+import Qt 4.7
+
+Rectangle {
+    id: screen
+
+    width: 800; height: 480
+    color: "black"
+
+    Item {
+        id: container
+        x: screen.width / 2; y: screen.height / 2
+
+        Text {
+            id: text
+            anchors.centerIn: parent
+            color: "white"
+            text: "Hello world!"
+            font.pixelSize: 60
+
+            SequentialAnimation on font.letterSpacing {
+                loops: Animation.Infinite;
+                NumberAnimation { from: 100; to: 300; easing.type: Easing.InQuad; duration: 3000 }
+                ScriptAction {
+                    script: {
+                        container.y = (screen.height / 4) + (Math.random() * screen.height / 2)
+                        container.x = (screen.width / 4) + (Math.random() * screen.width / 2)
+                    }
+                }
+            }
+
+            SequentialAnimation on opacity {
+                loops: Animation.Infinite;
+                NumberAnimation { from: 1; to: 0; duration: 2600 }
+                PauseAnimation { duration: 400 }
+            }
+        }
+    }
+}