tests/auto/qlocalsocket/test/test.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

load(qttest_p4)

DEFINES += QLOCALSERVER_DEBUG
DEFINES += QLOCALSOCKET_DEBUG

symbian {
    # nothing
} else:wince* {
    DEFINES += QT_LOCALSOCKET_TCP
    DEFINES += SRCDIR=\\\"../\\\"
} else {
    DEFINES += SRCDIR=\\\"$$PWD/../\\\"
}

QT = core network

SOURCES += ../tst_qlocalsocket.cpp

TARGET = tst_qlocalsocket
CONFIG(debug_and_release) {
  CONFIG(debug, debug|release) {
    DESTDIR = ../debug
  } else {
    DESTDIR = ../release
  }
} else {
  DESTDIR = ..
}

wince* {
    additionalFiles.sources = ../lackey/lackey.exe
    additionalFiles.path = lackey
}

symbian {
    additionalFiles.sources = lackey.exe
    additionalFiles.path = \sys\bin
    TARGET.UID3 = 0xE0340005
    DEFINES += SYMBIAN_SRCDIR_UID=$$lower($$replace(TARGET.UID3,"0x",""))
}

wince*|symbian {
    scriptFiles.sources = ../lackey/scripts/*.js
    scriptFiles.path = lackey/scripts
    DEPLOYMENT = additionalFiles scriptFiles
    QT += script    # for easy deployment of QtScript
}