blob: 62c3e98f99b1d27a5c3fba173a7f02b069ffe57c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Tests that the stack size is big enough for the application.
#
# This file contains a collection of tests for one or more of the Tcl
# built-in commands. Sourcing this file into Tcl runs the tests and
# generates output for errors. No output means no errors were found.
#
# Copyright (c) 1998-2000 Ajuba Solutions.
#
# See the file "license.terms" for information on usage and redistribution
# of this file, and for a DISCLAIMER OF ALL WARRANTIES.
package require tcltest 2
namespace import ::tcltest::*
# Note that a failure in this test results in a crash of the executable.
# In order to avoid that, we do a basic check of the current stacksize.
# This size can be changed with ulimit (ksh/bash/sh) or limit (csh/tcsh).
# This doesn't catch all cases, for example threads of lower stacksize
# can still squeak through. A core check is really needed. -- JH
testConstraint minStack2034 1
if {[testConstraint unix]} {
set stackSize [exec /bin/sh -c "ulimit -s"]
if {[string is integer $stackSize] && ($stackSize < 2034)} {
puts stderr "WARNING: the default application stacksize of $stackSize\
may cause Tcl to\ncrash due to stack overflow before the\
recursion limit is reached.\nA minimum stacksize of 2034\
kbytes is recommended.\nSkipping infinite recursion test."
testConstraint minStack2034 0
}
}
#
# Custom match to detect a stack overflow independently of the mechanism that
# triggered the error.
#
customMatch stackOverflow StackOverflow
proc StackOverflow {- res} {
set msgList [list \
"too many nested evaluations (infinite loop?)"\
"out of stack space (infinite loop?)"]
expr {$res in $msgList}
}
test stack-1.1 {maxNestingDepth reached on infinite recursion} -constraints {
minStack2034
} -body {
# do this in a sub process in case it segfaults
exec [interpreter] << {
proc recurse {} { recurse }
catch { recurse } rv
puts $rv
}
} -match stackOverflow
test stack-2.1 {maxNestingDepth reached on infinite recursion} -constraints {
minStack2034
} -body {
# do this in a sub process in case it segfaults
exec [interpreter] << {
interp alias {} unknown {} notaknownproc
catch { unknown } msg
puts $msg
}
} -match stackOverflow
# Make sure that there is enough stack to run regexp even if we're
# close to the recursion limit. [Bug 947070] [Patch 746378]
test stack-3.1 {enough room for regexp near recursion limit} -body {
# do this in a sub process in case it segfaults
exec [interpreter] << {
interp recursionlimit {} 10000
set depth 0
proc a { max } {
if { [info level] < $max } {
set ::depth [info level]
a $max
} else {
regexp {^ ?} x
}
}
catch { a 10001 }
set depth2 $depth
puts [list [a $depth] [expr { $depth2 - $depth }]]
}
} -result {1 1}
# cleanup
::tcltest::cleanupTests
return
# Local Variables:
# mode: tcl
# End:
|
