blob: a11371caa1709495e9de513b46b1cd2271f5ac77 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
load(qttest_p4)
SOURCES += ../tst_qfile.cpp
# Activate this define to be able to run the test without test network infrastructure.
# DEFINES += NO_NETWORK_TEST
CONFIG -= app_bundle
wince*|symbian {
QT = core gui
files.files += ..\\dosfile.txt ..\\noendofline.txt ..\\testfile.txt \
..\\testlog.txt ..\\two.dots.file ..\\tst_qfile.cpp \
..\\Makefile ..\\forCopying.txt ..\\forRenaming.txt
files.path = .
resour.files += ..\\resources\\file1.ext1
resour.path = resources
DEPLOYMENT += files resour
}
wince* {
SOURCES += $$QT_SOURCE_TREE/src/corelib/kernel/qfunctions_wince.cpp # needed for QT_OPEN
DEFINES += SRCDIR=\\\"\\\"
} else:symbian {
# do not define SRCDIR at all
TARGET.EPOCHEAPSIZE = 0x100000 0x3000000
} else {
QT = core network
DEFINES += SRCDIR=\\\"$$PWD/../\\\"
}
RESOURCES += ../qfile.qrc ../rename-fallback.qrc ../copy-fallback.qrc
TARGET = ../tst_qfile
win32 {
CONFIG(debug, debug|release) {
TARGET = ../../debug/tst_qfile
} else {
TARGET = ../../release/tst_qfile
}
LIBS+=-lole32 -luuid
}
symbian {
LIBS+=-lefsrv
}
|
