blob: cfa202e69322c074433dbd98cdf36aeb7b0d83fd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
TEMPLATE = subdirs
!contains(QT_CONFIG, no-gui) {
no-png {
message("Some graphics-related tools are unavailable without PNG support")
} else {
SUBDIRS += assistant \
pixeltool \
porting \
qtestlib \
qttracereplay
contains(QT_EDITION, Console) {
SUBDIRS += designer/src/uitools # Linguist depends on this
} else {
SUBDIRS += designer
}
symbian: SUBDIRS = designer
wince*: SUBDIRS = qtestlib designer
unix:!mac:!embedded:contains(QT_CONFIG, qt3support):SUBDIRS += qtconfig
win32:!wince*:SUBDIRS += activeqt
}
contains(QT_CONFIG, declarative):SUBDIRS += qmlviewer qmldebugger
}
SUBDIRS += linguist
mac {
SUBDIRS += macdeployqt
}
embedded:SUBDIRS += kmap2qmap
contains(QT_CONFIG, declarative):SUBDIRS += qml
contains(QT_CONFIG, dbus):SUBDIRS += qdbus
!wince*:contains(QT_CONFIG, xmlpatterns): SUBDIRS += xmlpatterns xmlpatternsvalidator
embedded: SUBDIRS += makeqpf
!wince*:!cross_compile:SUBDIRS += qdoc3
CONFIG+=ordered
QTDIR_build:REQUIRES = "contains(QT_CONFIG, full-config)"
|
