blob: 90868e8ca881b0eabc8f036905df5ab469f4d4aa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
TARGET = qtiff
include(../../qpluginbase.pri)
QTDIR_build:REQUIRES = "!contains(QT_CONFIG, no-tiff)"
HEADERS += qtiffhandler.h
SOURCES += main.cpp \
qtiffhandler.cpp
contains(QT_CONFIG, system-tiff) {
unix|win32-g++*:LIBS += -ltiff
win32:!win32-g++*:LIBS += libtiff.lib
contains(QT_CONFIG, system-jpeg) {
unix|win32-g++*:LIBS += -ljpeg
win32:!win32-g++*:LIBS += libjpeg.lib
}
} else {
INCLUDEPATH += ../../../3rdparty/libtiff/libtiff
SOURCES += \
../../../3rdparty/libtiff/libtiff/tif_aux.c \
../../../3rdparty/libtiff/libtiff/tif_close.c \
../../../3rdparty/libtiff/libtiff/tif_codec.c \
../../../3rdparty/libtiff/libtiff/tif_color.c \
../../../3rdparty/libtiff/libtiff/tif_compress.c \
../../../3rdparty/libtiff/libtiff/tif_dir.c \
../../../3rdparty/libtiff/libtiff/tif_dirinfo.c \
../../../3rdparty/libtiff/libtiff/tif_dirread.c \
../../../3rdparty/libtiff/libtiff/tif_dirwrite.c \
../../../3rdparty/libtiff/libtiff/tif_dumpmode.c \
../../../3rdparty/libtiff/libtiff/tif_error.c \
../../../3rdparty/libtiff/libtiff/tif_extension.c \
../../../3rdparty/libtiff/libtiff/tif_fax3.c \
../../../3rdparty/libtiff/libtiff/tif_fax3sm.c \
../../../3rdparty/libtiff/libtiff/tif_flush.c \
../../../3rdparty/libtiff/libtiff/tif_getimage.c \
../../../3rdparty/libtiff/libtiff/tif_luv.c \
../../../3rdparty/libtiff/libtiff/tif_lzw.c \
../../../3rdparty/libtiff/libtiff/tif_next.c \
../../../3rdparty/libtiff/libtiff/tif_open.c \
../../../3rdparty/libtiff/libtiff/tif_packbits.c \
../../../3rdparty/libtiff/libtiff/tif_pixarlog.c \
../../../3rdparty/libtiff/libtiff/tif_predict.c \
../../../3rdparty/libtiff/libtiff/tif_print.c \
../../../3rdparty/libtiff/libtiff/tif_read.c \
../../../3rdparty/libtiff/libtiff/tif_strip.c \
../../../3rdparty/libtiff/libtiff/tif_swab.c \
../../../3rdparty/libtiff/libtiff/tif_thunder.c \
../../../3rdparty/libtiff/libtiff/tif_tile.c \
../../../3rdparty/libtiff/libtiff/tif_version.c \
../../../3rdparty/libtiff/libtiff/tif_warning.c \
../../../3rdparty/libtiff/libtiff/tif_write.c \
../../../3rdparty/libtiff/libtiff/tif_zip.c
win32:!wince*: {
SOURCES += ../../../3rdparty/libtiff/libtiff/tif_win32.c
}
unix: {
SOURCES += ../../../3rdparty/libtiff/libtiff/tif_unix.c
}
wince*: {
SOURCES += ../../../corelib/kernel/qfunctions_wince.cpp \
../../../3rdparty/libtiff/libtiff/tif_wince.c \
../../../3rdparty/libtiff/libtiff/tif_win32.c
}
symbian: {
SOURCES += ../../../3rdparty/libtiff/port/lfind.c
}
}
contains(QT_CONFIG, system-zlib) {
symbian:LIBS_PRIVATE += -llibz
else:if(unix|win32-g++*):LIBS_PRIVATE += -lz
else:LIBS += zdll.lib
} else {
INCLUDEPATH += ../../../3rdparty/zlib
}
QTDIR_build:DESTDIR = $$QT_BUILD_TREE/plugins/imageformats
target.path += $$[QT_INSTALL_PLUGINS]/imageformats
INSTALLS += target
symbian:TARGET.UID3=0x2001E617
|
