[svn-r29155] HDFFV-9652: Add fortran wrappers/test for collective metadata functions

Tested: h5committest.new

2 files changed, 187 insertions, 0 deletions

diff --git a/fortran/src/H5Pff.F90 b/fortran/src/H5Pff.F90
index 6c6abe4..e66a7f2 100644
--- a/fortran/src/H5Pff.F90
+++ b/fortran/src/H5Pff.F90
@@ -7320,6 +7320,188 @@ SUBROUTINE h5pset_attr_phase_change_f(ocpl_id, max_compact, min_dense, hdferr)
     hdferr = h5pget_mpio_actual_io_mode_c(dxpl_id, actual_io_mode)
 
   END SUBROUTINE h5pget_mpio_actual_io_mode_f
+
+!****s* H5P/h5pset_all_coll_metadata_ops_f
+! NAME
+!  h5pset_all_coll_metadata_ops_f
+!
+! PURPOSE
+!  Sets requirement whether HDF5 metadata read operations using the access property 
+!  list are required to be collective or independent. If collective requirement is 
+!  selected, the HDF5 library will optimize the metadata reads improving performance. 
+!  The default setting is independent (false).
+!
+! INPUTS
+!  plist_id       - File access property list identifier.
+!  is_collective  - Indicates if metadata writes are collective or not.
+! OUTPUTS
+!  hdferr         - Returns 0 if successful and -1 if fails.
+!
+! AUTHOR
+!  M. Scot Breitenfeld
+!  Feb, 10 2016
+!
+! HISTORY
+!
+! SOURCE
+  SUBROUTINE h5pset_all_coll_metadata_ops_f(plist_id, is_collective, hdferr)
+    IMPLICIT NONE
+    INTEGER(HID_T)  , INTENT(IN)  :: plist_id
+    LOGICAL, INTENT(IN)           :: is_collective
+    INTEGER, INTENT(OUT)          :: hdferr
+!*****
+    LOGICAL(C_BOOL) :: c_is_collective
+    
+    INTERFACE
+       INTEGER FUNCTION h5pset_all_coll_metadata_ops(plist_id, is_collective) BIND(C, NAME='H5Pset_all_coll_metadata_ops')
+         IMPORT :: HID_T, C_BOOL
+         IMPLICIT NONE
+         INTEGER(HID_T) , INTENT(IN), VALUE :: plist_id
+         LOGICAL(C_BOOL), INTENT(IN), VALUE :: is_collective
+       END FUNCTION h5pset_all_coll_metadata_ops
+    END INTERFACE
+
+    ! Transfer value of Fortran LOGICAL to C c_bool type
+    c_is_collective = is_collective
+    
+    hdferr = INT(H5Pset_all_coll_metadata_ops(plist_id, c_is_collective))
+    
+  END SUBROUTINE h5pset_all_coll_metadata_ops_f
+
+!****s* H5P/h5pget_all_coll_metadata_ops_f 
+! NAME
+!  h5pget_all_coll_metadata_ops_f
+!
+! PURPOSE
+!  Retrieves metadata read mode from the access property list.
+!
+! INPUTS
+!  plist_id        - File access property list identifier.
+! OUTPUTS
+!  is_collective   - Collective access setting.
+!  hdferr          - Returns 0 if successful and -1 if fails.
+!
+! AUTHOR
+!  M. Scot Breitenfeld
+!  Feb, 10 2016
+!
+! HISTORY
+!
+! SOURCE
+  SUBROUTINE h5pget_all_coll_metadata_ops_f(plist_id, is_collective, hdferr)
+    
+    IMPLICIT NONE
+    INTEGER(HID_T)  , INTENT(IN)  :: plist_id
+    LOGICAL, INTENT(OUT)          :: is_collective
+    INTEGER, INTENT(OUT)          :: hdferr
+!*****
+    LOGICAL(C_BOOL) :: c_is_collective
+    
+    INTERFACE
+       INTEGER FUNCTION h5pget_all_coll_metadata_ops(plist_id, is_collective) BIND(C, NAME='H5Pget_all_coll_metadata_ops')
+         IMPORT :: HID_T, C_BOOL
+         IMPLICIT NONE
+         INTEGER(HID_T) , INTENT(IN), VALUE :: plist_id
+         LOGICAL(C_BOOL), INTENT(OUT) :: is_collective
+       END FUNCTION h5pget_all_coll_metadata_ops
+    END INTERFACE
+    
+    hdferr = INT(H5Pget_all_coll_metadata_ops(plist_id, c_is_collective))
+    
+    ! Transfer value of C c_bool type to Fortran LOGICAL 
+    is_collective = c_is_collective
+    
+  END SUBROUTINE h5pget_all_coll_metadata_ops_f
+
+!****s* H5P/h5pset_coll_metadata_write_f
+! NAME
+!  h5pset_coll_metadata_write_f
+!
+! PURPOSE
+!  Sets metadata writes to collective or independent. Default setting is independent (false).
+!
+! INPUTS
+!  fapl_id        - File access property list identifier.
+!  is_collective  - Indicates if metadata writes are collective or not.
+! OUTPUTS
+!  hdferr         - Returns 0 if successful and -1 if fails.
+!
+! AUTHOR
+!  M. Scot Breitenfeld
+!  Feb, 10 2016
+!
+! HISTORY
+!
+! SOURCE
+  SUBROUTINE h5pset_coll_metadata_write_f(plist_id, is_collective, hdferr)
+    IMPLICIT NONE
+    INTEGER(HID_T)  , INTENT(IN)  :: plist_id
+    LOGICAL, INTENT(IN)           :: is_collective
+    INTEGER, INTENT(OUT)          :: hdferr
+!*****
+    LOGICAL(C_BOOL) :: c_is_collective
+    
+    INTERFACE
+       INTEGER FUNCTION h5pset_coll_metadata_write(plist_id, is_collective) BIND(C, NAME='H5Pset_coll_metadata_write')
+         IMPORT :: HID_T, C_BOOL
+         IMPLICIT NONE
+         INTEGER(HID_T) , INTENT(IN), VALUE :: plist_id
+         LOGICAL(C_BOOL), INTENT(IN), VALUE :: is_collective
+       END FUNCTION h5pset_coll_metadata_write
+    END INTERFACE
+    
+    ! Transfer value of Fortran LOGICAL to C c_bool type
+    c_is_collective = is_collective
+    
+    hdferr = INT(H5Pset_coll_metadata_write(plist_id, c_is_collective))
+    
+  END SUBROUTINE h5pset_coll_metadata_write_f
+
+!****s* H5P/h5pget_coll_metadata_write_f
+! NAME
+!  h5pget_coll_metadata_write_f
+!
+! PURPOSE
+!  Retrieves metadata write mode from the file access property list.
+!
+! INPUTS
+!  plist_id        - File access property list identifier.
+! OUTPUTS
+!  is_collective   - Collective access setting.
+!  hdferr          - Returns 0 if successful and -1 if fails.
+!
+! AUTHOR
+!  M. Scot Breitenfeld
+!  Feb, 10 2016
+!
+! HISTORY
+!
+! SOURCE
+  SUBROUTINE h5pget_coll_metadata_write_f(plist_id, is_collective, hdferr)
+    
+    IMPLICIT NONE
+    INTEGER(HID_T)  , INTENT(IN)  :: plist_id
+    LOGICAL, INTENT(OUT)          :: is_collective
+    INTEGER, INTENT(OUT)          :: hdferr
+!*****
+    LOGICAL(C_BOOL) :: c_is_collective
+    
+    INTERFACE
+       INTEGER FUNCTION h5pget_coll_metadata_write(plist_id, is_collective) BIND(C, NAME='H5Pget_coll_metadata_write')
+         IMPORT :: HID_T, C_BOOL
+         IMPLICIT NONE
+         INTEGER(HID_T) , INTENT(IN), VALUE :: plist_id
+         LOGICAL(C_BOOL), INTENT(OUT) :: is_collective
+       END FUNCTION h5pget_coll_metadata_write
+    END INTERFACE
+    
+    hdferr = INT(H5Pget_coll_metadata_write(plist_id, c_is_collective))
+    
+    ! Transfer value of C c_bool type to Fortran LOGICAL 
+    is_collective = c_is_collective
+    
+  END SUBROUTINE h5pget_coll_metadata_write_f
+  
 #endif
 
 !
