Merge commit 'qt/master-stable'

Conflicts:
	config.tests/unix/openssl/openssl.pri
	demos/embedded/embedded.pro
	examples/itemviews/chart/chart.pro
	examples/network/network.pro
	examples/painting/painterpaths/painterpaths.pro
	examples/threads/mandelbrot/mandelbrot.pro
	qmake/project.cpp
	src/3rdparty/libtiff/libtiff/tif_config.h
	src/corelib/arch/arch.pri
	src/corelib/global/qglobal.cpp
	src/corelib/kernel/kernel.pri
	src/corelib/kernel/qcore_unix_p.h
	src/corelib/kernel/qobject.cpp
	src/corelib/thread/qthread_unix.cpp
	src/corelib/tools/qsharedpointer_impl.h
	src/corelib/tools/tools.pri
	src/gui/kernel/qaction.h
	src/gui/kernel/qapplication.cpp
	src/gui/painting/qregion.h
	src/gui/widgets/qlineedit.cpp
	src/gui/widgets/qlineedit_p.h
	src/network/socket/qnativesocketengine_unix.cpp
	tests/auto/qdir/tst_qdir.cpp
	tests/auto/qdiriterator/tst_qdiriterator.cpp
	tests/auto/qhttp/qhttp.pro
	tests/auto/qline/qline.pro
	tests/auto/qnetworkreply/tst_qnetworkreply.cpp
	tests/auto/qresourceengine/qresourceengine.pro
	tests/auto/qsharedpointer/qsharedpointer.pro
	tests/auto/qstring/qstring.pro
	tests/auto/qtcpsocket/qtcpsocket.pro
	tests/auto/qtcpsocket/tst_qtcpsocket.cpp

1 files changed, 63 insertions, 0 deletions

diff --git a/mkspecs/features/vxworks.prf b/mkspecs/features/vxworks.prf
new file mode 100644
index 0000000..a910c69
--- /dev/null
+++ b/mkspecs/features/vxworks.prf
@@ -0,0 +1,63 @@
+# VxWorks Munching Feature
+# When compiling C++ sources on VxWorks in kernel mode, all .o files have to
+# be processed by the so-called 'munch' script which will generate
+# additional code for static c'tors and d'tors. The resulting .c file has to
+# be compiled in turn and linked to the executable.
+# This can only been done when linking applications, since the munch script
+# generates a .c file containing static symbols: linking a lib that was
+# already munched to a munched application would lead to duplicate symbols!
+
+isEmpty(VXWORKS_MUNCH_EXT):VXWORKS_MUNCH_EXT = vxm
+isEmpty(VXWORKS_MUNCH_TOOL):VXWORKS_MUNCH_TOOL = $(WIND_BASE)/host/resource/hutils/tcl/munch.tcl
+
+
+!exists($$VXWORKS_MUNCH_TOOL) {
+    error("Could not find VxWorks Munch tool: '$${VXWORKS_MUNCH_TOOL}'. Please set the environment variable WIND_BASE correctly.")
+}
+
+# The following scope is entered for any project that specifies 'shared' as well
+# as for any project specifying neither 'shared', nor 'lib', nor 'staticlib'.
+# This means that for a static build only the executable is munched, while for
+# a shared build, every lib, plugin and executable is munched separately.
+
+shared|!staticlib:!lib {
+    *-dcc {
+    VXWORKS_MUNCH_CMD = (targ=`basename $(TARGET)`; \
+                         ddump -Ng \"$(TARGET)\" | tclsh $$VXWORKS_MUNCH_TOOL -c $$VXWORKS_ARCH_MUNCH >\"$(OBJECTS_DIR)/\$\${targ}_ctdt.c\" && \
+                         $$QMAKE_CC -c $$QMAKE_CFLAGS \"$(OBJECTS_DIR)/\$\${targ}_ctdt.c\" -o \"$(OBJECTS_DIR)/\$\${targ}_ctdt.o\" && \
+                         $$QMAKE_LINK $$QMAKE_LFLAGS -X -r5 -r4 \"$(OBJECTS_DIR)/\$\${targ}_ctdt.o\" \"$(TARGET)\" -o \"$(TARGET).munched\" && \
+                         mv \"$(TARGET).munched\" \"$(TARGET)\" && \
+                         chmod +x \"$(TARGET)\")
+    }
+    *-g++ {
+    VXWORKS_MUNCH_CMD = (targ=`basename $(TARGET)`; \
+                         nm \"$(DESTDIR)$(TARGET)\" | tclsh $$VXWORKS_MUNCH_TOOL -c $$VXWORKS_ARCH_MUNCH >\"$(OBJECTS_DIR)/\$\${targ}_ctdt.c\" && \
+                         $$QMAKE_CC -c $$QMAKE_CFLAGS -fdollars-in-identifiers \"$(OBJECTS_DIR)/\$\${targ}_ctdt.c\" -o \"$(OBJECTS_DIR)/\$\${targ}_ctdt.o\" && \
+                         $$QMAKE_LINK $$QMAKE_LFLAGS -nostdlib -Wl,-X -T $(WIND_BASE)/target/h/tool/gnu/ldscripts/link.OUT \"$(OBJECTS_DIR)/\$\${targ}_ctdt.o\" \"$(DESTDIR)$(TARGET)\" -o \"$(DESTDIR)$(TARGET).munched\" && \
+                         mv \"$(DESTDIR)$(TARGET).munched\" \"$(DESTDIR)$(TARGET)\" && \
+                         chmod +x \"$(DESTDIR)$(TARGET)\")
+    }
+
+    # We need to create a dummy lib.a in case someone links against this lib.
+    # In VxWorks it's the responsibility of the run-time linker ld to resolve
+    # symbols, since there are no real shared libraries for the toolchain linker
+    # to link against.
+
+    shared:contains(TEMPLATE, lib) {
+        VXWORKS_MUNCH_CMD += "&&"
+        VXWORKS_MUNCH_CMD += (atarg=`basename $(TARGET) .so.$${VERSION}`.a ; touch \"$(DESTDIR)\$\${atarg}\")
+    }
+
+    QMAKE_POST_LINK = $$VXWORKS_MUNCH_CMD $$QMAKE_POST_LINK
+    silent:QMAKE_POST_LINK = @echo creating $@.$$VXWORKS_MUNCH_EXT && $$QMAKE_POST_LINK
+
+    isEmpty(DESTDIR) {
+        target.targets += "`basename $(TARGET)`.$$VXWORKS_MUNCH_EXT"
+        QMAKE_DISTCLEAN += "`basename $(TARGET)`.$$VXWORKS_MUNCH_EXT"
+    } else {
+        target.targets += "$(DESTDIR)/`basename $(TARGET)`.$$VXWORKS_MUNCH_EXT"
+        QMAKE_DISTCLEAN += "$(DESTDIR)/`basename $(TARGET)`.$$VXWORKS_MUNCH_EXT"
+    }
+    *-g++:LIBS += -lgcc
+}
+