revert built-time qm generation

it simply breaks too much (embedded builds in particular).
will come up with something better in master.

note however, that the .qm files do NOT return to the repository. the
release manager needs to run "make qm" before packaging, just like
Qt-from-git users who want translations do (i.e., almost nobody).

Reviewed-by: Jason McDonald

2 files changed, 35 insertions, 53 deletions

diff --git a/translations/translations.pri b/translations/translations.pri
index c143043..0c5c1ee 100644
--- a/translations/translations.pri
+++ b/translations/translations.pri
@@ -8,8 +8,16 @@ defineReplace(prependAll) {
     return ($$result)
 }
 
-LUPDATE = $$QT_BUILD_TREE/bin/lupdate -locations relative -no-ui-lines
-win32:LUPDATE ~= s|/|\|g
+defineReplace(fixPath) {
+WIN {
+    return ($$replace($$1, /, \))
+} ELSE {
+    return ($$1)
+}
+}
+
+LUPDATE = $$fixPath($$QT_BUILD_TREE/bin/lupdate) -locations relative -no-ui-lines
+LRELEASE = $$fixPath($$QT_BUILD_TREE/bin/lrelease)
 
 ###### Qt Libraries
 
@@ -33,18 +41,27 @@ ts-qt.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
                                 -ts $$prependAll($$[QT_INSTALL_TRANSLATIONS]/qt_,$$QT_TS,.ts))
 ts-qt.depends = sub-tools
 
+qm-qt.commands = $$LRELEASE $$prependAll($$[QT_INSTALL_TRANSLATIONS]/qt_,$$QT_TS,.ts)
+qm-qt.depends = sub-tools
+
 ###### Designer
 
 ts-designer.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
                                     ../tools/designer/translations/translations.pro)
 ts-designer.depends = sub-tools
 
+qm-designer.commands = $$LRELEASE $$QT_SOURCE_TREE/tools/designer/translations/translations.pro
+qm-designer.depends = sub-tools
+
 ###### Linguist
 
 ts-linguist.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
                                     ../tools/linguist/linguist/linguist.pro)
 ts-linguist.depends = sub-tools
 
+qm-linguist.commands = $$LRELEASE $$QT_SOURCE_TREE/tools/linguist/linguist/linguist.pro
+qm-linguist.depends = sub-tools
+
 ###### Assistant
 
 ts-assistant.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
@@ -55,21 +72,36 @@ ts-assistant.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
                                     ../tools/assistant/translations/translations_adp.pro)
 ts-assistant.depends = sub-tools
 
+qm-assistant.commands = ($$LRELEASE $$QT_SOURCE_TREE/tools/assistant/translations/translations.pro \
+                         && $$LRELEASE \
+                            $$QT_SOURCE_TREE/tools/assistant/translations/qt_help.pro \
+                         && $$LRELEASE \
+                            $$QT_SOURCE_TREE/tools/assistant/translations/translations_adp.pro)
+qm-assistant.depends = sub-tools
+
 ###### Qtconfig
 
 ts-qtconfig.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
                                     ../tools/qtconfig/translations/translations.pro)
 ts-qtconfig.depends = sub-tools
 
+qm-qtconfig.commands = $$LRELEASE $$QT_SOURCE_TREE/tools/qtconfig/translations/translations.pro
+qm-qtconfig.depends = sub-tools
+
 ###### Qvfp
 
 ts-qvfb.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
                                     ../tools/qvfb/translations/translations.pro)
 ts-qvfb.depends = sub-tools
 
+qm-qvfb.commands = $$LRELEASE $$QT_SOURCE_TREE/tools/qvfb/translations/translations.pro
+qm-qvfb.depends = sub-tools
+
 ###### Overall Rules
 
 ts.depends = ts-qt ts-designer ts-linguist ts-assistant ts-qtconfig ts-qvfb
+qm.depends = qm-qt qm-designer qm-linguist qm-assistant qm-qtconfig qm-qvfb
 
 QMAKE_EXTRA_TARGETS += ts-qt ts-designer ts-linguist ts-assistant ts-qtconfig ts-qvfb \
-                       ts
+                       qm-qt qm-designer qm-linguist qm-assistant qm-qtconfig qm-qvfb \
+                       ts qm
diff --git a/translations/translations.pro b/translations/translations.pro
deleted file mode 100644
index 6f14108..0000000
--- a/translations/translations.pro
+++ /dev/null
@@ -1,50 +0,0 @@
-TRANSLATIONS = $$files(*.ts)
-
-LRELEASE = $$QT_BUILD_TREE/bin/lrelease
-win32 {
-    LRELEASE ~= s|/|\|g
-} else:!static {
-    path = $$QT_BUILD_TREE/lib
-    !macx:var = LD_LIBRARY_PATH
-    else:qt_no_framework:var = DYLD_LIBRARY_PATH
-    else:var = DYLD_FRAMEWORK_PATH
-
-    LRELEASE = test -z \"\$\$$$var\" && $$var=$$path || $$var=$$path:\$\$$$var; export $$var; $$LRELEASE
-}
-
-contains(TEMPLATE_PREFIX, vc):vcproj = 1
-
-TEMPLATE = app
-TARGET = qm_phony_target
-CONFIG -= qt separate_debug_info
-QT =
-LIBS =
-
-updateqm.input = TRANSLATIONS
-updateqm.output = ${QMAKE_FILE_BASE}.qm
-isEmpty(vcproj):updateqm.variable_out = PRE_TARGETDEPS
-updateqm.commands = @echo lrelease ${QMAKE_FILE_IN}; $$LRELEASE ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_OUT}
-updateqm.name = LRELEASE ${QMAKE_FILE_IN}
-updateqm.CONFIG += no_link
-QMAKE_EXTRA_COMPILERS += updateqm
-
-isEmpty(vcproj) {
-    QMAKE_LINK = @: IGNORE THIS LINE
-    OBJECTS_DIR =
-    win32:CONFIG -= embed_manifest_exe
-} else {
-    CONFIG += console
-    PHONY_DEPS = .
-    phony_src.input = PHONY_DEPS
-    phony_src.output = phony.c
-    phony_src.variable_out = GENERATED_SOURCES
-    phony_src.commands = echo int main() { return 0; } > phony.c
-    phony_src.name = CREATE phony.c
-    phony_src.CONFIG += combine
-    QMAKE_EXTRA_COMPILERS += phony_src
-}
-
-translations.path = $$[QT_INSTALL_TRANSLATIONS]
-translations.files = $$TRANSLATIONS
-translations.files ~= s,\\.ts$,.qm,g
-INSTALLS += translations