@@ -7836,6 +8018,7 @@ SUBROUTINE h5pget_virtual_dsetname_f(dcpl_id, index, name, hdferr, name_len)
 
 END SUBROUTINE h5pget_virtual_dsetname_f
 
+
 END MODULE H5P
 
 
diff --git a/fortran/src/hdf5_fortrandll.def.in b/fortran/src/hdf5_fortrandll.def.in
index 42b5642..3a5a91f 100644
--- a/fortran/src/hdf5_fortrandll.def.in
+++ b/fortran/src/hdf5_fortrandll.def.in
@@ -334,6 +334,10 @@ H5P_mp_H5PGET_VIRTUAL_DSETNAME_F
 @H5_NOPAREXP@H5P_mp_H5PSET_DXPL_MPIO_F
 @H5_NOPAREXP@H5P_mp_H5PGET_DXPL_MPIO_F
 @H5_NOPAREXP@H5P_mp_H5PGET_MPIO_ACTUAL_IO_MODE_F
+@H5_NOPAREXP@H5P_mp_H5PSET_ALL_COLL_METADATA_OPS_F
+@H5_NOPAREXP@H5P_mp_H5PGET_ALL_COLL_METADATA_OPS_F
+@H5_NOPAREXP@H5P_mp_H5PSET_COLL_METADATA_WRITE_F
+@H5_NOPAREXP@H5P_mp_H5PGET_COLL_METADATA_WRITE_F
 ; H5R
 H5R_mp_H5RCREATE_OBJECT_F
 H5R_mp_H5RCREATE_REGION_F