src/network/bearer/bearer.pri


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Qt network bearer management module

#DEFINES += BEARER_MANAGEMENT_DEBUG

HEADERS += bearer/qnetworkconfiguration.h \
           bearer/qnetworksession.h \
           bearer/qnetworkconfigmanager.h

SOURCES += bearer/qnetworksession.cpp \
           bearer/qnetworkconfigmanager.cpp \
           bearer/qnetworkconfiguration.cpp

maemo {
    QT += dbus
    CONFIG += link_pkgconfig

    exists(../debug) {
        message("Enabling debug messages.")
        DEFINES += BEARER_MANAGEMENT_DEBUG
    }

    HEADERS += bearer/qnetworksession_maemo_p.h \
               bearer/qnetworkconfigmanager_maemo_p.h \
               bearer/qnetworkconfiguration_maemo_p.h

    SOURCES += bearer/qnetworkconfigmanager_maemo.cpp \
               bearer/qnetworksession_maemo.cpp

    documentation.path = $$QT_MOBILITY_PREFIX/doc
    documentation.files = doc/html

    PKGCONFIG += glib-2.0 dbus-glib-1 gconf-2.0 osso-ic conninet

    CONFIG += create_pc create_prl
    QMAKE_PKGCONFIG_REQUIRES = glib-2.0 dbus-glib-1 gconf-2.0 osso-ic conninet
    pkgconfig.path = $$QT_MOBILITY_LIB/pkgconfig
    pkgconfig.files = QtBearer.pc

    INSTALLS += pkgconfig documentation
} else {
    HEADERS += bearer/qnetworkconfigmanager_p.h \
               bearer/qnetworkconfiguration_p.h \
               bearer/qnetworksession_p.h \
               bearer/qnetworksessionengine_p.h \
               bearer/qbearerplugin.h

    SOURCES += bearer/qnetworkconfigmanager_p.cpp \
               bearer/qnetworksessionengine.cpp \
               bearer/qbearerplugin.cpp

    contains(QT_CONFIG, networkmanager):DEFINES += BACKEND_NM
}