blob: d2011d0b0f95ce74c36aed40b14dff621e5d1964 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
isEmpty(TEMPLATE):TEMPLATE=app
CONFIG += qt warn_on console depend_includepath
qtAddLibrary(QtTest)
symbian:{
TARGET.EPOCHEAPSIZE = 0x100000 0x2000000
# DEFINES += QTEST_NO_SPECIALIZATIONS
TARGET.CAPABILITY="None"
RSS_RULES ="group_name=\"QtTests\";"
}
# prefix test binary with tst_
!contains(TARGET, ^tst_.*):TARGET = $$join(TARGET,,"tst_")
check.files =
check.path = .
!isEmpty(DESTDIR): check.commands = cd ./$(DESTDIR) &&
macx: check.commands += ./$(QMAKE_TARGET).app/Contents/MacOS/$(QMAKE_TARGET)
else:unix: check.commands += ./$(QMAKE_TARGET)
else:win32: {
CONFIG(debug, debug|release):check.commands += $(DESTDIR_TARGET)
else:check.commands += $(DESTDIR_TARGET)
}
embedded: check.commands += -qws
QMAKE_EXTRA_TARGETS += check
!debug_and_release|build_pass {
check.depends = first
} else {
check.CONFIG = recursive
# In debug and release mode, only run the test once.
# Run debug if available, release otherwise.
debug_and_release {
check.target = dummy_check
check.recurse_target = check
debug {
real_check.depends = debug-check
real_check.target = check
QMAKE_EXTRA_TARGETS += real_check
} else {
real_check.depends = release-check
real_check.target = check
QMAKE_EXTRA_TARGETS += real_check
}
}
}
target.path += $$[QT_INSTALL_PREFIX]/tests/qt4
INSTALLS += target
|
