1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
|
# Use subdirs template to suppress generation of unnecessary files
TEMPLATE = subdirs
symbian: {
load(data_caging_paths)
SUBDIRS=
# WARNING: Changing TARGET name will break Symbian SISX upgrade functionality
# DO NOT TOUCH TARGET VARIABLE IF YOU ARE NOT SURE WHAT YOU ARE DOING
TARGET = "Qt"
TARGET.UID3 = 0x2001E61C
VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}
symbian-abld|symbian-sbsv2 {
qtresources.sources = $${EPOCROOT}$$HW_ZDIR$$APP_RESOURCE_DIR/s60main.rsc
} else {
qtresources.sources = $$QMAKE_LIBDIR_QT/s60main.rsc
DESTDIR = $$QMAKE_LIBDIR_QT
}
qtresources.path = c:$$APP_RESOURCE_DIR
qtlibraries.sources = \
$$QMAKE_LIBDIR_QT/QtCore.dll \
$$QMAKE_LIBDIR_QT/QtXml.dll \
$$QMAKE_LIBDIR_QT/QtGui.dll \
$$QMAKE_LIBDIR_QT/QtNetwork.dll \
$$QMAKE_LIBDIR_QT/QtTest.dll \
$$QMAKE_LIBDIR_QT/QtSql.dll
symbian-abld|symbian-sbsv2 {
pluginLocations = $${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)
} else {
pluginLocations = $$QT_BUILD_TREE/plugins/s60
}
qts60plugindeployment = \
"IF package(0x1028315F)" \
" \"$$pluginLocations/qts60plugin_5_0.dll\" - \"c:\\sys\\bin\\qts60plugin_5_0.dll\"" \
"ELSEIF package(0x102752AE)" \
" \"$$pluginLocations/qts60plugin_3_2.dll\" - \"c:\\sys\\bin\\qts60plugin_3_2.dll\"" \
"ELSEIF package(0x102032BE)" \
" \"$$pluginLocations/qts60plugin_3_1.dll\" - \"c:\\sys\\bin\\qts60plugin_3_1.dll\"" \
"ELSE" \
" \"$$pluginLocations/qts60plugin_5_0.dll\" - \"c:\\sys\\bin\\qts60plugin_5_0.dll\"" \
"ENDIF"
qtlibraries.pkg_postrules += qts60plugindeployment
sqlitedeployment = \
"; Deploy sqlite onto phone that does not have it already" \
"@\"$$PWD/sqlite3.sis\", (0x2002af5f)"
qtlibraries.pkg_postrules += sqlitedeployment
qtlibraries.path = c:/sys/bin
vendorinfo = \
"; Localised Vendor name" \
"%{\"Nokia, Qt\"}" \
" " \
"; Unique Vendor name" \
":\"Nokia, Qt\"" \
" "
qtlibraries.pkg_prerules = vendorinfo
qtlibraries.pkg_prerules += "; Dependencies of Qt libraries"
qtlibraries.pkg_prerules += "(0x20013851), 1, 5, 1, {\"PIPS Installer\"}"
contains(QT_CONFIG, openssl) | contains(QT_CONFIG, openssl-linked) {
qtlibraries.pkg_prerules += "(0x200110CB), 1, 5, 1, {\"Open C LIBSSL Common\"}"
}
contains(CONFIG, stl) {
qtlibraries.pkg_prerules += "(0x2000F866), 1, 0, 0, {\"Standard C++ Library Common\"}"
}
qtlibraries.pkg_prerules += "(0x2002af5f), 0, 5, 0, {\"sqlite3\"}"
!contains(QT_CONFIG, no-jpeg): imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qjpeg.dll
!contains(QT_CONFIG, no-gif): imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qgif.dll
!contains(QT_CONFIG, no-mng): imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qmng.dll
!contains(QT_CONFIG, no-tiff): imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qtiff.dll
!contains(QT_CONFIG, no-ico): imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qico.dll
imageformats_plugins.path = c:$$QT_PLUGINS_BASE_DIR/imageformats
codecs_plugins.sources = $$QT_BUILD_TREE/plugins/codecs/qcncodecs.dll $$QT_BUILD_TREE/plugins/codecs/qjpcodecs.dll $$QT_BUILD_TREE/plugins/codecs/qtwcodecs.dll $$QT_BUILD_TREE/plugins/codecs/qkrcodecs.dll
codecs_plugins.path = c:$$QT_PLUGINS_BASE_DIR/codecs
contains(QT_CONFIG, phonon-backend) {
phonon_backend_plugins.sources += $$QMAKE_LIBDIR_QT/phonon_mmf.dll
phonon_backend_plugins.path = c:$$QT_PLUGINS_BASE_DIR/phonon_backend
DEPLOYMENT += phonon_backend_plugins
}
contains(QT_CONFIG, audio-backend) {
qaudio_backend_plugins.sources += $$QT_BUILD_TREE/plugins/audio/qaudio.dll
qaudio_backend_plugins.path = c:$$QT_PLUGINS_BASE_DIR/audio
DEPLOYMENT += qaudio_backend_plugins
}
# Support backup & restore for Qt libraries
qtbackup.sources = backup_registration.xml
qtbackup.path = c:/private/10202D56/import/packages/$$replace(TARGET.UID3, 0x,)
bearer_plugins.path = c:$$QT_PLUGINS_BASE_DIR/bearer
bearer_plugins.sources += $$QT_BUILD_TREE/plugins/bearer/qsymbianbearer.dll
DEPLOYMENT += qtresources \
qtlibraries \
qtbackup \
imageformats_plugins \
codecs_plugins \
graphicssystems_plugins \
bearer_plugins
contains(QT_CONFIG, svg): {
qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtSvg.dll
imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qsvg.dll
iconengines_plugins.sources = $$QT_BUILD_TREE/plugins/iconengines/qsvgicon.dll
iconengines_plugins.path = c:$$QT_PLUGINS_BASE_DIR/iconengines
DEPLOYMENT += iconengines_plugins
}
contains(QT_CONFIG, phonon): {
qtlibraries.sources += $$QMAKE_LIBDIR_QT/phonon.dll
}
contains(QT_CONFIG, script): {
qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtScript.dll
}
contains(QT_CONFIG, xmlpatterns): {
qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtXmlPatterns.dll
}
contains(QT_CONFIG, declarative): {
# TODO FIXME For some reason QtDeclarative cannot install on symbian/linux-armcc.
# Revert this patch and investigate later.
symbian-abld|symbian-sbsv2:qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtDeclarative.dll
}
graphicssystems_plugins.path = c:$$QT_PLUGINS_BASE_DIR/graphicssystems
contains(QT_CONFIG, openvg) {
qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtOpenVG.dll
graphicssystems_plugins.sources += $$QT_BUILD_TREE/plugins/graphicssystems/qvggraphicssystem.dll
}
contains(QT_CONFIG, multimedia) {
qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtMultimedia.dll
}
BLD_INF_RULES.prj_exports += "qt.iby $$CORE_MW_LAYER_IBY_EXPORT_PATH(qt.iby)"
BLD_INF_RULES.prj_exports += "qtdemoapps.iby $$CORE_APP_LAYER_IBY_EXPORT_PATH(qtdemoapps.iby)"
}
|
