#!/usr/bin/perl
#############################################################################
##
## Copyright (C) 2009 Nokia Corporation and/or its subsidiary(-ies).
## Contact: Nokia Corporation (qt-info@nokia.com)
##
## This file is part of the S60 port of the Qt Toolkit.
##
## $QT_BEGIN_LICENSE:LGPL$
## No Commercial Usage
## This file contains pre-release code and may not be distributed.
## You may use this file in accordance with the terms and conditions
## contained in the Technology Preview License Agreement accompanying
## this package.
##
## GNU Lesser General Public License Usage
## Alternatively, this file may be used under the terms of the GNU Lesser
## General Public License version 2.1 as published by the Free Software
## Foundation and appearing in the file LICENSE.LGPL included in the
## packaging of this file.  Please review the following information to
## ensure the GNU Lesser General Public License version 2.1 requirements
## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
##
## In addition, as a special exception, Nokia gives you certain
## additional rights.  These rights are described in the Nokia Qt LGPL
## Exception version 1.1, included in the file LGPL_EXCEPTION.txt in this
## package.
##
## If you have questions regarding the use of this file, please contact
## Nokia at qt-info@nokia.com.
##
##
##
##
##
##
##
##
## $QT_END_LICENSE$
##
#############################################################################

############################################################################################
#
# Convenience script for creating signed packages you can install on your phone.
#
############################################################################################

use strict;

# use a command-line parsing module
use Getopt::Long;
# Use file name parsing module
use File::Basename;

sub Usage() {
    print "\n";
    print "==========================================================================================\n";
    print "Convenience script for creating signed packages you can install on your phone.\n";
    print "\n";
    print "Usage: createpackage.pl [-i] templatepkg target-platform [certificate key [passphrase]]\n";
    print "\n";
    print "Where parameters are as follows:\n";
    print "     [-i|install]    = Install the package right away using PC suite\n";
    print "     [-p|preprocess] = Only preprocess the template .pkg file.\n";    
    print "     templatepkg     = Name of .pkg file template\n";
    print "     target          = Either debug or release\n";    
    print "     platform        = One of the supported platform\n";
    print "                       winscw | gcce | armv5 | armv6 | armv7\n";
    print "     certificate     = The certificate file used for signing\n";
    print "     key             = The certificate's private key file\n";
    print "     passphrase      = The certificate's private key file's passphrase\n";
    print "\n";
    print "For example:\n";    
    print "     createpackage.pl fluidlauncher_template.pkg release-armv5\n";        
    print "\n";
    print "If no certificate and key files are provided, either a RnD certificate or\n";
    print "a self-signed certificate from Qt installation root directory is used.\n";
    print "\n";
    print "==========================================================================================\n";
    exit();
}

# Read given options
my $install = "";
my $preprocessonly = "";
unless (GetOptions('i|install' => \$install, 'p|preprocess' => \$preprocessonly)){
    Usage();
}

# Read params to variables
my $templatepkg = $ARGV[0];
my $targetplatform = lc $ARGV[1];

my @tmpvalues = split('-', $targetplatform);
my $target = $tmpvalues[0];
my $platform = $tmpvalues[1];;

# Convert visual target to real target (debug->udeb and release->urel)
$target =~ s/debug/udeb/i;
$target =~ s/release/urel/i;

my $certificate = $ARGV[2];
my $key = $ARGV[3];
my $passphrase = $ARGV[4];

# Generate output pkg basename (i.e. file name without extension)
my $pkgoutputbasename = $templatepkg;
$pkgoutputbasename =~ s/_template\.pkg/_$targetplatform/g;
$pkgoutputbasename = lc($pkgoutputbasename);

# Store output file names to variables
my $pkgoutput = lc($pkgoutputbasename.".pkg");
my $unsigned_sis_name = $pkgoutputbasename."_unsigned.sis";
my $signed_sis_name = $pkgoutputbasename.".sis";

# Store some utility variables
my $scriptpath = dirname(__FILE__);
my $certtext = $certificate;
my $certpath = $scriptpath;
$certpath =~ s-^(.*[^\\])$-$1\\-o;      # ensure path ends with a backslash
$certpath = $certpath."../";            # certificates are one step up in hierarcy
$certpath =~ s-/-\\-go;	                # for those working with UNIX shells

# Check some pre-conditions and print error messages if needed
unless (length($templatepkg) && length($platform) && length($target)) {
    print "\nError: Template PKG filename, platform or target is not defined!\n";
    Usage();
}

# Check template exist
stat($templatepkg);
unless( -e _ ) {
    print "\nError: Package description file '$templatepkg' does not exist!\n";
    Usage();
}

# Check certifcate preconditions and set default certificate variables if needed
if (length($certificate)) {
    unless(length($key)) {
        print "\nError: Custom certificate key file parameter missing.!\n";
        Usage();
    }
} else {
    #If no certificate is given, check default options
    $certtext = "RnD";
    $certificate = $certpath."rd.cer";
    $key = $certpath."rd-key.pem";

    stat($certificate);
    unless( -e _ ) {
        $certtext = "Self Signed";
        $certificate = $certpath."selfsigned.cer";
        $key = $certpath."selfsigned.key";
    }
}

# Remove any existing .sis packages
unlink $unsigned_sis_name;
unlink $signed_sis_name;
unlink $pkgoutput;

# Preprocess PKG
local $/;
# read template file
open( TEMPLATE, $templatepkg) or die "Error '$templatepkg': $!\n";
$_=<TEMPLATE>;
close (TEMPLATE);

# replace the PKG variables
s/\$\(PLATFORM\)/$platform/gm;
s/\$\(TARGET\)/$target/gm;

#write the output
open( OUTPUT, ">$pkgoutput" ) or die "Error '$pkgoutput' $!\n";
print OUTPUT $_;
close OUTPUT;

if ($preprocessonly) {
    exit;
}

# Create and sign SIS
system ("makesis $pkgoutput $unsigned_sis_name");
system ("signsis $unsigned_sis_name $signed_sis_name $certificate $key $passphrase");

# Check if creating signed SIS Succeeded
stat($signed_sis_name);
if( -e _ ) {
    print ("\nSuccessfully created $signed_sis_name using certificate $certtext!\n");

    # remove temporary pkg and unsigned sis
    unlink $pkgoutput;
    unlink $unsigned_sis_name;

    # Install the sis if requested
    if ($install) {
        print ("\nInstalling $signed_sis_name...\n");
        system ("$signed_sis_name");
    }
} else {
    # Lets leave the generated PKG for problem solving purposes
    print ("\nSIS creation failed!\n");
}


#end of file