blob: 6a13dfffa00e43e120dc34629ed8848f8e3a7308 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
defineReplace(prependAll) {
prepend = $$1
arglist = $$2
append = $$3
for(a,arglist) {
result += $${prepend}$${a}$${append}
}
return ($$result)
}
qtPrepareTool(LUPDATE, lupdate)
LUPDATE += -locations relative -no-ui-lines
###### Qt Libraries
QT_TS = ar cs da de es fr he hu ja pl pt ru sk sl sv uk zh_CN zh_TW
ts-qt.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
-I../include -I../include/Qt \
3rdparty/phonon \
3rdparty/webkit \
activeqt \
corelib \
declarative \
gui \
multimedia \
network \
opengl \
plugins \
qt3support \
script \
scripttools \
sql \
svg \
xml \
xmlpatterns \
-ts $$prependAll($$QT_SOURCE_TREE/translations/qt_,$$QT_TS,.ts))
ts-qt.depends = sub-tools
###### Designer
ts-designer.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
../tools/designer/designer.pro)
ts-designer.depends = sub-tools
###### Linguist
ts-linguist.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
../tools/linguist/linguist/linguist.pro)
ts-linguist.depends = sub-tools
###### Assistant
ts-assistant.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
../tools/assistant/tools/assistant/assistant.pro)
ts-assistant.depends = sub-tools
###### Qt Help Lib
ts-qt_help.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
../tools/assistant/lib/lib.pro)
ts-qt_help.depends = sub-tools
###### Qtconfig
ts-qtconfig.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
../tools/qtconfig/qtconfig.pro)
ts-qtconfig.depends = sub-tools
###### Qvfp
ts-qvfb.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
../tools/qvfb/qvfb.pro)
ts-qvfb.depends = sub-tools
###### Overall Rules
ts.depends = ts-qt ts-designer ts-linguist ts-assistant ts-qt_help ts-qtconfig ts-qvfb
check-ts.commands = (cd $$PWD && perl check-ts.pl)
check-ts.depends = ts
QMAKE_EXTRA_TARGETS += ts-qt ts-designer ts-linguist ts-assistant ts-qt_help ts-qtconfig ts-qvfb \
ts check-ts
|