REM @echo off

SET BASEDIR=%~dp0

if not defined SDKDIR (
    echo SDKDIR is not defined.
    exit /b 1
)
if not defined NASMDIR (
    echo NASMDIR is not defined.
    exit /b 1
)
if not defined PERLDIR (
    echo PERLDIR is not defined.
    exit /b 1
)
if not defined MSYSDIR (
    echo MSYSDIR is not defined.
    exit /b 1
)

set PATH=%PERLDIR%\bin;%MSYSDIR%\usr\bin;%PATH%
set PERL=%PERLDIR%\bin\perl.exe

SET QT_VERSION=5.14
SET QT_RELEASE=2

SET QT_FULL_VER=%QT_VERSION%.%QT_RELEASE%
SET QT_SOURCE_ARCHIVE=qt-everywhere-src-%QT_FULL_VER%.zip
SET "DL_URL=https://download.qt.io/official_releases/qt/%QT_VERSION%/%QT_FULL_VER%/single/%QT_SOURCE_ARCHIVE%"
SET SRC_DIR=%BASEDIR%qt-%QT_VERSION%
SET OPENSSL=openssl-1.0.2r
SET OPENSSL_URL=https://www.openssl.org/source/%OPENSSL%.tar.gz"

SET PATH=%BASEDIR%\wintools;%NASMDIR%;%PATH%

if not exist "%OPENSSL%.tar.gz" wget.exe -c "%OPENSSL_URL%
7za.exe x %OPENSSL%.tar.gz -y
if not exist "%OPENSSL%" 7za.exe x %OPENSSL%.tar -y
cd %OPENSSL%
sh.exe -c "rm -f NUL"
cd %BASEDIR%

rem 32 - Bit
SET INST_ARCH=x86-msvc
call %SDKDIR%\setvcvars.bat 2019 x86
if %errorlevel% neq 0 exit /b %errorlevel%

rem Build OpenSSL
cd %BASEDIR%\%OPENSSL%
call %PERL% Configure VC-WIN32 --prefix=%BASEDIR%/openssl-%INST_ARCH%
if %errorlevel% neq 0 exit /b %errorlevel%
call ms\do_ms.bat
if %errorlevel% neq 0 exit /b %errorlevel%
call ms\do_nasm.bat
if %errorlevel% neq 0 exit /b %errorlevel%
rem Build static lib
call nmake -f ms\nt.mak
if %errorlevel% neq 0 exit /b %errorlevel%
call nmake -f ms\nt.mak install
if %errorlevel% neq 0 exit /b %errorlevel%
call nmake -f ms\ntdll.mak
if %errorlevel% neq 0 exit /b %errorlevel%
call nmake -f ms\ntdll.mak install
if %errorlevel% neq 0 exit /b %errorlevel%

cd %BASEDIR%

if not exist "%QT_SOURCE_ARCHIVE%" wget.exe -c "%DL_URL%"

if exist %SRC_DIR% (
    echo Removing previous build dir %SRC_DIR% ...
    del /f /s /q %SRC_DIR% > nul
    rmdir /s /q %SRC_DIR%
)

7za.exe x %QT_SOURCE_ARCHIVE% -y
rename qt-everywhere-src-%QT_FULL_VER% qt-%QT_VERSION%

SET PREFIX=%BASEDIR%qt-%QT_VERSION%-%INST_ARCH%\
cd %SRC_DIR%
del config.cache
call .\configure -prefix %PREFIX% -static -shared -mp -platform win32-msvc -release -ssl -nomake examples -nomake tests -skip qtwebengine -qt-zlib -qt-libjpeg -qt-libpng -qt-pcre -qt-freetype -opengl desktop -openssl -I%BASEDIR%\openssl-%INST_ARCH%\include -L%BASEDIR%\openssl-%INST_ARCH%\lib -opensource -confirm-license 
if %errorlevel% neq 0 exit /b %errorlevel%
call nmake
if %errorlevel% neq 0 exit /b %errorlevel%
call nmake install
if %errorlevel% neq 0 exit /b %errorlevel%

cd %PREFIX%
%BASEDIR%wintools\7za.exe a -tzip %BASEDIR%\qt-%QT_FULL_VER%-%INST_ARCH%.zip .\*
cd %BASEDIR%

rm -Rf %OPENSSL%
rm -Rf qt-%QT_VERSION%