Integrate the OpenVG graphics system into Qt 4.6

This change also moves the EGL support classes from QtOpenGL to QtGui
so they can be shared between OpenGL and OpenVG.

1 files changed, 48 insertions, 0 deletions

diff --git a/src/openvg/openvg.pro b/src/openvg/openvg.pro
new file mode 100644
index 0000000..4d499ef
--- /dev/null
+++ b/src/openvg/openvg.pro
@@ -0,0 +1,48 @@
+TARGET = QtOpenVG
+QT += core \
+    gui
+
+DEFINES+=QT_BUILD_OPENVG_LIB
+
+contains(QT_CONFIG, shivavg) {
+    DEFINES += QVG_NO_DRAW_GLYPHS
+    DEFINES += QVG_NO_RENDER_TO_MASK
+    DEFINES += QVG_SCISSOR_CLIP
+}
+
+HEADERS += \
+    qvg.h \
+    qvg_p.h \
+    qpaintengine_vg_p.h \
+    qpixmapdata_vg_p.h \
+    qpixmapfilter_vg_p.h \
+    qvgcompositionhelper_p.h
+SOURCES += \
+    qpaintengine_vg.cpp \
+    qpixmapdata_vg.cpp \
+    qpixmapfilter_vg.cpp
+
+contains(QT_CONFIG, egl) {
+    HEADERS += \
+        qwindowsurface_vgegl_p.h \
+        qwindowsurface_vg_p.h
+    SOURCES += \
+        qwindowsurface_vg.cpp \
+        qwindowsurface_vgegl.cpp
+}
+
+include(../qbase.pri)
+
+unix:QMAKE_PKGCONFIG_REQUIRES = QtCore QtGui
+
+!isEmpty(QMAKE_INCDIR_OPENVG): INCLUDEPATH += $$QMAKE_INCDIR_OPENVG
+!isEmpty(QMAKE_LIBDIR_OPENVG): LIBS += -L$$QMAKE_LIBDIR_OPENVG
+!isEmpty(QMAKE_LIBS_OPENVG): LIBS += $$QMAKE_LIBS_OPENVG
+
+contains(QT_CONFIG, egl) {
+    !isEmpty(QMAKE_INCDIR_EGL): INCLUDEPATH += $$QMAKE_INCDIR_EGL
+    !isEmpty(QMAKE_LIBDIR_EGL): LIBS += -L$$QMAKE_LIBDIR_EGL
+    !isEmpty(QMAKE_LIBS_EGL): LIBS += $$QMAKE_LIBS_EGL
+}
+
+INCLUDEPATH += ../3rdparty/harfbuzz/src