2 files changed, 129 insertions, 0 deletions
diff --git a/examples/declarative/modelviews/parallax/qml/ParallaxView.qml b/examples/declarative/modelviews/parallax/qml/ParallaxView.qml
new file mode 100644
index 0000000..e869a21
--- /dev/null
+++ b/examples/declarative/modelviews/parallax/qml/ParallaxView.qml
@@ -0,0 +1,83 @@
+import Qt 4.7
+
+Item {
+    id: root
+
+    property alias background: background.source
+    default property alias content: visualModel.children
+    property int currentIndex: 0
+
+    Image {
+        id: background
+        fillMode: Image.TileHorizontally
+        x: -list.contentX / 2
+        width: Math.max(list.contentWidth, parent.width)
+    }
+
+    ListView {
+        id: list
+
+        currentIndex: root.currentIndex
+        onCurrentIndexChanged: root.currentIndex = currentIndex
+
+        orientation: Qt.Horizontal
+        boundsBehavior: Flickable.DragOverBounds
+        anchors.fill: parent
+        model: VisualItemModel { id: visualModel }
+
+        highlightRangeMode: ListView.StrictlyEnforceRange
+        snapMode: ListView.SnapOneItem
+    }
+
+    ListView {
+        id: selector
+
+        Rectangle {
+            color: "#60FFFFFF"
+            x: -10; y: -10; radius: 10; z: -1
+            width: parent.width + 20; height: parent.height + 20
+        }
+        currentIndex: root.currentIndex
+        onCurrentIndexChanged: root.currentIndex = currentIndex
+
+        height: 50
+        anchors.bottom: parent.bottom
+        anchors.horizontalCenter: parent.horizontalCenter
+        width: Math.min(count * 50, parent.width - 20)
+        interactive: width == parent.width - 20
+        orientation: Qt.Horizontal
+
+        delegate: Item {
+            width: 50; height: 50
+            id: delegateRoot
+
+            Image {
+                id: image
+                source: modelData.icon
+                smooth: true
+                scale: 0.8
+            }
+
+            MouseArea {
+                anchors.fill: parent
+                onClicked: { root.currentIndex = index }
+            }
+
+            states: State {
+                name: "Selected"
+                when: delegateRoot.ListView.isCurrentItem == true
+                PropertyChanges {
+                    target: image
+                    scale: 1
+                    y: -5
+                }
+            }
+            transitions: Transition {
+                NumberAnimation {
+                    properties: "scale,y"
+                }
+             }
+        }
+        model: visualModel.children
+    }
+}
diff --git a/examples/declarative/modelviews/parallax/qml/Smiley.qml b/examples/declarative/modelviews/parallax/qml/Smiley.qml
new file mode 100644
index 0000000..662addc
--- /dev/null
+++ b/examples/declarative/modelviews/parallax/qml/Smiley.qml
@@ -0,0 +1,46 @@
+import Qt 4.7
+
+Item {
+    id: window
+    width: 320; height: 480
+
+    // The shadow for the smiley face
+    Image {
+        anchors.horizontalCenter: parent.horizontalCenter
+        source: "../pics/shadow.png"; y: smiley.minHeight + 58
+
+        // The scale property depends on the y position of the smiley face.
+        scale: smiley.y * 0.5 / (smiley.minHeight - smiley.maxHeight)
+    }
+
+    Image {
+        id: smiley
+        property int maxHeight: window.height / 3
+        property int minHeight: 2 * window.height / 3
+
+        anchors.horizontalCenter: parent.horizontalCenter
+        source: "../pics/face-smile.png"; y: minHeight
+
+        // Animate the y property. Setting repeat to true makes the
+        // animation repeat indefinitely, otherwise it would only run once.
+        SequentialAnimation  on y {
+            loops: Animation.Infinite
+
+            // Move from minHeight to maxHeight in 300ms, using the OutExpo easing function
+            NumberAnimation {
+                from: smiley.minHeight; to: smiley.maxHeight
+                easing.type: Easing.OutExpo; duration: 300
+            }
+
+            // Then move back to minHeight in 1 second, using the OutBounce easing function
+            NumberAnimation {
+                from: smiley.maxHeight; to: smiley.minHeight
+                easing.type: Easing.OutBounce; duration: 1000
+            }
+
+            // Then pause for 500ms
+            PauseAnimation { duration: 500 }
+        }
+    }
+}
+