1 files changed, 69 insertions, 2 deletions
diff --git a/Tests/ConfigSources/CMakeLists.txt b/Tests/ConfigSources/CMakeLists.txt
index 1db00cc..5513af8 100644
--- a/Tests/ConfigSources/CMakeLists.txt
+++ b/Tests/ConfigSources/CMakeLists.txt
@@ -16,6 +16,72 @@ void config_$<CONFIG>() {}
 ]]
   )
 
+# Custom command outputs named with the configuration(s).
+add_custom_command(
+  OUTPUT "custom1_$<CONFIG>.cpp"
+  COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_CURRENT_SOURCE_DIR}/custom1.cpp.in" "custom1_$<CONFIG>.cpp"
+  DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/custom1.cpp.in
+  VERBATIM
+  )
+# Output path starts in a generator expression.
+add_custom_command(
+  OUTPUT "$<1:custom2_$<CONFIG>.cpp>"
+  COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_CURRENT_SOURCE_DIR}/custom2.cpp.in" "custom2_$<CONFIG>.cpp"
+  DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/custom2.cpp.in
+  VERBATIM
+  )
+# Source file generated as a custom command's byproduct.
+add_custom_command(
+  OUTPUT custom3.txt
+  BYPRODUCTS "$<1:custom3_$<CONFIG>.cpp>"
+  COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_CURRENT_SOURCE_DIR}/custom3.cpp.in" "custom3_$<CONFIG>.cpp"
+  COMMAND ${CMAKE_COMMAND} -E touch custom3.txt
+  DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/custom3.cpp.in
+  VERBATIM
+  )
+# Source file generated as a custom target's byproduct.
+add_custom_target(custom4
+  BYPRODUCTS "custom4_$<CONFIG>.cpp"
+  COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CMAKE_CURRENT_SOURCE_DIR}/custom4.cpp.in" "custom4_$<CONFIG>.cpp"
+  VERBATIM
+  )
+# Source file generated by appended custom command.
+add_custom_command(
+  OUTPUT "custom5_$<CONFIG>.cpp"
+  COMMAND ${CMAKE_COMMAND} -E echo custom5_$<CONFIG>.cpp
+  DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/custom5.cpp.in
+  VERBATIM
+  )
+add_custom_command(APPEND
+  OUTPUT "custom5_$<CONFIG>.cpp"
+  COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_CURRENT_SOURCE_DIR}/custom5.cpp.in" "custom5_$<CONFIG>.cpp.in"
+  VERBATIM
+  )
+# Appending through any configuration's output affects all configurations.
+if(CMAKE_CONFIGURATION_TYPES MATCHES ";([^;]+)$")
+  set(last_config "${CMAKE_MATCH_1}")
+else()
+  set(last_config ${CMAKE_BUILD_TYPE})
+endif()
+add_custom_command(APPEND
+  OUTPUT "custom5_${last_config}.cpp"
+  COMMAND ${CMAKE_COMMAND} -E copy "custom5_$<CONFIG>.cpp.in" "custom5_$<CONFIG>.cpp"
+  VERBATIM
+  )
+foreach(n RANGE 1 5)
+  set_property(SOURCE custom${n}_Debug.cpp PROPERTY COMPILE_DEFINITIONS CUSTOM_CFG_DEBUG)
+  foreach(other Release RelWithDebInfo MinSizeRel)
+    set_property(SOURCE custom${n}_${other}.cpp PROPERTY COMPILE_DEFINITIONS CUSTOM_CFG_OTHER)
+  endforeach()
+endforeach()
+add_library(Custom STATIC
+  custom1_$<CONFIG>.cpp
+  custom2_$<CONFIG>.cpp
+  custom3_$<CONFIG>.cpp custom3.txt
+  custom4_$<CONFIG>.cpp
+  custom5_$<CONFIG>.cpp
+  )
+
 # Per-config sources via INTERFACE_SOURCES.
 add_library(iface INTERFACE)
 target_sources(iface INTERFACE
@@ -34,7 +100,7 @@ add_executable(ConfigSources
   $<$<CONFIG:NotAConfig>:does_not_exist.cpp>
   ${CMAKE_CURRENT_BINARY_DIR}/config_$<CONFIG>.cpp
   )
-target_link_libraries(ConfigSources iface)
+target_link_libraries(ConfigSources Custom iface)
 
 # Per-config sources via LINK_LIBRARIES.
 add_library(iface_debug INTERFACE)
@@ -53,6 +119,7 @@ target_compile_definitions(ConfigSourcesLink PRIVATE
   "$<$<NOT:$<CONFIG:Debug>>:CFG_OTHER>"
   )
 target_link_libraries(ConfigSourcesLink PRIVATE
+  Custom
   "$<$<CONFIG:Debug>:iface_debug>"
   "$<$<NOT:$<CONFIG:Debug>>:iface_other>"
   "$<$<CONFIG:NotAConfig>:iface_does_not_exist>"
@@ -70,7 +137,7 @@ target_compile_definitions(ConfigSourcesLinkIface PRIVATE
   "$<$<CONFIG:Debug>:CFG_DEBUG>"
   "$<$<NOT:$<CONFIG:Debug>>:CFG_OTHER>"
   )
-target_link_libraries(ConfigSourcesLinkIface ConfigSourcesIface)
+target_link_libraries(ConfigSourcesLinkIface Custom ConfigSourcesIface)
 
 # A target with sources in only one configuration that is not the
 # first in CMAKE_CONFIGURATION_TYPES.