Use AC_MSG_RESULT/AC_MSG_ERROR/AC_MSG_WARN instead of echo (#1532)

1 files changed, 14 insertions, 37 deletions

diff --git a/configure.ac b/configure.ac
index 4d7be31..d5cef35 100644
--- a/configure.ac
+++ b/configure.ac
@@ -231,9 +231,10 @@ AC_CACHE_CHECK([for cached host], [hdf5_cv_host], [hdf5_cv_host="none"]);
 if test $hdf5_cv_host = "none"; then
   hdf5_cv_host=$host
 elif test $hdf5_cv_host != $host; then
-  echo "The config.cache file was generated on $hdf5_cv_host but"
-  echo "this is $host.  Please remove that file and try again."
-  AC_MSG_ERROR([config.cache file is invalid])
+  AC_MSG_ERROR([
+     The config.cache file was generated on $hdf5_cv_host but
+     this is $host.  Please remove that file and try again.
+     config.cache file is invalid])
 fi
 
 ## ----------------------------------------------------------------------
@@ -567,11 +568,7 @@ AC_ARG_ENABLE([fortran],
                               [Compile the Fortran interface [default=no]])],
               [HDF_FORTRAN=$enableval])
 
-if test "X$HDF_FORTRAN" = "Xyes"; then
-  echo "yes"
-else
-  echo "no"
-fi
+AC_MSG_RESULT([$HDF_FORTRAN])
 
 if test "X$HDF_FORTRAN" = "Xyes"; then
 
@@ -794,9 +791,9 @@ AC_ARG_ENABLE([cxx],
               [AS_HELP_STRING([--enable-cxx],
                               [Compile the C++ interface [default=no]])],
               [HDF_CXX=$enableval])
+AC_MSG_RESULT([$HDF_CXX])
 
 if test "X$HDF_CXX" = "Xyes"; then
-  echo "yes"
   HDF5_INTERFACES="$HDF5_INTERFACES c++"
 
   ## Expose the compiler for *.in files
@@ -806,7 +803,6 @@ if test "X$HDF_CXX" = "Xyes"; then
   AC_LANG_PUSH(C++)
 
 else
-  AC_MSG_RESULT([no])
   CXX="no"
 fi
 
@@ -1022,7 +1018,7 @@ AC_ARG_ENABLE([java],
 
 if test "X$HDF_JAVA" = "Xyes"; then
   if test "X${enable_shared}" != "Xno"; then
-    echo "yes"
+    AC_MSG_RESULT([yes])
     if test "X$CLASSPATH" = "X"; then
       H5_CLASSPATH=".:$srcdir/java/lib"
     else
@@ -1115,12 +1111,7 @@ AC_ARG_ENABLE([tests],
                               [Compile the HDF5 tests [default=yes]])],
               [HDF5_TESTS=$enableval])
 
-if test "X$HDF5_TESTS" = "Xno"; then
-  AC_MSG_RESULT([yes])
-  echo "Building HDF5 tests is disabled"
-else
-  AC_MSG_RESULT([no])
-fi
+AC_MSG_RESULT([$HDF5_TESTS])
 
 ## These need to be exposed for some tests.
 AC_SUBST([H5_UTILS_TEST_BUILDDIR])
@@ -1145,12 +1136,7 @@ AC_ARG_ENABLE([tools],
                               [Compile the HDF5 tools [default=yes]])],
               [HDF5_TOOLS=$enableval])
 
-if test "X$HDF5_TOOLS" = "Xno"; then
-  AC_MSG_RESULT([yes])
-  echo "Building HDF5 tools is disabled"
-else
-  AC_MSG_RESULT([no])
-fi
+AC_MSG_RESULT([$HDF5_TOOLS])
 
 ## ----------------------------------------------------------------------
 ## Check if they would like to enable building doxygen files
@@ -1169,8 +1155,9 @@ AC_ARG_ENABLE([doxygen],
                               [Compile the HDF5 doxygen files [default=no]])],
               [HDF5_DOXYGEN=$enableval])
 
+AC_MSG_RESULT([$HDF5_DOXYGEN])
+
 if test "X$HDF5_DOXYGEN" = "Xyes"; then
-  AC_MSG_RESULT([yes])
   DX_DOXYGEN_FEATURE(ON)
   DX_DOT_FEATURE(OFF)
   DX_HTML_FEATURE(ON)
@@ -1230,10 +1217,6 @@ if test "X$HDF5_DOXYGEN" = "Xyes"; then
   DOXYGEN_PREDEFINED='H5_HAVE_DIRECT H5_HAVE_LIBHDFS H5_HAVE_MAP_API H5_HAVE_PARALLEL H5_HAVE_ROS3_VFD'
 
   DX_INIT_DOXYGEN([HDF5], [./doxygen/Doxyfile], [hdf5lib_docs])
-
-else
-  AC_MSG_RESULT([no])
-  echo "Doxygen support is disabled"
 fi
 
 
@@ -1263,18 +1246,17 @@ AC_ARG_ENABLE([static_exec],
                               [Install only statically linked executables
                                [default=no]])],
               [STATIC_EXEC=$enableval])
+AC_MSG_RESULT([$STATIC_EXEC])
 
 if test "X$STATIC_EXEC" = "Xyes"; then
-  echo "yes"
   ## Issue a warning if -static flag is not supported.
   if test "X$lt_cv_prog_compiler_static_works" = "Xno"; then
-    echo "    warning: -static flag not supported on this system; executable won't statically link shared system libraries."
+    AC_MSG_WARN([-static flag not supported on this system; executable won't statically link shared system libraries.])
     LT_STATIC_EXEC=""
   else
     LT_STATIC_EXEC="-all-static"
   fi
 else
-  echo "no"
   LT_STATIC_EXEC=""
 fi
 AM_CONDITIONAL([USE_PLUGINS_CONDITIONAL], [test "X$LT_STATIC_EXEC" = X])
@@ -3824,12 +3806,7 @@ AC_ARG_ENABLE([build-all],
                      [Build helper programs that only developers should need [default=no]])],
      [BUILD_ALL=$enableval],
      [BUILD_ALL=no])
-
-if test "X$BUILD_ALL" = "Xyes"; then
- echo "yes"
-else
- echo "no"
-fi
+AC_MSG_RESULT([$BUILD_ALL])
 AM_CONDITIONAL([BUILD_ALL_CONDITIONAL], [test "X$BUILD_ALL" = "Xyes"])
 
 ## ----------------------------------------------------------------------