Initial import of statemachine branch from the old kinetic repository

1 files changed, 64 insertions, 0 deletions

diff --git a/mkspecs/features/win32/qaxserver.prf b/mkspecs/features/win32/qaxserver.prf
new file mode 100644
index 0000000..a18c421
--- /dev/null
+++ b/mkspecs/features/win32/qaxserver.prf
@@ -0,0 +1,64 @@
+build_pass:console: {
+    warning("QAxServer applications cannot be console applications.")
+    warning("Remove 'console' from your CONFIG.")
+}
+
+ACTIVEQT_VERSION = $$VERSION
+isEmpty(ACTIVEQT_VERSION):ACTIVEQT_VERSION = 1.0
+
+DEFINES += QAXSERVER
+
+ACTIVEQT_IDE = makefile
+equals(TEMPLATE_PREFIX, "vc"):ACTIVEQT_IDE = VisualStudio
+equals(TEMPLATE, "vcapp"):ACTIVEQT_IDE = VisualStudio
+equals(TEMPLATE, "vclib"):ACTIVEQT_IDE = VisualStudio
+
+equals(ACTIVEQT_IDE, "VisualStudio") {
+    ACTIVEQT_IDC = $${QMAKE_IDC}
+    ACTIVEQT_IDL = $${QMAKE_IDL}
+    ACTIVEQT_TARGET = "$(TargetPath)"
+    win32-msvc {
+        ACTIVEQT_NEWLINE = $$escape_expand(\t)
+        ACTIVEQT_OUTPUT = $(IntDir)/$${TARGET}
+    } else {
+        ACTIVEQT_NEWLINE = $$escape_expand(\n\t)
+        ACTIVEQT_OUTPUT = $(IntDir)$${TARGET}
+    }
+    ACTIVEQT_TLBOUT = "$(TargetDir)/$${TARGET}.tlb"
+    GENERATED += $${OBJECTS_DIR}/$${TARGET}.idl $${ACTIVEQT_TLBOUT}
+}
+equals(ACTIVEQT_IDE, "makefile") {
+    ACTIVEQT_IDC = -$(IDC)
+    ACTIVEQT_IDL = -$(IDL)
+    ACTIVEQT_NEWLINE = $$escape_expand(\n\t)
+    ACTIVEQT_TARGET = $(DESTDIR_TARGET)
+    ACTIVEQT_OUTPUT = $(OBJECTS_DIR)/$${TARGET}
+    isEmpty(DESTDIR) {
+        ACTIVEQT_TLBOUT = $${TARGET}.tlb
+    } else {
+        ACTIVEQT_TLBOUT = $${DESTDIR}/$${TARGET}.tlb
+    }
+}
+
+!qaxserver_no_postlink {
+    !isEmpty(QMAKE_POST_LINK):QMAKE_POST_LINK += $$quote($$ACTIVEQT_NEWLINE)
+    QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /idl $${ACTIVEQT_OUTPUT}.idl -version $${ACTIVEQT_VERSION}$${ACTIVEQT_NEWLINE})
+    !isEmpty(RC_FILE) {
+        QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDL "$${ACTIVEQT_OUTPUT}.idl" /nologo /tlb "$${ACTIVEQT_OUTPUT}.tlb"$$ACTIVEQT_NEWLINE)
+        QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /tlb $${ACTIVEQT_OUTPUT}.tlb$$ACTIVEQT_NEWLINE)
+    } else {
+        QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDL "$${ACTIVEQT_OUTPUT}.idl" /nologo /tlb "$${ACTIVEQT_TLBOUT}"$$ACTIVEQT_NEWLINE)
+        message("No rc-file linked into project; type library will be a separate file.")
+    }
+    QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /regserver)
+    QMAKE_CLEAN += $${ACTIVEQT_OUTPUT}.idl $${ACTIVEQT_OUTPUT}.tlb
+}
+
+qt:!target_qt {
+   CONFIG(debug, debug|release) {
+      QMAKE_LIBS_QT_ENTRY = -lQAxServerd
+   } else { 
+      QMAKE_LIBS_QT_ENTRY = -lQAxServer
+   }
+   dll:QMAKE_LIBS += $$QMAKE_LIBS_QT_ENTRY
+}