1 files changed, 32 insertions, 0 deletions
diff --git a/src/qt_install.pri b/src/qt_install.pri
new file mode 100644
index 0000000..6dd2074
--- /dev/null
+++ b/src/qt_install.pri
@@ -0,0 +1,32 @@
+#always install the library
+win32 {
+   dlltarget.path=$$[QT_INSTALL_BINS]
+   INSTALLS += dlltarget
+}
+target.path=$$[QT_INSTALL_LIBS]
+INSTALLS += target
+
+#headers
+qt_install_headers {
+    INSTALL_HEADERS = $$SYNCQT.HEADER_FILES
+    equals(TARGET, QtCore) {
+       #headers generated by configure
+       INSTALL_HEADERS *= $$QT_BUILD_TREE/src/corelib/global/qconfig.h \
+                          $$QT_SOURCE_TREE/src/corelib/arch/$$QT_ARCH/arch
+    }
+
+    flat_headers.files = $$INSTALL_HEADERS
+    flat_headers.path = $$[QT_INSTALL_HEADERS]/Qt
+    INSTALLS += flat_headers
+
+    targ_headers.files = $$INSTALL_HEADERS $$SYNCQT.HEADER_CLASSES
+    targ_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET
+    INSTALLS += targ_headers
+}
+
+embedded:equals(TARGET, QtGui) {
+    # install fonts for embedded
+    INSTALLS += fonts
+    fonts.path = $$[QT_INSTALL_LIBS]/fonts
+    fonts.files = $$QT_SOURCE_TREE/lib/fonts/*
+}