blob: 4f53621cd68e61107ae543892d654ced6b1dca67 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
|
# Qt network bearer management module
#DEFINES += BEARER_MANAGEMENT_DEBUG
HEADERS += bearer/qnetworkconfiguration.h \
bearer/qnetworksession.h \
bearer/qnetworkconfigmanager.h \
bearer/qbearerplugin.h
SOURCES += bearer/qnetworksession.cpp \
bearer/qnetworkconfigmanager.cpp \
bearer/qnetworkconfiguration.cpp \
bearer/qbearerplugin.cpp
symbian {
exists($${EPOCROOT}epoc32/release/winscw/udeb/cmmanager.lib)| \
exists($${EPOCROOT}epoc32/release/armv5/lib/cmmanager.lib) {
message("Building with SNAP support")
DEFINES += SNAP_FUNCTIONALITY_AVAILABLE
LIBS += -lcmmanager
} else {
message("Building without SNAP support")
LIBS += -lapengine
}
INCLUDEPATH += $$APP_LAYER_SYSTEMINCLUDE
HEADERS += bearer/qnetworkconfigmanager_s60_p.h \
bearer/qnetworkconfiguration_s60_p.h \
bearer/qnetworksession_s60_p.h
SOURCES += bearer/qnetworkconfigmanager_s60_p.cpp \
bearer/qnetworkconfiguration_s60_p.cpp \
bearer/qnetworksession_s60_p.cpp
LIBS += -lcommdb \
-lapsettingshandlerui \
-lconnmon \
-lcentralrepository \
-lesock \
-linsock \
-lecom \
-lefsrv \
-lnetmeta
} else:maemo {
QT += dbus
CONFIG += link_pkgconfig
exists(../debug) {
message("Enabling debug messages.")
DEFINES += BEARER_MANAGEMENT_DEBUG
}
HEADERS += bearer/qnetworksession_maemo_p.h \
bearer/qnetworkconfigmanager_maemo_p.h \
bearer/qnetworkconfiguration_maemo_p.h
SOURCES += bearer/qnetworkconfigmanager_maemo.cpp \
bearer/qnetworksession_maemo.cpp
documentation.path = $$QT_MOBILITY_PREFIX/doc
documentation.files = doc/html
PKGCONFIG += glib-2.0 dbus-glib-1 gconf-2.0 osso-ic conninet
CONFIG += create_pc create_prl
QMAKE_PKGCONFIG_REQUIRES = glib-2.0 dbus-glib-1 gconf-2.0 osso-ic conninet
pkgconfig.path = $$QT_MOBILITY_LIB/pkgconfig
pkgconfig.files = QtBearer.pc
INSTALLS += pkgconfig documentation
} else {
DEFINES += BEARER_ENGINE
HEADERS += bearer/qnetworkconfigmanager_p.h \
bearer/qnetworkconfiguration_p.h \
bearer/qnetworksession_p.h \
bearer/qnetworksessionengine_p.h
SOURCES += bearer/qnetworkconfigmanager_p.cpp \
bearer/qnetworksession_p.cpp \
bearer/qnetworksessionengine.cpp
unix:!mac:contains(networkmanager_enabled, yes) {
contains(QT_CONFIG,dbus) {
DEFINES += BACKEND_NM
QT += dbus
HEADERS += bearer/qnmdbushelper_p.h \
bearer/qnetworkmanagerservice_p.h \
bearer/qnmwifiengine_unix_p.h
SOURCES += bearer/qnmdbushelper.cpp \
bearer/qnetworkmanagerservice_p.cpp \
bearer/qnmwifiengine_unix.cpp
} else {
message("NetworkManager backend requires Qt DBus support")
}
}
win32 {
HEADERS += bearer/qnlaengine_win_p.h \
bearer/qnetworksessionengine_win_p.h
SOURCES += bearer/qnlaengine_win.cpp
!wince* {
HEADERS += bearer/qnativewifiengine_win_p.h
SOURCES += bearer/qnativewifiengine_win.cpp
LIBS += -lWs2_32
} else {
LIBS += -lWs2
}
}
macx {
HEADERS += bearer/qcorewlanengine_mac_p.h
SOURCES+= bearer/qcorewlanengine_mac.mm
LIBS += -framework Foundation -framework SystemConfiguration
contains(corewlan_enabled, yes) {
isEmpty(QMAKE_MAC_SDK)|contains(QMAKE_MAC_SDK, "/Developer/SDKs/MacOSX10.6.sdk") {
LIBS += -framework CoreWLAN
DEFINES += MAC_SDK_10_6
}
}
}
}
|
