1 files changed, 33 insertions, 0 deletions
diff --git a/src/plugins/bearer/symbian/symbian.pro b/src/plugins/bearer/symbian/symbian.pro
new file mode 100644
index 0000000..d3ffb37
--- /dev/null
+++ b/src/plugins/bearer/symbian/symbian.pro
@@ -0,0 +1,33 @@
+TARGET = qsymbianbearer
+include(../../qpluginbase.pri)
+
+QT += network
+
+HEADERS += symbianengine.h
+SOURCES += symbianengine.cpp main.cpp
+
+exists($${EPOCROOT}epoc32/release/winscw/udeb/cmmanager.lib)| \
+exists($${EPOCROOT}epoc32/release/armv5/lib/cmmanager.lib) {
+    message("Building with SNAP support")
+    DEFINES += SNAP_FUNCTIONALITY_AVAILABLE
+    LIBS += -lcmmanager
+} else {
+    message("Building without SNAP support")
+    LIBS += -lapengine
+}
+
+INCLUDEPATH += $$APP_LAYER_SYSTEMINCLUDE
+
+LIBS += -lcommdb \
+        -lapsettingshandlerui \
+        -lconnmon \
+        -lcentralrepository \
+        -lesock \
+        -linsock \
+        -lecom \
+        -lefsrv \
+        -lnetmeta
+
+QTDIR_build:DESTDIR = $$QT_BUILD_TREE/plugins/bearer
+target.path += $$[QT_INSTALL_PLUGINS]/bearer
+INSTALLS += target