[svn-r27540] Replace svn:externals with hard copy of files

1 files changed, 277 insertions, 0 deletions

diff --git a/config/cmake_ext_mod/HDFMacros.cmake b/config/cmake_ext_mod/HDFMacros.cmake
new file mode 100644
index 0000000..d3ac36b
--- /dev/null
+++ b/config/cmake_ext_mod/HDFMacros.cmake
@@ -0,0 +1,277 @@
+#-------------------------------------------------------------------------------
+macro (SET_GLOBAL_VARIABLE name value)
+  set (${name} ${value} CACHE INTERNAL "Used to pass variables between directories" FORCE)
+endmacro (SET_GLOBAL_VARIABLE)
+
+#-------------------------------------------------------------------------------
+macro (IDE_GENERATED_PROPERTIES SOURCE_PATH HEADERS SOURCES)
+  #set(source_group_path "Source/AIM/${NAME}")
+  string (REPLACE "/" "\\\\" source_group_path ${SOURCE_PATH})
+  source_group (${source_group_path} FILES ${HEADERS} ${SOURCES})
+
+  #-- The following is needed if we ever start to use OS X Frameworks but only
+  #--  works on CMake 2.6 and greater
+  #set_property (SOURCE ${HEADERS}
+  #       PROPERTY MACOSX_PACKAGE_LOCATION Headers/${NAME}
+  #)
+endmacro (IDE_GENERATED_PROPERTIES)
+
+#-------------------------------------------------------------------------------
+macro (IDE_SOURCE_PROPERTIES SOURCE_PATH HEADERS SOURCES)
+  #  install (FILES ${HEADERS}
+  #       DESTINATION include/R3D/${NAME}
+  #       COMPONENT Headers       
+  #  )
+
+  string (REPLACE "/" "\\\\" source_group_path ${SOURCE_PATH}  )
+  source_group (${source_group_path} FILES ${HEADERS} ${SOURCES})
+
+  #-- The following is needed if we ever start to use OS X Frameworks but only
+  #--  works on CMake 2.6 and greater
+  #set_property (SOURCE ${HEADERS}
+  #       PROPERTY MACOSX_PACKAGE_LOCATION Headers/${NAME}
+  #)
+endmacro (IDE_SOURCE_PROPERTIES)
+
+#-------------------------------------------------------------------------------
+macro (TARGET_NAMING libtarget libtype)
+  if (${libtype} MATCHES "SHARED")
+    set_target_properties (${libtarget} PROPERTIES OUTPUT_NAME "${libtarget}${ARGN}")
+  endif (${libtype} MATCHES "SHARED")
+endmacro (TARGET_NAMING)
+
+#-------------------------------------------------------------------------------
+macro (INSTALL_TARGET_PDB libtarget targetdestination targetcomponent)
+  if (WIN32 AND MSVC)
+    get_target_property (target_name ${libtarget} OUTPUT_NAME_RELWITHDEBINFO)
+    install (
+      FILES
+          ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${CMAKE_BUILD_TYPE}/${CMAKE_IMPORT_LIBRARY_PREFIX}${target_name}.pdb
+      DESTINATION
+          ${targetdestination}
+      CONFIGURATIONS RelWithDebInfo
+      COMPONENT ${targetcomponent}
+  )
+  endif (WIN32 AND MSVC)
+endmacro (INSTALL_TARGET_PDB)
+
+#-------------------------------------------------------------------------------
+macro (INSTALL_PROGRAM_PDB progtarget targetdestination targetcomponent)
+  if (WIN32 AND MSVC)
+    get_target_property (target_name ${progtarget} OUTPUT_NAME_RELWITHDEBINFO)
+    get_target_property (target_prefix ${progtarget} PREFIX)
+    install (
+      FILES
+          ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${CMAKE_BUILD_TYPE}/${target_prefix}${target_name}.pdb
+      DESTINATION
+          ${targetdestination}
+      CONFIGURATIONS RelWithDebInfo
+      COMPONENT ${targetcomponent}
+  )
+  endif (WIN32 AND MSVC)
+endmacro (INSTALL_PROGRAM_PDB)
+
+#-------------------------------------------------------------------------------
+macro (HDF_SET_LIB_OPTIONS libtarget libname libtype)
+  if (${libtype} MATCHES "SHARED")
+    if (WIN32)
+      set (LIB_RELEASE_NAME "${libname}")
+      set (LIB_DEBUG_NAME "${libname}_D")
+    else (WIN32)
+      set (LIB_RELEASE_NAME "${libname}")
+      set (LIB_DEBUG_NAME "${libname}_debug")
+    endif (WIN32)
+  else (${libtype} MATCHES "SHARED")
+    if (WIN32)
+      set (LIB_RELEASE_NAME "lib${libname}")
+      set (LIB_DEBUG_NAME "lib${libname}_D")
+    else (WIN32)
+      set (LIB_RELEASE_NAME "${libname}")
+      set (LIB_DEBUG_NAME "${libname}_debug")
+    endif (WIN32)
+  endif (${libtype} MATCHES "SHARED")
+  
+  set_target_properties (${libtarget}
+      PROPERTIES
+      OUTPUT_NAME_DEBUG          ${LIB_DEBUG_NAME}
+      OUTPUT_NAME_RELEASE        ${LIB_RELEASE_NAME}
+      OUTPUT_NAME_MINSIZEREL     ${LIB_RELEASE_NAME}
+      OUTPUT_NAME_RELWITHDEBINFO ${LIB_RELEASE_NAME}
+  )
+  
+  #----- Use MSVC Naming conventions for Shared Libraries
+  if (MINGW AND ${libtype} MATCHES "SHARED")
+    set_target_properties (${libtarget}
+        PROPERTIES
+        IMPORT_SUFFIX ".lib"
+        IMPORT_PREFIX ""
+        PREFIX ""
+    )
+  endif (MINGW AND ${libtype} MATCHES "SHARED")
+
+endmacro (HDF_SET_LIB_OPTIONS)
+
+#-------------------------------------------------------------------------------
+macro (HDF_IMPORT_SET_LIB_OPTIONS libtarget libname libtype libversion)
+  HDF_SET_LIB_OPTIONS (${libtarget} ${libname} ${libtype})
+
+  if (${importtype} MATCHES "IMPORT")
+    set (importprefix "${CMAKE_STATIC_LIBRARY_PREFIX}")
+  endif (${importtype} MATCHES "IMPORT")
+  if (${CMAKE_BUILD_TYPE} MATCHES "Debug")
+    set (IMPORT_LIB_NAME ${LIB_DEBUG_NAME})
+  else (${CMAKE_BUILD_TYPE} MATCHES "Debug")
+    set (IMPORT_LIB_NAME ${LIB_RELEASE_NAME})
+  endif (${CMAKE_BUILD_TYPE} MATCHES "Debug")
+
+  if (${libtype} MATCHES "SHARED")
+    if (WIN32)
+      if (MINGW)
+        set_target_properties (${libtarget} PROPERTIES
+            IMPORTED_IMPLIB "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${IMPORT_LIB_NAME}.lib"
+            IMPORTED_LOCATION "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${IMPORT_LIB_NAME}${CMAKE_SHARED_LIBRARY_SUFFIX}"
+        )
+      else (MINGW)
+        set_target_properties (${libtarget} PROPERTIES
+            IMPORTED_IMPLIB "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${CMAKE_BUILD_TYPE}/${CMAKE_IMPORT_LIBRARY_PREFIX}${IMPORT_LIB_NAME}${CMAKE_IMPORT_LIBRARY_SUFFIX}"
+            IMPORTED_LOCATION "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${CMAKE_BUILD_TYPE}/${CMAKE_IMPORT_LIBRARY_PREFIX}${IMPORT_LIB_NAME}${CMAKE_SHARED_LIBRARY_SUFFIX}"
+         )
+      endif (MINGW)
+    else (WIN32)
+      if (CYGWIN)
+        set_target_properties (${libtarget} PROPERTIES
+            IMPORTED_IMPLIB "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${CMAKE_IMPORT_LIBRARY_PREFIX}${IMPORT_LIB_NAME}${CMAKE_IMPORT_LIBRARY_SUFFIX}"
+            IMPORTED_LOCATION "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${CMAKE_IMPORT_LIBRARY_PREFIX}${IMPORT_LIB_NAME}${CMAKE_SHARED_LIBRARY_SUFFIX}"
+        )
+      else (CYGWIN)
+        set_target_properties (${libtarget} PROPERTIES
+            IMPORTED_LOCATION "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${CMAKE_SHARED_LIBRARY_PREFIX}${IMPORT_LIB_NAME}${CMAKE_SHARED_LIBRARY_SUFFIX}"
+            IMPORTED_SONAME "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${CMAKE_SHARED_LIBRARY_PREFIX}${IMPORT_LIB_NAME}${CMAKE_SHARED_LIBRARY_SUFFIX}.${libversion}"
+            SOVERSION "${libversion}"
+        )
+      endif (CYGWIN)
+    endif (WIN32)
+  else (${libtype} MATCHES "SHARED")
+    if (WIN32 AND NOT MINGW)
+      set_target_properties (${libtarget} PROPERTIES
+          IMPORTED_LOCATION "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${CMAKE_BUILD_TYPE}/${IMPORT_LIB_NAME}${CMAKE_STATIC_LIBRARY_SUFFIX}"
+          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+      )
+    else (WIN32 AND NOT MINGW)
+      set_target_properties (${libtarget} PROPERTIES
+          IMPORTED_LOCATION "${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/${CMAKE_STATIC_LIBRARY_PREFIX}${IMPORT_LIB_NAME}${CMAKE_STATIC_LIBRARY_SUFFIX}"
+          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+      )
+    endif (WIN32 AND NOT MINGW)
+  endif (${libtype} MATCHES "SHARED")
+
+endmacro (HDF_IMPORT_SET_LIB_OPTIONS)
+
+#-------------------------------------------------------------------------------
+macro (TARGET_C_PROPERTIES wintarget libtype addcompileflags addlinkflags)
+  if (MSVC)
+    TARGET_MSVC_PROPERTIES (${wintarget} ${libtype} "${addcompileflags} ${WIN_COMPILE_FLAGS}" "${addlinkflags} ${WIN_LINK_FLAGS}")
+  else (MSVC)
+    set_target_properties (${wintarget}
+        PROPERTIES
+            COMPILE_FLAGS "${addcompileflags}"
+            LINK_FLAGS "${addlinkflags}"
+    ) 
+  endif (MSVC)
+endmacro (TARGET_C_PROPERTIES)
+
+#-------------------------------------------------------------------------------
+macro (TARGET_MSVC_PROPERTIES wintarget libtype addcompileflags addlinkflags)
+  if (MSVC)
+    set_target_properties (${wintarget}
+        PROPERTIES
+            COMPILE_FLAGS "${addcompileflags}"
+            LINK_FLAGS "${addlinkflags}"
+    ) 
+  endif (MSVC)
+endmacro (TARGET_MSVC_PROPERTIES)
+
+#-------------------------------------------------------------------------------
+macro (TARGET_FORTRAN_PROPERTIES forttarget libtype addcompileflags addlinkflags)
+  if (WIN32)
+    TARGET_FORTRAN_WIN_PROPERTIES (${forttarget} ${libtype} "${addcompileflags} ${WIN_COMPILE_FLAGS}" "${addlinkflags} ${WIN_LINK_FLAGS}")
+  endif (WIN32)
+endmacro (TARGET_FORTRAN_PROPERTIES)
+
+#-------------------------------------------------------------------------------
+macro (TARGET_FORTRAN_WIN_PROPERTIES forttarget libtype addcompileflags addlinkflags)
+  if (MSVC)
+    if (${libtype} MATCHES "SHARED")
+      set_target_properties (${forttarget}
+          PROPERTIES
+              COMPILE_FLAGS "/dll ${addcompileflags}"
+              LINK_FLAGS "/SUBSYSTEM:CONSOLE ${addlinkflags}"
+      ) 
+    else (${libtype} MATCHES "SHARED")
+      set_target_properties (${forttarget}
+          PROPERTIES
+              COMPILE_FLAGS "${addcompileflags}"
+              LINK_FLAGS "/SUBSYSTEM:CONSOLE ${addlinkflags}"
+      ) 
+    endif (${libtype} MATCHES "SHARED")
+  endif (MSVC)
+endmacro (TARGET_FORTRAN_WIN_PROPERTIES)
+
+#-----------------------------------------------------------------------------
+# Configure the README.txt file for the binary package
+#-----------------------------------------------------------------------------
+macro (HDF_README_PROPERTIES target_fortran)
+  set (BINARY_SYSTEM_NAME ${CMAKE_SYSTEM_NAME})
+  set (BINARY_PLATFORM "${CMAKE_SYSTEM_NAME}")
+  if (WIN32)
+    set (BINARY_EXAMPLE_ENDING "zip")
+    set (BINARY_INSTALL_ENDING "msi")
+    if (CMAKE_CL_64)
+      set (BINARY_SYSTEM_NAME "win64")
+    else (CMAKE_CL_64)
+      set (BINARY_SYSTEM_NAME "win32")
+    endif (CMAKE_CL_64)
+    if (${CMAKE_SYSTEM_VERSION} MATCHES "6.1")
+      set (BINARY_PLATFORM "${BINARY_PLATFORM} 7")
+    elseif (${CMAKE_SYSTEM_VERSION} MATCHES "6.2")
+      set (BINARY_PLATFORM "${BINARY_PLATFORM} 8")
+    endif (${CMAKE_SYSTEM_VERSION} MATCHES "6.1")
+    set (BINARY_PLATFORM "${BINARY_PLATFORM} ${MSVC_C_ARCHITECTURE_ID}")
+    if (${CMAKE_C_COMPILER_VERSION} MATCHES "16.*")
+      set (BINARY_PLATFORM "${BINARY_PLATFORM}, using VISUAL STUDIO 2010")
+    elseif (${CMAKE_C_COMPILER_VERSION} MATCHES "15.*")
+      set (BINARY_PLATFORM "${BINARY_PLATFORM}, using VISUAL STUDIO 2008")
+    elseif (${CMAKE_C_COMPILER_VERSION} MATCHES "17.*")
+      set (BINARY_PLATFORM "${BINARY_PLATFORM}, using VISUAL STUDIO 2012")
+    elseif (${CMAKE_C_COMPILER_VERSION} MATCHES "18.*")
+      set (BINARY_PLATFORM "${BINARY_PLATFORM}, using VISUAL STUDIO 2013")
+    else (${CMAKE_C_COMPILER_VERSION} MATCHES "16.*")
+      set (BINARY_PLATFORM "${BINARY_PLATFORM}, using VISUAL STUDIO ${CMAKE_C_COMPILER_VERSION}")
+    endif (${CMAKE_C_COMPILER_VERSION} MATCHES "16.*")
+  elseif (APPLE)
+    set (BINARY_EXAMPLE_ENDING "tar.gz")
+    set (BINARY_INSTALL_ENDING "dmg")
+    set (BINARY_PLATFORM "${BINARY_PLATFORM} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR}")
+    set (BINARY_PLATFORM "${BINARY_PLATFORM}, using ${CMAKE_C_COMPILER_ID} C ${CMAKE_C_COMPILER_VERSION}")
+  else (WIN32)
+    set (BINARY_EXAMPLE_ENDING "tar.gz")
+    set (BINARY_INSTALL_ENDING "sh")
+    set (BINARY_PLATFORM "${BINARY_PLATFORM} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR}")
+    set (BINARY_PLATFORM "${BINARY_PLATFORM}, using ${CMAKE_C_COMPILER_ID} C ${CMAKE_C_COMPILER_VERSION}")
+  endif (WIN32)
+
+  if (target_fortran)
+    set (BINARY_PLATFORM "${BINARY_PLATFORM} / ${CMAKE_Fortran_COMPILER_ID} Fortran")
+  endif (target_fortran)
+
+  if (BUILD_SHARED_LIBS)
+    set (LIB_TYPE "Static and Shared")
+  else (BUILD_SHARED_LIBS)
+    set (LIB_TYPE "Static")
+  endif (BUILD_SHARED_LIBS)
+    
+  configure_file (
+      ${HDF_RESOURCES_DIR}/README.txt.cmake.in 
+      ${CMAKE_BINARY_DIR}/README.txt @ONLY
+  )
+endmacro (HDF_README_PROPERTIES)