blob: 13b01f2462df233c7f8f0a2868da52eaac2e689a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
TEMPLATE = app
CONFIG += qt \
uic
DESTDIR = ../../bin
QT += declarative \
script \
network \
sql
contains(QT_CONFIG, opengl) {
QT += opengl
DEFINES += GL_SUPPORTED
}
# Input
HEADERS += qmlruntime.h \
proxysettings.h \
qdeclarativetester.h \
deviceorientation.h \
qdeclarativefolderlistmodel.h
SOURCES += main.cpp \
qmlruntime.cpp \
proxysettings.cpp \
qdeclarativetester.cpp \
qdeclarativefolderlistmodel.cpp
RESOURCES = qmlruntime.qrc
maemo5 {
SOURCES += deviceorientation_maemo.cpp
} else {
SOURCES += deviceorientation.cpp
}
FORMS = recopts.ui \
proxysettings.ui
INCLUDEPATH += ../../include/QtDeclarative
INCLUDEPATH += ../../src/declarative/util
INCLUDEPATH += ../../src/declarative/graphicsitems
include(../shared/deviceskin/deviceskin.pri)
target.path = $$[QT_INSTALL_BINS]
INSTALLS += target
wince* {
QT += scripttools \
xml \
phonon
contains(QT_CONFIG, xmlpatterns) {
QT += xmlpatterns
}
contains(QT_CONFIG, webkit) {
QT += webkit
}
}
symbian {
# TARGET.UID3 =
include($$QT_SOURCE_TREE/examples/symbianpkgrules.pri)
TARGET.EPOCHEAPSIZE = 0x20000 0x2000000
HEADERS += $$QT_SOURCE_TREE/examples/network/qftp/sym_iap_util.h
LIBS += -lesock -lcommdb -lconnmon -linsock
TARGET.CAPABILITY = "All -TCB"
}
mac {
QMAKE_INFO_PLIST=Info_mac.plist
TARGET=Qml
}
|
