examples/declarative/tabwidget/TabWidget.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

import Qt 4.7

Item {
    id: tabWidget
    property int current: 0
    default property alias content: stack.children

    onCurrentChanged: setOpacities()
    Component.onCompleted: setOpacities()

    function setOpacities()
    {
        for (var i = 0; i < stack.children.length; ++i) {
            stack.children[i].opacity = i == current ? 1 : 0
        }
    }

    Row {
        id: header
        Repeater {
            delegate:
            Rectangle {
                width: tabWidget.width / stack.children.length; height: 36
                Rectangle {
                    color: "#acb2c2"; width: parent.width; height: 1
                    anchors { bottom: parent.bottom; bottomMargin: 1 }
                }
                BorderImage {
                    source: "tab.png"; visible: tabWidget.current == index; border.left: 7; border.right: 7
                    anchors { fill: parent; leftMargin: 2; topMargin: 5; rightMargin: 1 }
                }
                Text {
                    horizontalAlignment: Qt.AlignHCenter; verticalAlignment: Qt.AlignVCenter
                    anchors.fill: parent; text: stack.children[index].title
                    elide: Text.ElideRight; font.bold: tabWidget.current == index
                }
                MouseArea {
                    anchors.fill: parent
                    onClicked: tabWidget.current = index
                }
            }
            model: stack.children.length
        }
    }

    Item {
        id: stack
        anchors.top: header.bottom; anchors.bottom: tabWidget.bottom; width: tabWidget.width
    }
}