mkspecs/features/egl.prf


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29

# On UNIX, we can use config tests to figure out if egl.h is in
# EGL/egl.h or GLES/egl.h. Sadly, there are no config tests on WinCE
# so we have to assume that for GLES 1.1 (CL), the EGL header is in
# GLES/egl.h. We also assume there is no separate libEGL.lib library,
# so we use the GL library instead.

wince*:contains(QT_CONFIG, opengles1) {
    INCLUDEPATH += $$QMAKE_INCDIR_OPENGL_ES1
    LIBS_PRIVATE += $$QMAKE_LIBS_OPENGL_ES1
    for(p, QMAKE_LIBDIR_OPENGL_ES1) {
        exists($$p):LIBS_PRIVATE += -L$$p
    }
    DEFINES += QT_GLES_EGL
} else:wince*:contains(QT_CONFIG, opengles1cl) {
    INCLUDEPATH += $$QMAKE_INCDIR_OPENGL_ES1CL
    LIBS_PRIVATE += $$QMAKE_LIBS_OPENGL_ES1CL
    LIBS += $$QMAKE_LFLAGS_EGL
    for(p, QMAKE_LIBDIR_OPENGL_ES1CL) {
        exists($$p):LIBS_PRIVATE += -L$$p
    }
    DEFINES += QT_GLES_EGL
} else {
    INCLUDEPATH += $$QMAKE_INCDIR_EGL
    LIBS_PRIVATE += $$QMAKE_LIBS_EGL
    LIBS += $$QMAKE_LFLAGS_EGL
    for(p, QMAKE_LIBDIR_EGL) {
        exists($$p):LIBS_PRIVATE += -L$$p
    }
}