blob: e394799380781962707628f1f9c51cf36814502b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
|
DEFINES += QDOC2_COMPAT
DEFINES += QT_NO_CAST_TO_ASCII
#DEFINES += QT_NO_CAST_FROM_ASCII
#DEFINES += QT_USE_FAST_OPERATOR_PLUS
#DEFINES += QT_USE_FAST_CONCATENATION
qdoc_bootstrapped {
include(../../src/tools/bootstrap/bootstrap.pri)
DEFINES -= QT_NO_CAST_FROM_ASCII
DEFINES += QT_NO_TRANSLATION
} else {
QT = core xml
CONFIG += console
CONFIG -= debug_and_release_target
}
!isEmpty(QT_BUILD_TREE):DESTDIR = $$QT_BUILD_TREE/bin
#CONFIG += debug
build_all:!build_pass {
CONFIG -= build_all
CONFIG += release
# CONFIG += debug
}
CONFIG -= app_bundle
HEADERS += apigenerator.h \
archiveextractor.h \
atom.h \
bookgenerator.h \
ccodeparser.h \
codechunk.h \
codemarker.h \
codeparser.h \
command.h \
config.h \
cppcodemarker.h \
cppcodeparser.h \
cpptoqsconverter.h \
dcfsection.h \
doc.h \
editdistance.h \
generator.h \
helpprojectwriter.h \
htmlgenerator.h \
jambiapiparser.h \
javacodemarker.h \
javadocgenerator.h \
linguistgenerator.h \
location.h \
loutgenerator.h \
mangenerator.h \
node.h \
openedlist.h \
pagegenerator.h \
plaincodemarker.h \
polyarchiveextractor.h \
polyuncompressor.h \
qsakernelparser.h \
qscodemarker.h \
qscodeparser.h \
quoter.h \
separator.h \
sgmlgenerator.h \
text.h \
tokenizer.h \
tr.h \
tree.h \
uncompressor.h \
webxmlgenerator.h
SOURCES += apigenerator.cpp \
archiveextractor.cpp \
atom.cpp \
bookgenerator.cpp \
ccodeparser.cpp \
codechunk.cpp \
codemarker.cpp \
codeparser.cpp \
command.cpp \
config.cpp \
cppcodemarker.cpp \
cppcodeparser.cpp \
cpptoqsconverter.cpp \
dcfsection.cpp \
doc.cpp \
editdistance.cpp \
generator.cpp \
helpprojectwriter.cpp \
htmlgenerator.cpp \
jambiapiparser.cpp \
javacodemarker.cpp \
javadocgenerator.cpp \
linguistgenerator.cpp \
location.cpp \
loutgenerator.cpp \
mangenerator.cpp \
main.cpp \
node.cpp \
openedlist.cpp \
pagegenerator.cpp \
plaincodemarker.cpp \
polyarchiveextractor.cpp \
polyuncompressor.cpp \
qsakernelparser.cpp \
qscodemarker.cpp \
qscodeparser.cpp \
quoter.cpp \
separator.cpp \
sgmlgenerator.cpp \
text.cpp \
tokenizer.cpp \
tree.cpp \
uncompressor.cpp \
webxmlgenerator.cpp \
yyindent.cpp
### Documentation for qdoc3 ###
win32:!win32-g++ {
unixstyle = false
} else :win32-g++:isEmpty(QMAKE_SH) {
unixstyle = false
} else {
unixstyle = true
}
$$unixstyle {
QDOC = cd $$PWD/doc && $$[QT_INSTALL_BINS]/qdoc3
} else {
QDOC = cd $$PWD/doc && $$[QT_INSTALL_BINS]/qdoc3.exe
QDOC = $$replace(QDOC, "/", "\\")
}
docs.commands = $$QDOC qdoc-manual.qdocconf
QMAKE_EXTRA_TARGETS += docs
target.path = $$[QT_INSTALL_BINS]
INSTALLS += target
|
