[svn-r1315] Changes since 19990607

----------------------

./configure.in
./configure			[REGENERATED]
./src/libhdf5.settings.in	[NEW]
./config/conclude.in
./INSTALL
./MANIFEST
	A file called `libhdf5.settings' is installed along with the
	libraries and it contains a list of various things that might
	be of interest to someone using the library (such as what
	compiler/options were used and what other libraries might need
	to be linked to satisfy external references).  We can add more
	things as it becomes necessary. Here's a sample...

	SUMMARY OF THE HDF5 CONFIGURATION
	=================================

	HDF5 Version:		hdf5-1.1.106
	Configured on:		Tue Jun  8 11:38:52 EDT 1999
	Configured by:		matzke@llnl.gov at Spizella Software
	Configure mode:		development
	Host system:		i686-pc-linux-gnulibc1
	Byte sex:		little-endian
	Libraries:		static, shared
	Parallel support:	mpicc
	Installation point:	/usr/local
	Compiler:		mpicc (egcs-2.91.66)
	Compiler switches:	-Wall -g
	Extra libraries:	-lmfhdf -ldf -lz -ljpeg -lm
	Archiver:		ar
	Ranlib:			ranlib
	Debugged Packages:	d,e,f,g,hg,i,mm,o,p,s,v,z
	API Tracing:		yes
	File addresses:		large

1 files changed, 70 insertions, 5 deletions

diff --git a/configure.in b/configure.in
index 887ad5e..ec49b7f 100644
--- a/configure.in
+++ b/configure.in
@@ -129,7 +129,8 @@ if test Xyes = "X$GCC"; then
 fi
 
 dnl ----------------------------------------------------------------------
-dnl Production flags?
+dnl Production flags?  Save the value in $CONFIG_MODE so we have it for
+dnl the record.
 dnl
 AC_MSG_CHECKING(for production mode)
 AC_ARG_ENABLE(production,
@@ -138,21 +139,25 @@ AC_ARG_ENABLE(production,
 case "X-$enableval" in
    X-yes)
       AC_MSG_RESULT("production")
+      CONFIG_MODE=production
       CFLAGS="$CFLAGS $PROD_CFLAGS"
       CPPFLAGS="$CPPFLAGS $PROD_CPPFLAGS"
       ;;
    X-|X-no)
       AC_MSG_RESULT("development")
+      CONFIG_MODE=development
       CFLAGS="$CFLAGS $DEBUG_CFLAGS"
       CPPFLAGS="$CPPFLAGS $DEBUG_CPPFLAGS"
       ;;
    X-pg|X-profile)
       AC_MSG_RESULT("profile")
+      CONFIG_MODE=profile
       CFLAGS="$CFLAGS $PROFILE_CFLAGS"
       CPPFLAGS="$CPPFLAGS $PROFILE_CPPFLAGS"
       ;;
    *)
       AC_MSG_RESULT("user-defined")
+      CONFIG_MODE="$X-enableval"
       ;;
 esac
 
@@ -230,12 +235,15 @@ AC_ARG_ENABLE(hsizet,
                           or 'size_t'.],
   HSIZET=$enableval)
 AC_MSG_CHECKING(for sizeof hsize_t and hssize_t)
+AC_SUBST(HSIZET)
 case $HSIZET in
     no|small)
 	AC_MSG_RESULT(small)
+	HSIZET=small
 	;;
     *)
         AC_MSG_RESULT(large)
+	HSIZET=large
         AC_DEFINE(HAVE_LARGE_HSIZET)
 	;;
 esac
@@ -475,6 +483,7 @@ AC_ARG_ENABLE(debug,
                           is most packages.],
   DEBUG_PKG=$enableval)
 
+AC_SUBST(DEBUG_PKG)
 all_packages="ac,b,d,e,f,g,hg,hl,i,mf,mm,o,p,s,t,v,z"
 if test X = "X$DEBUG_PKG" -o Xyes = "X$DEBUG_PKG"; then
    DEBUG_PKG="d,e,f,g,hg,i,mm,o,p,s,v,z"
@@ -506,8 +515,10 @@ AC_ARG_ENABLE(trace,
   [  --disable-trace         Disable API tracing capability],
   TRACE=$enableval)
 
+AC_SUBST(TRACE_API)
 if test X = "X$TRACE" -o Xyes = "X$TRACE"; then
    AC_MSG_RESULT(yes)
+   TRACE_API=yes
    CPPFLAGS="$CPPFLAGS -DH5_DEBUG_API"
 else
    AC_MSG_RESULT(no)
@@ -551,6 +562,7 @@ dnl			   protect the expansion until make executes the
 dnl			   command).  The value of this variable is
 dnl			   substituted in *.in files.
 dnl
+AC_SUBST(PARALLEL)
 AC_SUBST(RUNSERIAL)
 AC_SUBST(RUNPARALLEL)
 AC_SUBST(TESTPARALLEL)
@@ -566,7 +578,7 @@ case "$CC_BASENAME" in
     mpicc)
 	# The mpich compiler. Use mpirun from the same directory if it
 	# exists.
-	PARALLEL=yes
+	PARALLEL=mpicc
 	AC_MSG_CHECKING(for mpirun)
 
 	# Find the path where mpicc is located.
@@ -595,7 +607,7 @@ case "$CC_BASENAME" in
 
     mpcc|mpcc_r)
 	# The IBM compiler
-	PARALLEL=yes
+	PARALLEL="$CC_BASENAME"
 	;;
 
     *)
@@ -644,7 +656,7 @@ case "X-$enable_parallel" in
 	# for the libraries in order to get the onto the link line, the user
 	# will have already told us about the locations. Fail if something
 	# is missing.
-	PARALLEL=yes
+	PARALLEL=mpich
 	AC_CHECK_LIB(mpich,MPI_Init,,AC_MSG_ERROR(no mpich library))
 	;;
 
@@ -699,6 +711,59 @@ dnl	        AC_MSG_ERROR('unable to link a simple MPI-IO application'))
 fi
 
 dnl ----------------------------------------------------------------------
+dnl Set some variables for general configuration information to be saved
+dnl and installed with the libraries.
+dnl
+
+# HDF5 version from the first line of the README file.
+H5_VERSION=`cut -d' ' -f3 $srcdir/README |head -1`
+AC_SUBST(H5_VERSION)
+
+# Configuration date
+AC_SUBST(CONFIG_DATE) CONFIG_DATE=`date`
+
+# User doing the configuration
+AC_SUBST(CONFIG_USER) CONFIG_USER="$USER@`hostname`"
+if test "X-$ORGANIZATION" != "X-"; then
+    CONFIG_USER="$CONFIG_USER at $ORGANIZATION"
+fi
+
+# Configuration mode (production, development, profile, etc) saved above.
+AC_SUBST(CONFIG_MODE)
+
+# Byte sex from the AC_C_BIGENDIAN macro.
+AC_SUBST(BYTESEX)
+if test "X-$WORDS_BIGENDIAN" = "X-"; then
+    BYTESEX="little-endian"
+else
+    BYTESEX="big-endian"
+fi
+
+# Are we compiling static libraries, shared libraries, or both?
+AC_SUBST(STATIC_SHARED)
+if test "X-$enable_static" = "X-yes" && test "X-$enable_shared" = "X-yes"; then
+    STATIC_SHARED="static, shared"
+elif test "X-$enable_static" = "X-yes"; then
+    STATIC_SHARED="static"
+elif test "X-$enable_shared" = "X-yes"; then
+    STATIC_SHARED="shared"
+else
+    STATIC_SHARED="none"
+fi
+
+# Parallel support? (set above except empty if none)
+PARALLEL=${PARALLEL:-no}
+
+# Compiler with version information
+AC_SUBST(CC_VERSION)
+if test "X-$cc_vendor" != "X-" && test "X-$cc_version" != "X-"; then
+    CC_VERSION="$CC ($cc_vendor-$cc_version)"
+else
+    CC_VERSION="$CC"
+fi
+
+
+dnl ----------------------------------------------------------------------
 dnl Build the Makefiles.  Almost every Makefile.in will begin with the line
 dnl `@COMMENCE@' and end with the line `@CONCLUDE@'.  These lines insert
 dnl various files from the config directory into the Makefile.
@@ -752,7 +817,7 @@ touch ./config/stamp1
 # Then the config.status file (but not makefiles)
 saved_no_create=$no_create
 no_create=yes
-AC_OUTPUT(config/depend config/commence config/conclude \
+AC_OUTPUT(src/libhdf5.settings config/depend config/commence config/conclude \
           Makefile src/Makefile pablo/Makefile test/Makefile \
           testpar/Makefile tools/Makefile examples/Makefile)
 no_create=$saved_no_create