Extend the build system to SSSE3

Extend the build of QtGui to include generic compilation of files
specific to SSSE3.

Also extend qsimd_p.h for the new #includes.

1 files changed, 20 insertions, 0 deletions

diff --git a/src/gui/gui.pro b/src/gui/gui.pro
index 3aee078..1b43ef2 100644
--- a/src/gui/gui.pro
+++ b/src/gui/gui.pro
@@ -187,6 +187,25 @@ contains(QMAKE_MAC_XARCH, no) {
             silent:sse2_compiler.commands = @echo compiling[sse2] ${QMAKE_FILE_IN} && $$sse2_compiler.commands
             QMAKE_EXTRA_COMPILERS += sse2_compiler
         }
+        ssse3 {
+            ssse3_compiler.commands = $$QMAKE_CXX -c -Winline
+
+            mac {
+                ssse3_compiler.commands += -Xarch_i386 -mssse3
+                ssse3_compiler.commands += -Xarch_x86_64 -mssse3
+            } else {
+                ssse3_compiler.commands += -mssse3
+            }
+
+            ssse3_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
+            ssse3_compiler.dependency_type = TYPE_C
+            ssse3_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
+            ssse3_compiler.input = SSSE3_SOURCES
+            ssse3_compiler.variable_out = OBJECTS
+            ssse3_compiler.name = compiling[ssse3] ${QMAKE_FILE_IN}
+            silent:ssse3_compiler.commands = @echo compiling[ssse3] ${QMAKE_FILE_IN} && $$ssse3_compiler.commands
+            QMAKE_EXTRA_COMPILERS += ssse3_compiler
+        }
         iwmmxt {
             iwmmxt_compiler.commands = $$QMAKE_CXX -c -Winline
             iwmmxt_compiler.commands += -mcpu=iwmmxt
@@ -205,6 +224,7 @@ contains(QMAKE_MAC_XARCH, no) {
         3dnow:sse: SOURCES += $$SSE3DNOW_SOURCES
         sse: SOURCES += $$SSE_SOURCES
         sse2: SOURCES += $$SSE2_SOURCES
+        ssse3: SOURCES += $$SSSE3_SOURCES
         iwmmxt: SOURCES += $$IWMMXT_SOURCES
     }
 }