Long live Qt for S60!

10 files changed, 621 insertions, 0 deletions

diff --git a/mkspecs/features/symbian/application_icon.prf b/mkspecs/features/symbian/application_icon.prf
new file mode 100644
index 0000000..df4bb1c
--- /dev/null
+++ b/mkspecs/features/symbian/application_icon.prf
@@ -0,0 +1,39 @@
+load(data_caging_paths)
+
+# If no_icon keyword exist, the S60 UI app is just made hidden. This because S60 app FW
+# requires the registration resource file to exist always
+contains( CONFIG, no_icon ) {
+    symbian:RSS_RULES ="hidden = KAppIsHidden;" 
+    CONFIG -= no_icon
+} else {
+# There is no sense to compile MIF icon is no_icon CONFIGS is set
+    !isEmpty(ICON) {
+        
+        !count(ICON, $$size(TRANSLATIONS)):!count(ICON, 1) {
+            message("ICON keyword must have one or the same amout of items as in TRANSLATIONS keyword")
+        }
+
+        # MIF files will have UID in their names, if TARGET.UID3 is not set we need to generate it
+        isEmpty(TARGET.UID3):TARGET.UID3 = $$generate_test_uid($$TARGET)
+
+        # Note: symbian-sbsv2 builds can't utilize extra compiler for mifconv, so ICON handling is done in code
+        symbian-abld {        
+            #Makefile: requires paths with backslash    
+            ICON = $$replace( ICON, /, \\)
+
+            # Extra compiler rules for mifconv
+            mifconv.output = ${ZDIR}$$APP_RESOURCE_DIR/$${TARGET.UID3}.mif
+            # Based on: http://www.forum.nokia.com/document/Cpp_Developers_Library
+            # svg-t icons should always use /c32 depth
+            mifconv.commands = mifconv ${QMAKE_FILE_OUT} $$join(ICON, " /c32 ", "/c32 ",) 
+            mifconv.input = ICON
+            mifconv.CONFIG = no_link combine
+            # target_predeps together with combine seems not to work correctly, lets define it by ourselves
+            PRE_TARGETDEPS += $$mifconv.output
+            QMAKE_EXTRA_COMPILERS += mifconv
+        } 
+        # Rules to use generated MIF file from symbian resources
+        RSS_RULES.number_of_icons = $$size(ICON)
+        RSS_RULES.icon_file = $$replace( APP_RESOURCE_DIR, /, \\\\ )\\\\$${TARGET.UID3}.mif
+    }
+}
\ No newline at end of file
diff --git a/mkspecs/features/symbian/data_caging_paths.prf b/mkspecs/features/symbian/data_caging_paths.prf
new file mode 100644
index 0000000..3ed5661
--- /dev/null
+++ b/mkspecs/features/symbian/data_caging_paths.prf
@@ -0,0 +1,80 @@
+#
+# ==============================================================================
+#  Name        : data_caging_paths.prf
+#  Part of     : 
+#  Interface   : Data Caging Path Definitions API for Qt/S60
+#  Description : Predefined include paths to be used in the pro-files for the 
+#                paths related to data caging.
+#
+# Usage examples:
+#
+#     # Load these definitions on pro-file if needed:
+#     load(data_caging_paths)
+#    
+#     # These variables are mostly useful when specifying deployment
+#
+#     myLib.sources = myLib.dll
+#     myLib.path = $$SHARED_LIB_DIR
+#     DEPLOYMENT += myLib
+#
+#     # Note: Do not use $$PLUGINS_DIR or $$PLUGINS_1_DIR to deploy Qt plugins.
+#     # $$QT_PUBLIC_PLUGINS_BASE specifies the public base directory for Qt
+#     # plugin stubs:
+#
+#     myPublicImageFormatPlugin.sources = myImageFormat.dll
+#     myPublicImageFormatPlugin.path = $$QT_PLUGINS_BASE_DIR/imageformats
+#     DEPLOYMENT += myPublicImageFormatPlugin
+#
+# ==============================================================================
+
+exists($${EPOCROOT}epoc32/include/data_caging_paths.prf) {
+    
+    # Load platform specific paths
+    load($${EPOCROOT}epoc32/include/data_caging_paths.prf)
+
+} else {                      
+    # No platform specific paths provided, use default paths
+
+    APPARC_RECOGNISER_RESOURCES_DIR  = /resource/apps/registrationresourcefiles
+    APP_BITMAP_DIR                   = /resource/apps
+    APP_RESOURCE_DIR                 = /resource/apps
+    BITMAP_DIR                       = /resource/apps
+    BIOFILE_DIR                      = /resource/messaging/bif
+    CHARCONV_PLUGIN_DIR              = /resource/charconv
+    CONTACTS_RESOURCE_DIR            = /resource/cntmodel
+    CTRL_PANEL_RESOURCE_DIR          = /resource/controls
+    CONVERTER_PLUGIN_RESOURCE_DIR    = /resource/convert
+    ECOM_RESOURCE_DIR                = /resource/plugins
+    ERROR_RESOURCE_DIR               = /resource/errors
+    PROGRAMS_DIR                     = /sys/bin
+    FEP_RESOURCES_DIR                = /resource/fep
+    HELP_FILE_DIR                    = /resource/help
+    LOG_ENGINE_RESOURCE_DIR          = /resource/logengine
+    MTM_RESOURCE_DIR                 = /resource/messaging
+    MTM_INFO_FILE_DIR                = /resource/messaging/mtm
+    PRINTER_DRIVER_DIR               = /resource/printers
+    SHARED_LIB_DIR                   = /sys/bin
+    UIKLAF_RESOURCE_DIR              = /resource/uiklaf
+    WAPPUSH_PLUGIN_RESOURCE_DIR      = /resource/messaging/wappush
+    WATCHER_PLUGIN_RESOURCE_DIR      = /resource/messaging/watchers
+    RECOGNISERS_DIR                  = /sys/bin
+    PARSERS_DIR                      = /sys/bin
+    NOTIFIERS_DIR                    = /sys/bin
+    PLUGINS_DIR                      = /sys/bin
+    PLUGINS_1_DIR                    = /sys/bin
+    RESOURCE_FILES_DIR               = /resource
+
+    CA_CERTIFICATES_DIR     = /private/101f72a6
+    COMMDB_DIR              = /private/100012a5
+    SS_CONFIG_FILE_DIR      = /private/101f7989/esock
+    TRUSTED_FONTS_DIR       = /private/10003a16/fonts
+    UNTRUSTED_FONT_DIR      = /private/10003a16/import/fonts
+    WINDOW_SERVER_INI_DIR   = /private/10003b20
+    SKINS_DIR               = /private/10207114
+    BOOTDATA_DIR            = /resource/bootdata
+}
+
+isEmpty(QT_PLUGINS_BASE_DIR): QT_PLUGINS_BASE_DIR = /$$RESOURCE_FILES_DIR/qt/plugins
+isEmpty(HW_ZDIR): HW_ZDIR = epoc32/data/z
+isEmpty(REG_RESOURCE_DIR): REG_RESOURCE_DIR = /private/10003a3f/apps
+isEmpty(REG_RESOURCE_IMPORT_DIR): REG_RESOURCE_IMPORT_DIR = /private/10003a3f/import/apps
\ No newline at end of file
diff --git a/mkspecs/features/symbian/default_post.prf b/mkspecs/features/symbian/default_post.prf
new file mode 100644
index 0000000..3c2944c
--- /dev/null
+++ b/mkspecs/features/symbian/default_post.prf
@@ -0,0 +1,31 @@
+load(default_post)
+
+contains(TEMPLATE, ".*app") {
+    contains(CONFIG, stdbinary) {
+        QMAKE_LIBS +=
+    } else:contains(QT, gui):contains(CONFIG,qt) {
+        S60MAIN_LIBS = -leuser -lavkon -leikcore -leiksrv -lws32 -lapparc -lcone -leikcoctl -lbafl -lefsrv
+        QMAKE_LIBS += -lqtmain.lib $$S60MAIN_LIBS
+    } else {
+        QMAKE_LIBS += $$QMAKE_LIBS_QT_ENTRY
+    }
+}
+contains(TEMPLATE, lib): {
+    contains(CONFIG, staticlib)|contains(CONFIG, static): {
+        # Static libs should not have LIBRARY statements in S60
+        QMAKE_LIBS =
+        # Static libs do not need def files
+        MMP_RULES -= EXPORTUNFROZEN
+    }
+    contains(CONFIG, plugin):!contains(CONFIG, stdbinary): {
+        # Plugins based on normal libraries have predefined def file
+        MMP_RULES -= EXPORTUNFROZEN
+    }
+} else {
+    # Applications don't need this
+    MMP_RULES -= EXPORTUNFROZEN
+}
+
+contains(TEMPLATE, ".*app"):contains(QT, gui):contains(CONFIG,qt) {
+    load(application_icon.prf)
+}
\ No newline at end of file
diff --git a/mkspecs/features/symbian/default_pre.prf b/mkspecs/features/symbian/default_pre.prf
new file mode 100644
index 0000000..ddb23b3
--- /dev/null
+++ b/mkspecs/features/symbian/default_pre.prf
@@ -0,0 +1,2 @@
+CONFIG = stl_off $$CONFIG
+load(default_pre)
diff --git a/mkspecs/features/symbian/epocallowdlldata.prf b/mkspecs/features/symbian/epocallowdlldata.prf
new file mode 100644
index 0000000..b336f48
--- /dev/null
+++ b/mkspecs/features/symbian/epocallowdlldata.prf
@@ -0,0 +1 @@
+TARGET.EPOCALLOWDLLDATA=1
diff --git a/mkspecs/features/symbian/moc.prf b/mkspecs/features/symbian/moc.prf
new file mode 100644
index 0000000..089dddc
--- /dev/null
+++ b/mkspecs/features/symbian/moc.prf
@@ -0,0 +1,16 @@
+load(moc)
+
+RET = $$find(MOC_DIR, "\.[a-z]")
+!isEmpty(RET):{
+    error("Symbian does not support directories starting with a dot. Please set MOC_DIR to a different value in your profile.")
+}
+
+RET = $$find(RCC_DIR, "\.[a-z]")
+!isEmpty(RET):{
+    error("Symbian does not support directories starting with a dot. Please set RCC_DIR to a different value in your profile.")
+}
+
+RET = $$find(OBJECTS_DIR, "\.[a-z]")
+!isEmpty(RET):{
+    error("Symbian does not support directories starting with a dot. Please set OBJECTS_DIR to a different value in your profile.")
+}
diff --git a/mkspecs/features/symbian/platform_paths.prf b/mkspecs/features/symbian/platform_paths.prf
new file mode 100644
index 0000000..334f1e9
--- /dev/null
+++ b/mkspecs/features/symbian/platform_paths.prf
@@ -0,0 +1,416 @@
+#
+# ==============================================================================
+#  Name        : platform_paths.prf
+#  Part of     : 
+#  Interface   : Platform Path Definitions API for Qt/S60
+#  Description : Predefined include paths to be used in the pro-files for the 
+#                components in the layered model. There is one definition for
+#                each layer. The pro-file should use the statement that is 
+#                intended for the same layer as where the pro-file resides.
+#
+# Usage examples:
+#
+#     Note: this file gets automatically added to all Qt/S60 projects
+#    
+#     Variable usages to add the system include paths
+#       
+#       The include paths has to be related to the layer in which your SW 
+#       resides. Thus as an example: a component residing in middleware
+#       layer should use the MW specific macro.
+#
+#         INCLUDEPATH += $$APP_LAYER_SYSTEMINCLUDE
+#         INCLUDEPATH += $$MW_LAYER_SYSTEMINCLUDE
+#         INCLUDEPATH += $$OS_LAYER_SYSTEMINCLUDE
+#
+#       If there is a need to include public headers of some S60 component,
+#       various *_EXPORT_PATH macros can be utilized:
+#
+#         INCLUDEPATH += $$OS_LAYER_PUBLIC_EXPORT_PATH(somecomponent)
+#
+#     Variables related to using various parts of stdapis:
+#
+#       To use STLLIB you need to have this in your pro-file:
+#
+#         QMAKE_CXXFLAGS.CW *= $$STLLIB_USAGE_CW_FLAGS
+#         DEFINES *= $$STLLIB_USAGE_DEFINES
+#
+#       Depending on what module you are using from stdapis you need to have
+#       one or more of the following variables in your pro-file.
+#
+#         INCLUDEPATH += $$OS_LAYER_LIBC_SYSTEMINCLUDE
+#         INCLUDEPATH += $$OS_LAYER_GLIB_SYSTEMINCLUDE
+#         INCLUDEPATH += $$OS_LAYER_SSL_SYSTEMINCLUDE
+#         INCLUDEPATH += $$OS_LAYER_STDCPP_SYSTEMINCLUDE
+#         INCLUDEPATH += $$OS_LAYER_BOOST_SYSTEMINCLUDE
+#         INCLUDEPATH += $$OS_LAYER_DBUS_SYSTEMINCLUDE
+#         INCLUDEPATH += $$OS_LAYER_LIBUTILITY_SYSTEMINCLUDE
+#
+#
+#       
+#
+# ==============================================================================
+
+exists($${EPOCROOT}epoc32/include/platform_paths.prf) {
+    
+    # Load platform specific paths
+    load($${EPOCROOT}epoc32/include/platform_paths.prf)
+
+} else {  
+
+    # No platform specific paths provided, use default paths
+
+    exists($${EPOCROOT}epoc32/include/platform) { # New SF structure
+    
+        # ---------------------------------------
+        # Location, where the applications layer specific public headers are exported
+        # ---------------------------------------
+
+        defineReplace(APP_LAYER_SDK_EXPORT_PATH) {
+             return (/epoc32/include/app/$$1)
+        }
+        defineReplace(APP_LAYER_PUBLIC_EXPORT_PATH) {
+             return (/epoc32/include/app/$$1)
+        }
+
+        # ---------------------------------------
+        # Location, where the applications layer specific platform headers are exported
+        # ---------------------------------------
+
+        defineReplace(APP_LAYER_DOMAIN_EXPORT_PATH) {
+             return (/epoc32/include/platform/app/$$1)
+        }
+        defineReplace(APP_LAYER_PLATFORM_EXPORT_PATH) {
+             return (/epoc32/include/platform/app/$$1)
+        }
+
+        # ---------------------------------------
+        # Location, where the middleware layer specific public headers are exported
+        # ---------------------------------------
+
+        defineReplace(MW_LAYER_SDK_EXPORT_PATH) {
+             return (/epoc32/include/mw/$$1)
+        }
+        defineReplace(MW_LAYER_PUBLIC_EXPORT_PATH) {
+             return (/epoc32/include/mw/$$1)
+        }
+
+        # ---------------------------------------
+        # Location, where the middleware layer specific platform headers are exported
+        # ---------------------------------------
+
+        defineReplace(MW_LAYER_DOMAIN_EXPORT_PATH) {
+             return (/epoc32/include/platform/mw/$$1)
+        }
+        defineReplace(MW_LAYER_PLATFORM_EXPORT_PATH) {
+             return (/epoc32/include/platform/mw/$$1)
+        }
+
+        # ---------------------------------------
+        # Location, where the os layer specific public headers are exported
+        # ---------------------------------------
+
+        defineReplace(OSEXT_LAYER_SDK_EXPORT_PATH) {
+             return (/epoc32/include/$$1)
+        }
+        defineReplace(OS_LAYER_PUBLIC_EXPORT_PATH) {
+             return (/epoc32/include/$$1)
+        }
+
+        # ---------------------------------------
+        # Location, where the os specific platform headers are exported
+        # ---------------------------------------
+
+        defineReplace(OSEXT_LAYER_DOMAIN_EXPORT_PATH) {
+             return (/epoc32/include/platform/$$1)
+        }
+        defineReplace(OS_LAYER_PLATFORM_EXPORT_PATH) {
+             return (/epoc32/include/platform/$$1)
+        }
+
+        # ---------------------------------------
+        #  General comments about the 3 define statements related to include paths:
+        #  1) the /epoc32/include/oem is now defined there for backward compability.
+        #     Once the directory is empty, the directory will be removed. However this 
+        #     enables us to ensure that if you use these define statements => you do 
+        #     not have to remove the statements later on, when the directory no longer 
+        #     exists.
+        #  2) These statements should be enough in normal cases. For certain specific 
+        #     cases you might need to add some specific directory from /epoc32/include
+        #     (for instance /epoc32/include/ecom).
+        #     In normal cases the include staments in code should be relative to one of 
+        #     the system include paths, but in certain cases, the included files requires
+        #     that the subdirectory is also part of the system include paths.
+        # ---------------------------------------
+
+        # This variable defines the include paths, which are intended to be 
+        # used in the pro-files that are part of the applications-layer. It includes all 
+        # the needed directories from the /epoc32/include, that are valid ones for the 
+        # application-layer components. 
+        #
+        # Applications layer is the last one in the list, since most likely the most of 
+        # the headers come from middleware or os-layer  => thus they are first.
+
+        APP_LAYER_SYSTEMINCLUDE = \
+         /epoc32/include \
+         /epoc32/include/mw \
+         /epoc32/include/platform/mw \
+         /epoc32/include/platform \
+         /epoc32/include/app \
+         /epoc32/include/platform/app \
+         /epoc32/include/platform/loc \
+         /epoc32/include/platform/mw/loc \
+         /epoc32/include/platform/app/loc \
+         /epoc32/include/platform/loc/sc \
+         /epoc32/include/platform/mw/loc/sc \
+         /epoc32/include/platform/app/loc/sc
+
+        # This define statements defines the include paths, which are intended to be
+        # used in the pro-files that are part of the middleware-layer. It includes all 
+        # the needed directories from the /epoc32/include, that are valid ones for the 
+        # middleware-layer components. 
+
+        MW_LAYER_SYSTEMINCLUDE = \
+         /epoc32/include \
+         /epoc32/include/mw \
+         /epoc32/include/platform/mw \
+         /epoc32/include/platform \
+         /epoc32/include/platform/loc \
+         /epoc32/include/platform/mw/loc \
+         /epoc32/include/platform/loc/sc \
+         /epoc32/include/platform/mw/loc/sc
+
+        # This define statements defines the include paths, which are intended to be
+        # used in the pro-files that are part of the  osextensions-layer. It includes all
+        # the needed directories from the /epoc32/include, that are valid ones for the
+        # os-layer components. 
+
+        OS_LAYER_SYSTEMINCLUDE = \
+         /epoc32/include \
+         /epoc32/include/platform \
+         /epoc32/include/platform/loc \
+         /epoc32/include/platform/loc/sc
+
+        # This define statements defines the include paths, which are intended to be
+        # used in the pro-files that are part of the os-layer. This is intended 
+        # to be only used by those components which need to use in their mmp-file either
+        # kern_ext.mmh or nkern_ext.mmh. Reason is that those
+        # 2 files already contain the /epoc32/include  as system include path.
+
+        OS_LAYER_KERNEL_SYSTEMINCLUDE = \
+         /epoc32/include/platform
+
+
+        # ---------------------------------------
+        # Definitions that also define the systeminclude paths for various
+        # part of stdapis. Append to INCLUDEPATH in pro-file.
+        # ---------------------------------------
+
+        OS_LAYER_LIBC_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis)
+
+        OS_LAYER_GLIB_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/glib-2.0) \
+                                      $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/glib-2.0/glib) \
+                                      $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/glib-2.0/gObject)
+
+
+        OS_LAYER_SSL_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/openssl)
+
+        OS_LAYER_STDCPP_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/stlport) 
+
+        OS_LAYER_BOOST_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/boost)
+
+        OS_LAYER_DBUS_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/dbus-1.0) \
+                                      $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/dbus-1.0/dbus)
+
+        OS_LAYER_LIBUTILITY_SYSTEMINCLUDE = $$OS_LAYER_PLATFORM_EXPORT_PATH(stdapis/utility)
+
+
+        # You need to define the following in pro-file, if you are using the stllib:
+        # QMAKE_CXXFLAGS.CW *= $$STLLIB_USAGE_CW_FLAGS
+        # DEFINES *= $$STLLIB_USAGE_DEFINES
+        STLLIB_USAGE_CW_FLAGS = "-wchar_t on"
+        STLLIB_USAGE_DEFINES = _WCHAR_T_DECLARED
+
+    } else { # Old pre-SF structure
+
+        # ---------------------------------------
+        # Location, where the applications layer specific public headers are exported
+        # ---------------------------------------
+
+        defineReplace(APP_LAYER_SDK_EXPORT_PATH) {
+             return (/epoc32/include/applications/$$1)
+        }
+        defineReplace(APP_LAYER_PUBLIC_EXPORT_PATH) {
+             return (/epoc32/include/applications/$$1)
+        }
+
+        # ---------------------------------------
+        # Location, where the applications layer specific platform headers are exported
+        # ---------------------------------------
+
+        defineReplace(APP_LAYER_DOMAIN_EXPORT_PATH) {
+             return (/epoc32/include/domain/applications/$$1)
+        }
+        defineReplace(APP_LAYER_PLATFORM_EXPORT_PATH) {
+             return (/epoc32/include/domain/applications/$$1)
+        }
+
+        # ---------------------------------------
+        # Location, where the middleware layer specific public headers are exported
+        # ---------------------------------------
+
+        defineReplace(MW_LAYER_SDK_EXPORT_PATH) {
+             return (/epoc32/include/middleware/$$1)
+        }
+        defineReplace(MW_LAYER_PUBLIC_EXPORT_PATH) {
+             return (/epoc32/include/middleware/$$1)
+        }
+
+        # ---------------------------------------
+        # Location, where the middleware layer specific platform headers are exported
+        # ---------------------------------------
+
+        defineReplace(MW_LAYER_DOMAIN_EXPORT_PATH) {
+             return (/epoc32/include/domain/middleware/$$1)
+        }
+        defineReplace(MW_LAYER_PLATFORM_EXPORT_PATH) {
+             return (/epoc32/include/domain/middleware/$$1)
+        }
+
+        # ---------------------------------------
+        # Location, where the os layer specific public headers are exported
+        # ---------------------------------------
+
+        defineReplace(OSEXT_LAYER_SDK_EXPORT_PATH) {
+             return (/epoc32/include/osextensions/$$1)
+        }
+        defineReplace(OS_LAYER_PUBLIC_EXPORT_PATH) {
+             return (/epoc32/include/osextensions/$$1)
+        }
+
+        # ---------------------------------------
+        # Location, where the os specific platform headers are exported
+        # ---------------------------------------
+
+        defineReplace(OSEXT_LAYER_DOMAIN_EXPORT_PATH) {
+             return (/epoc32/include/domain/osextensions/$$1)
+        }
+        defineReplace(OS_LAYER_PLATFORM_EXPORT_PATH) {
+             return (/epoc32/include/domain/osextensions/$$1)
+        }
+
+        # ---------------------------------------
+        #  General comments about the 3 define statements related to include paths:
+        #  1) the /epoc32/include/oem is now defined there for backward compability.
+        #     Once the directory is empty, the directory will be removed. However this 
+        #     enables us to ensure that if you use these define statements => you do 
+        #     not have to remove the statements later on, when the directory no longer 
+        #     exists.
+        #  2) These statements should be enough in normal cases. For certain specific 
+        #     cases you might need to add some specific directory from /epoc32/include
+        #     (for instance /epoc32/include/ecom).
+        #     In normal cases the include staments in code should be relative to one of 
+        #     the system include paths, but in certain cases, the included files requires
+        #     that the subdirectory is also part of the system include paths.
+        # ---------------------------------------
+
+        # This variable defines the include paths, which are intended to be 
+        # used in the pro-files that are part of the applications-layer. It includes all 
+        # the needed directories from the /epoc32/include, that are valid ones for the 
+        # application-layer components. 
+        #
+        # Applications layer is the last one in the list, since most likely the most of 
+        # the headers come from middleware or os-layer  => thus they are first.
+
+        APP_LAYER_SYSTEMINCLUDE = \
+         /epoc32/include \
+         /epoc32/include/oem \
+         /epoc32/include/middleware \
+         /epoc32/include/domain/middleware \
+         /epoc32/include/osextensions \
+         /epoc32/include/domain/osextensions \
+         /epoc32/include/applications \
+         /epoc32/include/domain/applications \
+         /epoc32/include/domain/osextensions/loc \
+         /epoc32/include/domain/middleware/loc \
+         /epoc32/include/domain/applications/loc \
+         /epoc32/include/domain/osextensions/loc/sc \
+         /epoc32/include/domain/middleware/loc/sc \
+         /epoc32/include/domain/applications/loc/sc
+
+        # This define statements defines the include paths, which are intended to be
+        # used in the pro-files that are part of the middleware-layer. It includes all 
+        # the needed directories from the /epoc32/include, that are valid ones for the 
+        # middleware-layer components. 
+
+        MW_LAYER_SYSTEMINCLUDE = \
+         /epoc32/include \
+         /epoc32/include/oem \
+         /epoc32/include/middleware \
+         /epoc32/include/domain/middleware \
+         /epoc32/include/osextensions \
+         /epoc32/include/domain/osextensions \
+         /epoc32/include/domain/osextensions/loc \
+         /epoc32/include/domain/middleware/loc \
+         /epoc32/include/domain/osextensions/loc/sc \
+         /epoc32/include/domain/middleware/loc/sc
+
+        # This define statements defines the include paths, which are intended to be
+        # used in the pro-files that are part of the  osextensions-layer. It includes all
+        # the needed directories from the /epoc32/include, that are valid ones for the
+        # os-layer components. 
+
+        OS_LAYER_SYSTEMINCLUDE = \
+         /epoc32/include \
+         /epoc32/include/oem \
+         /epoc32/include/osextensions \
+         /epoc32/include/domain/osextensions \
+         /epoc32/include/domain/osextensions/loc \
+         /epoc32/include/domain/osextensions/loc/sc
+
+        # This define statements defines the include paths, which are intended to be
+        # used in the pro-files that are part of the os-layer. This is intended 
+        # to be only used by those components which need to use in their mmp-file either
+        # kern_ext.mmh or nkern_ext.mmh. Reason is that those
+        # 2 files already contain the /epoc32/include  as system include path.
+
+        OS_LAYER_KERNEL_SYSTEMINCLUDE = \
+         /epoc32/include/oem \
+         /epoc32/include/osextensions \
+         /epoc32/include/domain/osextensions
+
+
+        # ---------------------------------------
+        # Definitions that also define the systeminclude paths for various
+        # part of stdapis. Append to INCLUDEPATH in pro-file.
+        # ---------------------------------------
+
+        OS_LAYER_LIBC_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis)
+
+        OS_LAYER_GLIB_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/glib-2.0) \
+                                      $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/glib-2.0/glib) \
+                                      $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/glib-2.0/gObject)
+
+
+        OS_LAYER_SSL_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/openssl)
+
+        OS_LAYER_STDCPP_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/stlport) 
+
+        OS_LAYER_BOOST_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/boost)
+
+        OS_LAYER_DBUS_SYSTEMINCLUDE = $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/dbus-1.0) \
+                                      $$OS_LAYER_PUBLIC_EXPORT_PATH(stdapis/dbus-1.0/dbus)
+
+        OS_LAYER_LIBUTILITY_SYSTEMINCLUDE = $$OS_LAYER_PLATFORM_EXPORT_PATH(stdapis/utility)
+
+
+        # You need to define the following in pro-file, if you are using the stllib:
+        # QMAKE_CXXFLAGS.CW *= $$STLLIB_USAGE_CW_FLAGS
+        # DEFINES *= $$STLLIB_USAGE_DEFINES
+        STLLIB_USAGE_CW_FLAGS = "-wchar_t on"
+        STLLIB_USAGE_DEFINES = _WCHAR_T_DECLARED
+    
+    } 
+}
+
+
+    
diff --git a/mkspecs/features/symbian/qt.prf b/mkspecs/features/symbian/qt.prf
new file mode 100644
index 0000000..29b39a5
--- /dev/null
+++ b/mkspecs/features/symbian/qt.prf
@@ -0,0 +1,15 @@
+contains(DEFINES, QT_MAKEDLL)|contains(DEFINES, QT_DLL) {
+    CONFIG *= epocallowdlldata
+}
+
+CONFIG += qtmain
+
+load(qt)
+
+contains(CONFIG, qt):!contains(TARGET.UID3, 0x2001E61C):!contains(TARGET.UID3, 0xE001E61C) {
+    default_deployment.depends += \
+        "(0x2001E61C), $${QT_MAJOR_VERSION}, $${QT_MINOR_VERSION}, $${QT_PATCH_VERSION},  {\"QtLibs pre-release\"}"
+}
+
+isEmpty(TARGET.EPOCSTACKSIZE):TARGET.EPOCSTACKSIZE = 0x14000
+isEmpty(TARGET.EPOCHEAPSIZE):TARGET.EPOCHEAPSIZE = 0x020000 0x800000
diff --git a/mkspecs/features/symbian/stl.prf b/mkspecs/features/symbian/stl.prf
new file mode 100644
index 0000000..b91d783
--- /dev/null
+++ b/mkspecs/features/symbian/stl.prf
@@ -0,0 +1,19 @@
+CONFIG -= stl_off
+
+# STL usage in S60 requires the following mmp variables to be uses
+# OPTION CW -wchar_t on
+# MACRO  _WCHAR_T_DECLARED
+
+QMAKE_CXXFLAGS.CW *= $$STLLIB_USAGE_CW_FLAGS 
+DEFINES *= $$STLLIB_USAGE_DEFINES
+
+# Legacy support requires some hardcoded stdapis paths.
+# Note: Also the new header is used from STL when it is enabled
+INCLUDEPATH += \
+    $${EPOCROOT}epoc32/include/stdapis/stlport \ 
+    $$OS_LAYER_STDCPP_SYSTEMINCLUDE
+LIBS *= -llibstdcpp.dll
+
+# Remove mkspecs/common/symbian/stl-off from beginning of includepath 
+# in order to use new and delete operators from STL
+INCLUDEPATH -= $$[QT_INSTALL_PREFIX]/mkspecs/common/symbian/stl-off
diff --git a/mkspecs/features/symbian/stl_off.prf b/mkspecs/features/symbian/stl_off.prf
new file mode 100644
index 0000000..d5d1c7c
--- /dev/null
+++ b/mkspecs/features/symbian/stl_off.prf
@@ -0,0 +1,2 @@
+CONFIG -= stl
+