Add enablers for Symbian App Booster

To use the Symbian App Booster, a registration file (matching the
filename of the executable, eg helloworld.applite) must be copied to the
import folder within QtAppBooster's private directory. The appropriate
library (qdeclarativebooster) must also be linked against. With this
change, the required actions are carried out by adding
"CONFIG += symbian_appbooster" to the application's .pro file.

Task-number: QT-4892
Reviewed-by: Miikka Heikkinen

1 files changed, 32 insertions, 0 deletions

diff --git a/mkspecs/features/symbian/symbian_appbooster.prf b/mkspecs/features/symbian/symbian_appbooster.prf
new file mode 100644
index 0000000..080f4d0
--- /dev/null
+++ b/mkspecs/features/symbian/symbian_appbooster.prf
@@ -0,0 +1,32 @@
+contains(TEMPLATE, ".*app") {
+    baseTarget = $$symbianRemoveSpecialCharacters($$basename(TARGET))
+
+    symbian-abld|symbian-sbsv2 {
+        LITE_REG_TARGET = $$_PRO_FILE_PWD_
+    } else {
+        contains(DESTDIR, "/.*") {
+            LITE_REG_TARGET = $$DESTDIR
+        } else:isEmpty(DESTDIR) {
+            LITE_REG_TARGET = $$OUT_PWD
+        } else {
+            LITE_REG_TARGET = $$OUT_PWD/$$DESTDIR
+        }
+    }
+
+    LITE_REG_TARGET = $${LITE_REG_TARGET}/$${baseTarget}.applite
+    LITE_REG_TEMPLATE = $$[QT_INSTALL_DATA]/mkspecs/common/symbian/template.applite
+
+    lite_reg_copy.input = LITE_REG_TEMPLATE
+    lite_reg_copy.output = $$LITE_REG_TARGET
+    lite_reg_copy.variable_out = PRE_TARGETDEPS
+    lite_reg_copy.commands = $$QMAKE_COPY ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
+    lite_reg_copy.CONFIG += no_link
+    QMAKE_EXTRA_COMPILERS += lite_reg_copy
+
+    isEmpty(LITE_IMPORT_DIR): LITE_IMPORT_DIR = /private/20034884/import/apps
+    lite_deployment.sources += $$LITE_REG_TARGET
+    lite_deployment.path = $$LITE_IMPORT_DIR
+    DEPLOYMENT += lite_deployment
+
+    LIBS += -lqDeclarativeBooster.dll
+}