Added fixes for Tcl Bug 999544 (ported from core-8-4-branch).

1 files changed, 397 insertions, 0 deletions

diff --git a/unix/tcl.m4 b/unix/tcl.m4
index e1ef439..39bcb34 100644
--- a/unix/tcl.m4
+++ b/unix/tcl.m4
@@ -2785,6 +2785,403 @@ AC_DEFUN([SC_TCL_CHECK_BROKEN_FUNC],[
     fi
 ])
 
+#--------------------------------------------------------------------
+# SC_TCL_GETHOSTBYADDR_R
+#
+#	Check if we have MT-safe variant of gethostbyaddr().
+#
+# Arguments:
+#	None
+#	
+# Results:
+#
+#	Might define the following vars:
+#		HAVE_GETHOSTBYADDR_R
+#		HAVE_GETHOSTBYADDR_R_7
+#		HAVE_GETHOSTBYADDR_R_8
+#
+#--------------------------------------------------------------------
+
+AC_DEFUN([SC_TCL_GETHOSTBYADDR_R], [AC_CHECK_FUNC(gethostbyaddr_r, [
+    AC_MSG_CHECKING([for gethostbyaddr_r with 7 args])
+    AC_TRY_COMPILE([
+        #include <netdb.h>
+    ], [
+        char *addr;
+        int length;
+        int type;
+        struct hostent *result;
+        char buffer[2048];
+        int buflen = 2048;
+        int h_errnop;
+
+        (void) gethostbyaddr_r(addr, length, type, result, buffer, buflen,
+                               &h_errnop);
+    ], [
+        AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
+            [Define to 1 if gethostbyaddr_r is available.])
+        AC_DEFINE(HAVE_GETHOSTBYADDR_R_7, 1,
+            [Define to 1 if gethostbyaddr_r takes 7 args.])
+        AC_MSG_RESULT(yes)
+    ], [
+        AC_MSG_RESULT(no)
+        AC_MSG_CHECKING([for gethostbyaddr_r with 8 args])
+        AC_TRY_COMPILE([
+            #include <netdb.h>
+        ], [
+            char *addr;
+            int length;
+            int type;
+            struct hostent *result, *resultp;
+            char buffer[2048];
+            int buflen = 2048;
+            int h_errnop;
+
+            (void) gethostbyaddr_r(addr, length, type, result, buffer, buflen,
+                                   &resultp, &h_errnop);
+        ], [
+            AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
+                [Define to 1 if gethostbyaddr_r is available.])
+            AC_DEFINE(HAVE_GETHOSTBYADDR_R_8, 1,
+                [Define to 1 if gethostbyaddr_r takes 8 args.])
+            AC_MSG_RESULT(yes)
+        ], [
+            AC_MSG_RESULT(no)
+
+        ])
+    ])
+])
+])
+
+#--------------------------------------------------------------------
+# SC_TCL_GETHOSTBYNAME_R
+#
+#	Check to see what variant of gethostbyname_r() we have.
+#	Based on David Arnold's example from the comp.programming.threads
+#	FAQ Q213
+#
+# Arguments:
+#	None
+#	
+# Results:
+#
+#	Might define the following vars:
+#		HAVE_GETHOSTBYADDR_R
+#		HAVE_GETHOSTBYADDR_R_3
+#		HAVE_GETHOSTBYADDR_R_5
+#		HAVE_GETHOSTBYADDR_R_6
+#
+#--------------------------------------------------------------------
+
+AC_DEFUN([SC_TCL_GETHOSTBYNAME_R], [AC_CHECK_FUNC(gethostbyname_r, [
+    AC_MSG_CHECKING([for gethostbyname_r with 6 args])
+    AC_TRY_COMPILE([
+        #include <netdb.h>
+    ], [
+        char *name;
+        struct hostent *he, *res;
+        char buffer[2048];
+        int buflen = 2048;
+        int h_errnop;
+
+        (void) gethostbyname_r(name, he, buffer, buflen, &res, &h_errnop);
+    ], [
+        AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
+            [Define to 1 if gethostbyname_r is available.])
+        AC_DEFINE(HAVE_GETHOSTBYNAME_R_6, 1,
+            [Define to 1 if gethostbyname_r takes 6 args.])
+        AC_MSG_RESULT(yes)
+    ], [
+        AC_MSG_RESULT(no)
+        AC_MSG_CHECKING([for gethostbyname_r with 5 args])
+        AC_TRY_COMPILE([
+            #include <netdb.h>
+        ], [
+            char *name;
+            struct hostent *he;
+            char buffer[2048];
+            int buflen = 2048;
+            int h_errnop;
+
+            (void) gethostbyname_r(name, he, buffer, buflen, &h_errnop);
+        ], [
+            AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
+                [Define to 1 if gethostbyname_r is available.])
+            AC_DEFINE(HAVE_GETHOSTBYNAME_R_5, 1,
+                [Define to 1 if gethostbyname_r takes 5 args.])
+            AC_MSG_RESULT(yes)
+        ], [
+            AC_MSG_RESULT(no)
+            AC_MSG_CHECKING([for gethostbyname_r with 3 args])
+            AC_TRY_COMPILE([
+                #include <netdb.h>
+            ], [
+                char *name;
+                struct hostent *he;
+                struct hostent_data data;
+
+                (void) gethostbyname_r(name, he, &data);
+            ], [
+                AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
+                    [Define to 1 if gethostbyname_r is available.])
+                AC_DEFINE(HAVE_GETHOSTBYNAME_R_3, 1,
+                    [Define to 1 if gethostbyname_r takes 3 args.])
+                AC_MSG_RESULT(yes)
+            ], [
+                AC_MSG_RESULT(no)
+            ])
+        ])
+    ])
+])
+])
+
+#--------------------------------------------------------------------
+# SC_TCL_GETPWUID_R
+#
+#	Check if we have MT-safe variant of getpwuid() and if yes,
+#	which one exactly.
+#
+# Arguments:
+#	None
+#	
+# Results:
+#
+#	Might define the following vars:
+#		HAVE_GETPWUID_R
+#		HAVE_GETPWUID_R_4
+#		HAVE_GETPWUID_R_5
+#
+#--------------------------------------------------------------------
+
+AC_DEFUN([SC_TCL_GETPWUID_R], [AC_CHECK_FUNC(getpwuid_r, [
+    AC_MSG_CHECKING([for getpwuid_r with 5 args])
+    AC_TRY_COMPILE([
+        #include <sys/types.h>
+        #include <pwd.h>
+    ], [
+        uid_t uid;
+        struct passwd pw, *pwp;
+        char buf[512];
+        int buflen = 512;
+
+        (void) getpwuid_r(uid, &pw, buf, buflen, &pwp);
+    ], [
+        AC_DEFINE(HAVE_GETPWUID_R, 1,
+            [Define to 1 if getpwuid_r is available.])
+        AC_DEFINE(HAVE_GETPWUID_R_5, 1,
+            [Define to 1 if getpwuid_r takes 5 args.])
+        AC_MSG_RESULT(yes)
+    ], [
+        AC_MSG_RESULT(no)
+        AC_MSG_CHECKING([for getpwuid_r with 4 args])
+        AC_TRY_COMPILE([
+            #include <sys/types.h>
+            #include <pwd.h>
+        ], [
+            uid_t uid;
+            struct passwd pw;
+            char buf[512];
+            int buflen = 512;
+
+            (void)getpwnam_r(uid, &pw, buf, buflen);
+         ], [
+            AC_DEFINE(HAVE_GETPWUID_R, 1,
+                [Define to 1 if getpwuid_r is available.])
+            AC_DEFINE(HAVE_GETPWUID_R_4, 1,
+                [Define to 1 if getpwuid_r takes 4 args.])
+            AC_MSG_RESULT(yes)
+         ], [
+            AC_MSG_RESULT(no)
+         ])
+    ])
+])
+])
+
+#--------------------------------------------------------------------
+# SC_TCL_GETPWNAM_R
+#
+#	Check if we have MT-safe variant of getpwnam() and if yes,
+#	which one exactly.
+#
+# Arguments:
+#	None
+#	
+# Results:
+#
+#	Might define the following vars:
+#		HAVE_GETPWNAM_R
+#		HAVE_GETPWNAM_R_4
+#		HAVE_GETPWNAM_R_5
+#
+#--------------------------------------------------------------------
+
+AC_DEFUN([SC_TCL_GETPWNAM_R], [AC_CHECK_FUNC(getpwnam_r, [
+    AC_MSG_CHECKING([for getpwnam_r with 5 args])
+    AC_TRY_COMPILE([
+        #include <sys/types.h>
+        #include <pwd.h>
+    ], [
+        char *name;
+        struct passwd pw, *pwp;
+        char buf[512];
+        int buflen = 512;
+
+        (void) getpwnam_r(name, &pw, buf, buflen, &pwp);
+    ], [
+        AC_DEFINE(HAVE_GETPWNAM_R, 1,
+            [Define to 1 if getpwnam_r is available.])
+        AC_DEFINE(HAVE_GETPWNAM_R_5, 1,
+            [Define to 1 if getpwnam_r takes 5 args.])
+        AC_MSG_RESULT(yes)
+    ], [
+        AC_MSG_RESULT(no)
+        AC_MSG_CHECKING([for getpwnam_r with 4 args])
+        AC_TRY_COMPILE([
+            #include <sys/types.h>
+            #include <pwd.h>
+        ], [
+            char *name;
+            struct passwd pw;
+            char buf[512];
+            int buflen = 512;
+
+            (void)getpwnam_r(name, &pw, buf, buflen);
+         ], [
+            AC_DEFINE(HAVE_GETPWNAM_R, 1,
+                [Define to 1 if getpwnam_r is available.])
+            AC_DEFINE(HAVE_GETPWNAM_R_4, 1,
+                [Define to 1 if getpwnam_r takes 4 args.])
+            AC_MSG_RESULT(yes)
+         ], [
+            AC_MSG_RESULT(no)
+         ])
+    ])
+])
+])
+
+#--------------------------------------------------------------------
+# SC_TCL_GETGRGID_R
+#
+#	Check if we have MT-safe variant of getgrgid() and if yes,
+#	which one exactly.
+#
+# Arguments:
+#	None
+#	
+# Results:
+#
+#	Might define the following vars:
+#		HAVE_GETGRGID_R
+#		HAVE_GETGRGID_R_4
+#		HAVE_GETGRGID_R_5
+#
+#--------------------------------------------------------------------
+
+AC_DEFUN([SC_TCL_GETGRGID_R], [AC_CHECK_FUNC(getgrgid_r, [
+    AC_MSG_CHECKING([for getgrgid_r with 5 args])
+    AC_TRY_COMPILE([
+        #include <sys/types.h>
+        #include <grp.h>
+    ], [
+        gid_t gid;
+        struct group gr, *grp;
+        char buf[512];
+        int buflen = 512;
+
+        (void) getgrgid_r(gid, &gr, buf, buflen, &grp);
+    ], [
+        AC_DEFINE(HAVE_GETGRGID_R, 1,
+            [Define to 1 if getgrgid_r is available.])
+        AC_DEFINE(HAVE_GETGRGID_R_5, 1,
+            [Define to 1 if getgrgid_r takes 5 args.])
+        AC_MSG_RESULT(yes)
+    ], [
+        AC_MSG_RESULT(no)
+        AC_MSG_CHECKING([for getgrgid_r with 4 args])
+        AC_TRY_COMPILE([
+            #include <sys/types.h>
+            #include <grp.h>
+        ], [
+            gid_t gid;
+            struct group gr;
+            char buf[512];
+            int buflen = 512;
+
+            (void)getgrgid_r(gid, &gr, buf, buflen);
+         ], [
+            AC_DEFINE(HAVE_GETGRGID_R, 1,
+                [Define to 1 if getgrgid_r is available.])
+            AC_DEFINE(HAVE_GETGRGID_R_4, 1,
+                [Define to 1 if getgrgid_r takes 4 args.])
+            AC_MSG_RESULT(yes)
+         ], [
+            AC_MSG_RESULT(no)
+         ])
+    ])
+])
+])
+
+#--------------------------------------------------------------------
+# SC_TCL_GETGRNAM_R
+#
+#	Check if we have MT-safe variant of getgrnam() and if yes,
+#	which one exactly.
+#
+# Arguments:
+#	None
+#	
+# Results:
+#
+#	Might define the following vars:
+#		HAVE_GETGRNAM_R
+#		HAVE_GETGRNAM_R_4
+#		HAVE_GETGRNAM_R_5
+#
+#--------------------------------------------------------------------
+
+AC_DEFUN([SC_TCL_GETGRNAM_R], [AC_CHECK_FUNC(getgrnam_r, [
+    AC_MSG_CHECKING([for getgrnam_r with 5 args])
+    AC_TRY_COMPILE([
+        #include <sys/types.h>
+        #include <grp.h>
+    ], [
+        char *name;
+        struct group gr, *grp;
+        char buf[512];
+        int buflen = 512;
+
+        (void) getgrnam_r(name, &gr, buf, buflen, &grp);
+    ], [
+        AC_DEFINE(HAVE_GETGRNAM_R, 1,
+            [Define to 1 if getgrnam_r is available.])
+        AC_DEFINE(HAVE_GETGRNAM_R_5, 1,
+            [Define to 1 if getgrnam_r takes 5 args.])
+        AC_MSG_RESULT(yes)
+    ], [
+        AC_MSG_RESULT(no)
+        AC_MSG_CHECKING([for getgrnam_r with 4 args])
+        AC_TRY_COMPILE([
+            #include <sys/types.h>
+            #include <grp.h>
+        ], [
+            char *name;
+            struct group gr;
+            char buf[512];
+            int buflen = 512;
+
+            (void)getgrnam_r(name, &gr, buf, buflen);
+         ], [
+            AC_DEFINE(HAVE_GETGRNAM_R, 1,
+                [Define to 1 if getgrnam_r is available.])
+            AC_DEFINE(HAVE_GETGRNAM_R_4, 1,
+                [Define to 1 if getgrnam_r takes 4 args.])
+            AC_MSG_RESULT(yes)
+         ], [
+            AC_MSG_RESULT(no)
+         ])
+    ])
+])
+])
 
 # Local Variables:
 # mode: autoconf