[svn-r19050] Description:

	Bring r18704:19049 from trunk to revise_chunks branch.

Tested on:
        FreeBSD/32 6.3 (duty) in debug mode
        FreeBSD/64 6.3 (liberty) w/C++ & FORTRAN, in debug mode
        Linux/32 2.6 (jam) w/PGI compilers, w/default API=1.8.x,
                w/C++ & FORTRAN, w/threadsafe, in debug mode
        Linux/64-amd64 2.6 (amani) w/Intel compilers, w/default API=1.6.x,
                w/C++ & FORTRAN, in production mode
        Solaris/32 2.10 (linew) w/deprecated symbols disabled, w/C++ & FORTRAN,
                w/szip filter, in production mode
        Linux/64-ia64 2.6 (cobalt) w/Intel compilers, w/C++ & FORTRAN,
                in production mode
        Linux/64-amd64 2.6 (abe) w/parallel, w/FORTRAN, in debug mode
        Mac OS X/32 10.6.3 (amazon) in debug mode
        Mac OS X/32 10.6.3 (amazon) w/C++ & FORTRAN, w/threadsafe,
                in production mode

1 files changed, 35 insertions, 0 deletions

diff --git a/acsite.m4 b/acsite.m4
index 0ed8781..eaab535 100644
--- a/acsite.m4
+++ b/acsite.m4
@@ -19,6 +19,41 @@ dnl -------------------------------------------------------------------------
 dnl -------------------------------------------------------------------------
 
 dnl -------------------------------------------------------------------------
+dnl _AC_SYS_LARGEFILE_MACRO_VALUE
+dnl
+dnl The following macro overrides the autoconf macro of the same name
+dnl with this custom definition. This macro performs the same checks as 
+dnl autoconf's native _AC_SYS_LARGEFILE_MACRO_VALUE, but will also set
+dnl AM_CPPFLAGS with the appropriate -D defines so additional configure 
+dnl sizeof checks do not fail.
+dnl
+# _AC_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, VALUE,
+#               CACHE-VAR,
+#               DESCRIPTION,
+#               PROLOGUE, [FUNCTION-BODY])
+# ----------------------------------------------------------
+m4_define([_AC_SYS_LARGEFILE_MACRO_VALUE],
+[AC_CACHE_CHECK([for $1 value needed for large files], [$3],
+[while :; do
+  m4_ifval([$6], [AC_LINK_IFELSE], [AC_COMPILE_IFELSE])(
+    [AC_LANG_PROGRAM([$5], [$6])],
+    [$3=no; break])
+  m4_ifval([$6], [AC_LINK_IFELSE], [AC_COMPILE_IFELSE])(
+    [AC_LANG_PROGRAM([@%:@define $1 $2
+$5], [$6])],
+    [$3=$2; break])
+  $3=unknown
+  break
+done])
+case $$3 in #(
+  no | unknown) ;;
+  *) AC_DEFINE_UNQUOTED([$1], [$$3], [$4])
+     AM_CPPFLAGS="-D$1=$$3 $AM_CPPFLAGS";;
+esac
+rm -rf conftest*[]dnl
+])# _AC_SYS_LARGEFILE_MACRO_VALUE
+
+dnl -------------------------------------------------------------------------
 dnl AC_F9X_MODS()
 dnl
 dnl	Check how F9X handles modules. This macro also checks which