Rename some examples: proxyviewer -> networkaccessmanagerfactory,

proxywidgets -> qwidgets, dynamic -> dynamicscene, velocity -> corkboards

15 files changed, 380 insertions, 0 deletions

diff --git a/examples/declarative/toys/dynamicscene/dynamicscene.qml b/examples/declarative/toys/dynamicscene/dynamicscene.qml
new file mode 100644
index 0000000..52c7c1e
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/dynamicscene.qml
@@ -0,0 +1,176 @@
+import Qt 4.7
+import Qt.labs.particles 1.0
+import "qml"
+
+Item {
+    id: window
+
+    property int activeSuns: 0
+
+    //This is a desktop-sized example
+    width: 1024; height: 512
+    
+    //This is the message box that pops up when there's an error
+    Rectangle {
+        id: dialog
+
+        opacity: 0
+        anchors.centerIn: parent
+        width: dialogText.width + 6; height: dialogText.height + 6
+        border.color: 'black'
+        color: 'lightsteelblue'
+        z: 65535 //Arbitrary number chosen to be above all the items, including the scaled perspective ones.
+
+        function show(str){
+            dialogText.text = str;
+            dialogAnim.start();
+        }
+
+        Text {
+            id: dialogText
+            x: 3; y: 3
+            font.pixelSize: 14
+        }
+
+        SequentialAnimation {
+            id: dialogAnim
+            NumberAnimation { target: dialog; property:"opacity"; to: 1; duration: 1000 }
+            PauseAnimation { duration: 5000 }
+            NumberAnimation { target: dialog; property:"opacity"; to: 0; duration: 1000 }
+        }
+    }
+
+    // sky
+    Rectangle {
+        id: sky
+        anchors { left: parent.left; top: parent.top; right: toolbox.right; bottom: parent.verticalCenter }
+        gradient: Gradient {
+            GradientStop { id: gradientStopA; position: 0.0; color: "#0E1533" }
+            GradientStop { id: gradientStopB; position: 1.0; color: "#437284" }
+        }
+    }
+
+    // stars (when there's no sun)
+    Particles {
+        id: stars
+        x: 0; y: 0; width: parent.width; height: parent.height / 2
+        source: "images/star.png"
+        angleDeviation: 360
+        velocity: 0; velocityDeviation: 0
+        count: parent.width / 10
+        fadeInDuration: 2800
+        opacity: 1
+    }
+
+    // ground
+    Rectangle {
+        id: ground
+        z: 2    // just above the sun so that the sun can set behind it
+        anchors { left: parent.left; top: parent.verticalCenter; right: toolbox.left; bottom: parent.bottom }
+        gradient: Gradient {
+            GradientStop { position: 0.0; color: "ForestGreen" }
+            GradientStop { position: 1.0; color: "DarkGreen" }
+        }
+    }
+
+    SystemPalette { id: activePalette }
+
+    // right-hand panel
+    Rectangle {
+        id: toolbox
+
+        width: 480
+        color: activePalette.window
+        anchors { right: parent.right; top: parent.top; bottom: parent.bottom }
+
+        Column {
+            anchors.centerIn: parent
+            spacing: 8
+
+            Text { text: "Drag an item into the scene." }
+
+            Rectangle {
+                width: childrenRect.width + 10; height: childrenRect.height + 10
+                border.color: "black"
+
+                Row {
+                    anchors.centerIn: parent
+                    spacing: 8
+
+                    PaletteItem {
+                        anchors.verticalCenter: parent.verticalCenter
+                        componentFile: "Sun.qml"
+                        image: "../images/sun.png"
+                    }
+                    PaletteItem {
+                        anchors.verticalCenter: parent.verticalCenter
+                        componentFile: "GenericSceneItem.qml"
+                        image: "../images/moon.png"
+                    }
+                    PaletteItem {
+                        anchors.verticalCenter: parent.verticalCenter
+                        componentFile: "PerspectiveItem.qml"
+                        image: "../images/tree_s.png"
+                    }
+                    PaletteItem {
+                        anchors.verticalCenter: parent.verticalCenter
+                        componentFile: "PerspectiveItem.qml"
+                        image: "../images/rabbit_brown.png"
+                    }
+                    PaletteItem {
+                        anchors.verticalCenter: parent.verticalCenter
+                        componentFile: "PerspectiveItem.qml"
+                        image: "../images/rabbit_bw.png"
+                    }
+                }
+            }
+
+            Text { text: "Active Suns: " + activeSuns }
+
+            Rectangle { width: parent.width; height: 1; color: "black" }
+
+            Text { text: "Arbitrary QML:" }
+
+            Rectangle {
+                width: 460; height: 240
+
+                TextEdit {
+                    id: qmlText
+                    anchors.fill: parent; anchors.margins: 5
+                    readOnly: false
+                    focusOnPress: true
+                    font.pixelSize: 14
+
+                    text: "import Qt 4.7\nImage {\n    id: smile\n    x: 500 * Math.random()\n    y: 200 * Math.random() \n    source: 'images/face-smile.png'\n\n    NumberAnimation on opacity { \n        to: 0; duration: 1500\n    }\n\n    Component.onCompleted: smile.destroy(1500);\n}"
+                }
+            }
+
+            Button {
+                text: "Create"
+                onClicked: {
+                    try { 
+                        Qt.createQmlObject(qmlText.text, window, 'CustomObject');
+                    } catch(err) {
+                        dialog.show('Error on line ' + err.qmlErrors[0].lineNumber + '\n' + err.qmlErrors[0].message);
+                    }
+                }
+            }
+        }
+    }
+
+    //Day state, for when a sun is added to the scene
+    states: State {
+        name: "Day"
+        when: window.activeSuns > 0
+
+        PropertyChanges { target: gradientStopA; color: "DeepSkyBlue" }
+        PropertyChanges { target: gradientStopB; color: "SkyBlue" }
+        PropertyChanges { target: stars; opacity: 0 }
+    }
+
+    transitions: Transition {
+        PropertyAnimation { duration: 3000 }
+        ColorAnimation { duration: 3000 }
+    }
+
+}
diff --git a/examples/declarative/toys/dynamicscene/dynamicscene.qmlproject b/examples/declarative/toys/dynamicscene/dynamicscene.qmlproject
new file mode 100644
index 0000000..d4909f8
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/dynamicscene.qmlproject
@@ -0,0 +1,16 @@
+import QmlProject 1.0
+
+Project {
+    /* Include .qml, .js, and image files from current directory and subdirectories */
+    QmlFiles {
+        directory: "."
+    }
+    JavaScriptFiles {
+        directory: "."
+    }
+    ImageFiles {
+        directory: "."
+    }
+    /* List of plugin directories passed to QML runtime */
+    // importPaths: [ " ../exampleplugin " ]
+}
diff --git a/examples/declarative/toys/dynamicscene/images/NOTE b/examples/declarative/toys/dynamicscene/images/NOTE
new file mode 100644
index 0000000..fcd87f9
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/images/NOTE
@@ -0,0 +1 @@
+Images (except star.png) are from the KDE project.
diff --git a/examples/declarative/toys/dynamicscene/images/face-smile.png b/examples/declarative/toys/dynamicscene/images/face-smile.png
new file mode 100644
index 0000000..3d66d72
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/images/face-smile.png
diff --git a/examples/declarative/toys/dynamicscene/images/moon.png b/examples/declarative/toys/dynamicscene/images/moon.png
new file mode 100644
index 0000000..1c0d606
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/images/moon.png
diff --git a/examples/declarative/toys/dynamicscene/images/rabbit_brown.png b/examples/declarative/toys/dynamicscene/images/rabbit_brown.png
new file mode 100644
index 0000000..ebfdeed
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/images/rabbit_brown.png
diff --git a/examples/declarative/toys/dynamicscene/images/rabbit_bw.png b/examples/declarative/toys/dynamicscene/images/rabbit_bw.png
new file mode 100644
index 0000000..7bff9b9
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/images/rabbit_bw.png
diff --git a/examples/declarative/toys/dynamicscene/images/star.png b/examples/declarative/toys/dynamicscene/images/star.png
new file mode 100644
index 0000000..27ef924
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/images/star.png
diff --git a/examples/declarative/toys/dynamicscene/images/sun.png b/examples/declarative/toys/dynamicscene/images/sun.png
new file mode 100644
index 0000000..7713ca5
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/images/sun.png
diff --git a/examples/declarative/toys/dynamicscene/images/tree_s.png b/examples/declarative/toys/dynamicscene/images/tree_s.png
new file mode 100644
index 0000000..6eac35a
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/images/tree_s.png
diff --git a/examples/declarative/toys/dynamicscene/qml/Button.qml b/examples/declarative/toys/dynamicscene/qml/Button.qml
new file mode 100644
index 0000000..963a850
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/qml/Button.qml
@@ -0,0 +1,40 @@
+import Qt 4.7
+
+Rectangle {
+    id: container
+
+    property variant text
+    signal clicked
+
+    height: text.height + 10; width: text.width + 20
+    border.width: 1
+    radius: 4
+    smooth: true
+
+    gradient: Gradient {
+        GradientStop {
+            position: 0.0
+            color: !mouseArea.pressed ? activePalette.light : activePalette.button
+        }
+        GradientStop {
+            position: 1.0
+            color: !mouseArea.pressed ? activePalette.button : activePalette.dark
+        }
+    }
+
+    SystemPalette { id: activePalette }
+
+    MouseArea {
+        id: mouseArea
+        anchors.fill: parent
+        onClicked: container.clicked()
+    }
+
+    Text {
+        id: text
+        anchors.centerIn:parent
+        font.pointSize: 10
+        text: parent.text
+        color: activePalette.buttonText
+    }
+}
diff --git a/examples/declarative/toys/dynamicscene/qml/PaletteItem.qml b/examples/declarative/toys/dynamicscene/qml/PaletteItem.qml
new file mode 100644
index 0000000..dcb5cc3
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/qml/PaletteItem.qml
@@ -0,0 +1,19 @@
+import Qt 4.7
+import "itemCreation.js" as Code
+
+Image {
+    id: paletteItem
+
+    property string componentFile
+    property string image
+
+    source: image
+
+    MouseArea { 
+        anchors.fill: parent
+
+        onPressed: Code.startDrag(mouse);
+        onPositionChanged: Code.continueDrag(mouse);
+        onReleased: Code.endDrag(mouse);
+    }
+}
diff --git a/examples/declarative/toys/dynamicscene/qml/PerspectiveItem.qml b/examples/declarative/toys/dynamicscene/qml/PerspectiveItem.qml
new file mode 100644
index 0000000..c04d3dc
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/qml/PerspectiveItem.qml
@@ -0,0 +1,25 @@
+import Qt 4.7
+
+Image {
+    id: rootItem
+
+    property bool created: false
+    property string image 
+
+    property double scaledBottom: y + (height + height*scale) / 2 
+    property bool onLand: scaledBottom > window.height / 2
+
+    source: image
+    opacity: onLand ? 1 : 0.25
+    scale: Math.max((y + height - 250) * 0.01, 0.3)
+    smooth: true
+
+    onCreatedChanged: {
+        if (created && !onLand)
+            rootItem.destroy();
+        else
+            z = scaledBottom;
+    }
+
+    onYChanged: z = scaledBottom;
+}
diff --git a/examples/declarative/toys/dynamicscene/qml/Sun.qml b/examples/declarative/toys/dynamicscene/qml/Sun.qml
new file mode 100644
index 0000000..43dcb9a
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/qml/Sun.qml
@@ -0,0 +1,38 @@
+import Qt 4.7
+
+Image {
+    id: sun
+
+    property bool created: false
+    property string image: "../images/sun.png"
+
+    source: image
+
+    // once item is created, start moving offscreen
+    NumberAnimation on y {
+        to: window.height / 2
+        running: created
+        onRunningChanged: {
+            if (running)
+                duration = (window.height - sun.y) * 10;
+            else
+                state = "OffScreen"
+        }
+    }
+
+    states: State {
+        name: "OffScreen"
+        StateChangeScript {
+            script: { sun.created = false; sun.destroy() }
+        }
+    }
+
+    onCreatedChanged: {
+        if (created) {
+            sun.z = 1;    // above the sky but below the ground layer 
+            window.activeSuns++;
+        } else {
+            window.activeSuns--;
+        }
+    }
+}
diff --git a/examples/declarative/toys/dynamicscene/qml/itemCreation.js b/examples/declarative/toys/dynamicscene/qml/itemCreation.js
new file mode 100644
index 0000000..59750f3
--- /dev/null
+++ b/examples/declarative/toys/dynamicscene/qml/itemCreation.js
@@ -0,0 +1,65 @@
+var itemComponent = null;
+var draggedItem = null;
+var startingMouse;
+var posnInWindow;
+
+function startDrag(mouse)
+{
+    posnInWindow = paletteItem.mapToItem(null, 0, 0);
+    startingMouse = { x: mouse.x, y: mouse.y }
+    loadComponent();
+}
+
+//Creation is split into two functions due to an asynchronous wait while
+//possible external files are loaded.
+
+function loadComponent() {
+    if (itemComponent != null) { // component has been previously loaded
+        createItem();
+        return;
+    }
+
+    itemComponent = Qt.createComponent(paletteItem.componentFile);
+    if (itemComponent.status == Component.Loading)  //Depending on the content, it can be ready or error immediately
+        component.statusChanged.connect(createItem);
+    else    
+        createItem();
+}
+
+function createItem() {
+    if (itemComponent.status == Component.Ready && draggedItem == null) {
+        draggedItem = itemComponent.createObject(window);
+        draggedItem.image = paletteItem.image;
+        draggedItem.x = posnInWindow.x;
+        draggedItem.y = posnInWindow.y;
+        draggedItem.z = 3;  // make sure created item is above the ground layer
+    } else if (itemComponent.status == Component.Error) {
+        draggedItem = null;
+        console.log("error creating component");
+        console.log(component.errorsString());
+    }
+}
+
+function continueDrag(mouse)
+{
+    if (draggedItem == null)
+        return;
+
+    draggedItem.x = mouse.x + posnInWindow.x - startingMouse.x;
+    draggedItem.y = mouse.y + posnInWindow.y - startingMouse.y;
+}
+
+function endDrag(mouse)
+{
+    if (draggedItem == null)
+        return;
+
+    if (draggedItem.x + draggedItem.width > toolbox.x) { //Don't drop it in the toolbox
+        draggedItem.destroy();
+        draggedItem = null;
+    } else {
+        draggedItem.created = true;
+        draggedItem = null;
+    }
+}
+