Tests: Cover NO_SONAME property for SHARED libraries

This property was added by commit v2.8.9~204^2~2 (Support building
shared libraries or modules without soname, 2012-04-22).  A test for
using the property on MODULE libraries was added by commit
v2.8.9~204^2~1 (Test NO_SONAME property, 2012-04-23).  Add such a test
for SHARED libraries too.

3 files changed, 58 insertions, 0 deletions

diff --git a/Tests/ExportImport/Import/A/CMakeLists.txt b/Tests/ExportImport/Import/A/CMakeLists.txt
index 0f56495..5ce9628 100644
--- a/Tests/ExportImport/Import/A/CMakeLists.txt
+++ b/Tests/ExportImport/Import/A/CMakeLists.txt
@@ -90,6 +90,50 @@ add_custom_target(check_testLib1_genex ALL
           -P ${CMAKE_CURRENT_SOURCE_DIR}/check_testLib1_genex.cmake
   )
 
+if(CMAKE_SHARED_LIBRARY_SONAME_C_FLAG AND
+    "${CMAKE_C_CREATE_SHARED_MODULE}" MATCHES "SONAME_FLAG")
+  foreach(ns exp bld)
+    get_property(configs TARGET ${ns}_testLib5 PROPERTY IMPORTED_CONFIGURATIONS)
+    foreach(c ${configs})
+      string(TOUPPER "${c}" CONFIG)
+      get_property(soname TARGET ${ns}_testLib5 PROPERTY IMPORTED_NO_SONAME_${CONFIG})
+      if(soname)
+        message(SEND_ERROR "${ns}_testLib5 has IMPORTED_NO_SONAME_${CONFIG} but should:\n  ${soname}")
+      else()
+        message(STATUS "${ns}_testLib5 does not have IMPORTED_NO_SONAME_${CONFIG} as expected")
+      endif()
+    endforeach()
+
+    get_property(configs TARGET ${ns}_testLibNoSONAME PROPERTY IMPORTED_CONFIGURATIONS)
+    foreach(c ${configs})
+      string(TOUPPER "${c}" CONFIG)
+      get_property(soname TARGET ${ns}_testLibNoSONAME PROPERTY IMPORTED_NO_SONAME_${CONFIG})
+      if(soname)
+        message(STATUS "${ns}_testLibNoSONAME has IMPORTED_NO_SONAME_${CONFIG} as expected")
+      else()
+        message(SEND_ERROR "${ns}_testLibNoSONAME does not have IMPORTED_NO_SONAME_${CONFIG} but should")
+      endif()
+    endforeach()
+
+    # Parse the binary to check for SONAME if possible.
+    if("${CMAKE_EXECUTABLE_FORMAT}" MATCHES "ELF")
+      find_program(READELF_EXE readelf)
+      if(READELF_EXE)
+        add_custom_target(check_${ns}_testLib5_soname ALL COMMAND
+          ${CMAKE_COMMAND} -Dreadelf=${READELF_EXE}
+          -Dlib=$<TARGET_FILE:${ns}_testLib5>
+          -P ${CMAKE_CURRENT_SOURCE_DIR}/check_lib_soname.cmake
+          )
+        add_custom_target(check_${ns}_testLibNoSONAME_soname ALL COMMAND
+          ${CMAKE_COMMAND} -Dreadelf=${READELF_EXE}
+          -Dlib=$<TARGET_FILE:${ns}_testLibNoSONAME>
+          -P ${CMAKE_CURRENT_SOURCE_DIR}/check_lib_nosoname.cmake
+          )
+      endif()
+    endif()
+  endforeach()
+endif()
+
 add_executable(cmp0022OLD_test cmp0022OLD_test_vs6_1.cpp)
 target_link_libraries(cmp0022OLD_test bld_cmp0022OLD)
 add_executable(cmp0022NEW_test cmp0022NEW_test_vs6_1.cpp)
diff --git a/Tests/ExportImport/Import/A/check_lib_nosoname.cmake b/Tests/ExportImport/Import/A/check_lib_nosoname.cmake
new file mode 100644
index 0000000..6261ff4
--- /dev/null
+++ b/Tests/ExportImport/Import/A/check_lib_nosoname.cmake
@@ -0,0 +1,7 @@
+execute_process(COMMAND ${readelf} -d ${lib} OUTPUT_FILE ${lib}.readelf.txt)
+file(STRINGS ${lib}.readelf.txt soname REGEX "\\(SONAME\\)")
+if(soname)
+  message(FATAL_ERROR "${lib} has soname but should not:\n  ${soname}")
+else()
+  message(STATUS "${lib} has no soname as expected:\n  ${soname}")
+endif()
diff --git a/Tests/ExportImport/Import/A/check_lib_soname.cmake b/Tests/ExportImport/Import/A/check_lib_soname.cmake
new file mode 100644
index 0000000..7794e80
--- /dev/null
+++ b/Tests/ExportImport/Import/A/check_lib_soname.cmake
@@ -0,0 +1,7 @@
+execute_process(COMMAND ${readelf} -d ${lib} OUTPUT_FILE ${lib}.readelf.txt)
+file(STRINGS ${lib}.readelf.txt soname REGEX "\\(SONAME\\)")
+if(soname)
+  message(STATUS "${lib} has soname as expected:\n  ${soname}")
+else()
+  message(FATAL_ERROR "${lib} has no soname but should:\n  ${soname}")
+endif()