4 files changed, 131 insertions, 0 deletions
diff --git a/src/plugins/phonon/mmf/mmf.pro b/src/plugins/phonon/mmf/mmf.pro
new file mode 100644
index 0000000..ff27ea1
--- /dev/null
+++ b/src/plugins/phonon/mmf/mmf.pro
@@ -0,0 +1,4 @@
+TEMPLATE    = subdirs
+SUBDIRS     = mmfphonondebug plugin
+
+plugin.depends = mmfphonondebug
diff --git a/src/plugins/phonon/mmf/mmfphonondebug/mmfphonondebug.pro b/src/plugins/phonon/mmf/mmfphonondebug/mmfphonondebug.pro
new file mode 100644
index 0000000..2cfec15
--- /dev/null
+++ b/src/plugins/phonon/mmf/mmfphonondebug/mmfphonondebug.pro
@@ -0,0 +1,31 @@
+TEMPLATE = lib
+TARGET = phonon_mmf_debug
+OBJECTDUMP_DIR = $$QT_SOURCE_TREE/src/3rdparty/phonon/mmf/mmfphonondebug
+
+CONFIG += staticlib
+
+DEFINES += OBJECTDUMP_LIBRARY
+
+HEADERS +=					\
+	$$OBJECTDUMP_DIR/objectdump_global.h 	\
+	$$OBJECTDUMP_DIR/objectdump.h		\
+	$$OBJECTDUMP_DIR/objecttree.h
+
+SOURCES += 					\
+	$$OBJECTDUMP_DIR/objectdump.cpp 	\
+	$$OBJECTDUMP_DIR/objecttree.cpp
+
+symbian {
+	HEADERS += $$OBJECTDUMP_DIR/objectdump_symbian.h
+	SOURCES += $$OBJECTDUMP_DIR/objectdump_symbian.cpp
+
+	LIBS += -lcone
+	LIBS += -lws32
+
+	TARGET.CAPABILITY = all -tcb
+
+} else {
+	SOURCES += $$OBJECTDUMP_DIR/objectdump_stub.cpp
+}
+
+TARGET.UID3=0x2001E62A
diff --git a/src/plugins/phonon/mmf/plugin/plugin.pro b/src/plugins/phonon/mmf/plugin/plugin.pro
new file mode 100644
index 0000000..de108a6
--- /dev/null
+++ b/src/plugins/phonon/mmf/plugin/plugin.pro
@@ -0,0 +1,95 @@
+# MMF Phonon backend
+
+QT += phonon
+TARGET = phonon_mmf
+PHONON_MMF_DIR = $$QT_SOURCE_TREE/src/3rdparty/phonon/mmf
+
+# Uncomment the following line in order to use the CDrmPlayerUtility client
+# API for audio playback, rather than CMdaAudioPlayerUtility.
+#CONFIG += phonon_mmf_audio_drm
+
+phonon_mmf_audio_drm {
+    LIBS += -lDrmAudioPlayUtility
+
+    DEFINES += QT_PHONON_MMF_AUDIO_DRM
+} else {
+    LIBS += -lmediaclientaudio
+}
+
+# In the internal 5th SDK, DrmAudioSamplePlayer.h is placed in this folder, as
+# opposed to the public, where it is placed in epoc32/include. In some cases
+# it's needed for other headers as well.
+INCLUDEPATH += $$MW_LAYER_SYSTEMINCLUDE
+
+HEADERS +=                                           \
+           $$PHONON_MMF_DIR/abstractaudioeffect.h    \
+           $$PHONON_MMF_DIR/abstractmediaplayer.h    \
+           $$PHONON_MMF_DIR/abstractplayer.h         \
+           $$PHONON_MMF_DIR/audiooutput.h            \
+           $$PHONON_MMF_DIR/audioequalizer.h         \
+           $$PHONON_MMF_DIR/audioplayer.h            \
+           $$PHONON_MMF_DIR/backend.h                \
+           $$PHONON_MMF_DIR/bassboost.h              \
+           $$PHONON_MMF_DIR/defs.h                   \
+           $$PHONON_MMF_DIR/dummyplayer.h            \
+           $$PHONON_MMF_DIR/effectfactory.h          \
+           $$PHONON_MMF_DIR/mmf_medianode.h          \
+           $$PHONON_MMF_DIR/mediaobject.h            \
+           $$PHONON_MMF_DIR/utils.h                  \
+           $$PHONON_MMF_DIR/videooutput.h            \
+           $$PHONON_MMF_DIR/videooutputobserver.h    \
+           $$PHONON_MMF_DIR/mmf_videoplayer.h        \
+           $$PHONON_MMF_DIR/videowidget.h            \
+           $$PHONON_MMF_DIR/volumeobserver.h
+
+SOURCES +=                                           \
+           $$PHONON_MMF_DIR/abstractaudioeffect.cpp  \
+           $$PHONON_MMF_DIR/abstractmediaplayer.cpp  \
+           $$PHONON_MMF_DIR/abstractplayer.cpp       \
+           $$PHONON_MMF_DIR/audiooutput.cpp          \
+           $$PHONON_MMF_DIR/audioequalizer.cpp       \
+           $$PHONON_MMF_DIR/audioplayer.cpp          \
+           $$PHONON_MMF_DIR/backend.cpp              \
+           $$PHONON_MMF_DIR/bassboost.cpp            \
+           $$PHONON_MMF_DIR/dummyplayer.cpp          \
+           $$PHONON_MMF_DIR/effectfactory.cpp        \
+           $$PHONON_MMF_DIR/mmf_medianode.cpp        \
+           $$PHONON_MMF_DIR/mediaobject.cpp          \
+           $$PHONON_MMF_DIR/utils.cpp                \
+           $$PHONON_MMF_DIR/videooutput.cpp          \
+           $$PHONON_MMF_DIR/mmf_videoplayer.cpp      \
+           $$PHONON_MMF_DIR/videowidget.cpp
+
+debug {
+    INCLUDEPATH += $$PHONON_MMF_DIR/mmfphonondebug
+    LIBS += -lphonon_mmf_debug.lib
+    LIBS += -lhal
+}
+
+LIBS += -lmediaclientvideo  # For CVideoPlayerUtility
+LIBS += -lcone              # For CCoeEnv
+LIBS += -lws32              # For RWindow
+LIBS += -lefsrv             # For file server
+LIBS += -lapgrfx -lapmime   # For recognizer
+
+# *** Temporary hack, necessitated by
+# inline QSymbianControl::setTransparentBlit
+LIBS += -lfbscli
+
+# These are for effects.
+LIBS += -lAudioEqualizerEffect -lBassBoostEffect -lDistanceAttenuationEffect -lDopplerBase -lEffectBase -lEnvironmentalReverbEffect -lListenerDopplerEffect -lListenerLocationEffect -lListenerOrientationEffect -lLocationBase -lLoudnessEffect -lOrientationBase -lSourceDopplerEffect -lSourceLocationEffect -lSourceOrientationEffect -lStereoWideningEffect
+
+# This is needed for having the .qtplugin file properly created on Symbian.
+QTDIR_build:DESTDIR = $$QT_BUILD_TREE/plugins/phonon_backend
+
+target.path = $$[QT_INSTALL_PLUGINS]/phonon_backend
+INSTALLS += target
+
+include(../../../qpluginbase.pri)
+
+# We need this to be able to resolve ambiguity for VideoPlayer.h. Phonon and
+# the SDK has the header.
+INCLUDEPATH *= /epoc32
+
+TARGET.UID3=0x2001E629
+
diff --git a/src/plugins/phonon/phonon.pro b/src/plugins/phonon/phonon.pro
index e43a4c2..814a062 100644
--- a/src/plugins/phonon/phonon.pro
+++ b/src/plugins/phonon/phonon.pro
@@ -7,3 +7,4 @@ mac:contains(QT_CONFIG, phonon-backend): SUBDIRS *= qt7
 win32:!wince*:contains(QT_CONFIG, phonon-backend): SUBDIRS *= ds9
 wince*:contains(QT_CONFIG, phonon-backend): SUBDIRS *= waveout
 wince*:contains(QT_CONFIG, directshow): SUBDIRS *= ds9
+symbian:contains(QT_CONFIG, phonon-backend): SUBDIRS *= mmf