1 files changed, 124 insertions, 0 deletions
diff --git a/demos/declarative/flickr/mobile/ImageDetails.qml b/demos/declarative/flickr/mobile/ImageDetails.qml
new file mode 100644
index 0000000..9116428
--- /dev/null
+++ b/demos/declarative/flickr/mobile/ImageDetails.qml
@@ -0,0 +1,124 @@
+import Qt 4.6
+import "../common" as Common
+
+Flipable {
+    id: container
+
+    property var frontContainer: containerFront
+    property string photoTitle: ""
+    property string photoTags: ""
+    property int photoWidth
+    property int photoHeight
+    property string photoType
+    property string photoAuthor
+    property string photoDate
+    property string photoUrl
+    property int rating: 2
+    property var prevScale: 1.0
+
+    signal closed
+
+    transform: Rotation {
+        id: itemRotation
+        origin.x: container.width / 2;
+        axis.y: 1; axis.z: 0
+    }
+
+    front: Item {
+        id: containerFront; anchors.fill: container
+
+        Rectangle {
+            anchors.fill: parent
+            color: "black"; opacity: 0.4
+        }
+
+        Column {
+            spacing: 10
+            anchors {
+                left: parent.left; leftMargin: 20
+                right: parent.right; rightMargin: 20
+                top: parent.top; topMargin: 180
+            }
+            Text { font.bold: true; color: "white"; elide: Text.ElideRight; text: container.photoTitle }
+            Text { color: "white"; elide: Text.ElideRight; text: "<b>Size:</b> " + container.photoWidth + 'x' + container.photoHeight }
+            Text { color: "white"; elide: Text.ElideRight; text: "<b>Type:</b> " + container.photoType }
+            Text { color: "white"; elide: Text.ElideRight; text: "<b>Author:</b> " + container.photoAuthor }
+            Text { color: "white"; elide: Text.ElideRight; text: "<b>Published:</b> " + container.photoDate }
+            Text { color: "white"; elide: Text.ElideRight; text: container.photoTags == "" ? "" : "<b>Tags:</b> " }
+            Text { color: "white"; elide: Text.ElideRight; elide: Text.ElideRight; text: container.photoTags }
+        }
+    }
+
+    back: Item {
+        anchors.fill: container
+
+        Rectangle { anchors.fill: parent; color: "black"; opacity: 0.4 }
+
+        Common.Progress { anchors.centerIn: parent; width: 200; height: 18; progress: bigImage.progress; visible: bigImage.status!=1 }
+        Flickable {
+            id: flickable; anchors.fill: parent; clip: true
+            viewportWidth: imageContainer.width; viewportHeight: imageContainer.height
+
+            Item {
+                id: imageContainer
+                width: Math.max(bigImage.width * bigImage.scale, flickable.width);
+                height: Math.max(bigImage.height * bigImage.scale, flickable.height);
+
+                Image {
+                    id: bigImage; source: container.photoUrl; scale: slider.value
+                    // Center image if it is smaller than the flickable area.
+                    x: imageContainer.width > width*scale ? (imageContainer.width - width*scale) / 2 : 0
+                    y: imageContainer.height > height*scale ? (imageContainer.height - height*scale) / 2 : 0
+                    smooth: !flickable.moving
+                    onStatusChanged : {
+                        // Default scale shows the entire image.
+                        if (status == 1 && width != 0) {
+                            slider.minimum = Math.min(flickable.width / width, flickable.height / height);
+                            prevScale = Math.min(slider.minimum, 1);
+                            slider.value = prevScale;
+                        }
+                    }
+                }
+            }
+        }
+
+        Text {
+            text: "Image Unavailable"
+            visible: bigImage.status == 'Error'
+            anchors.centerIn: parent; color: "white"; font.bold: true
+        }
+
+        Common.Slider {
+            id: slider; visible: { bigImage.status == 1 && maximum > minimum }
+            anchors {
+                bottom: parent.bottom; bottomMargin: 65
+                left: parent.left; leftMargin: 25
+                right: parent.right; rightMargin: 25
+            }
+            onValueChanged: {
+                if (bigImage.width * value > flickable.width) {
+                    var xoff = (flickable.width/2 + flickable.viewportX) * value / prevScale;
+                    flickable.viewportX = xoff - flickable.width/2;
+                }
+                if (bigImage.height * value > flickable.height) {
+                    var yoff = (flickable.height/2 + flickable.viewportY) * value / prevScale;
+                    flickable.viewportY = yoff - flickable.height/2;
+                }
+                prevScale = value;
+            }
+        }
+    }
+
+    states: State {
+        name: "Back"
+        PropertyChanges { target: itemRotation; angle: 180 }
+    }
+
+    transitions: Transition {
+        SequentialAnimation {
+            PropertyAction { target: bigImage; property: "smooth"; value: false }
+            NumberAnimation { easing: "easeInOutQuad"; matchProperties: "angle"; duration: 500 }
+            PropertyAction { target: bigImage; property: "smooth"; value: !flickable.moving }
+        }
+    }
+}